lib32-pcsclite
LOW
maintainer orphaned
0 votes
scanned 2026-08-23 11:20:29.798052
Why flagged
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
Triggered rules
Low
Few votes, recently uploaded
zero_votes_recent
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
PKGBUILD
1
# Maintainer: Chih-Hsuan Yen <yan12125@archlinux.org>
2
# Contributor: Alad Wenter <alad@archlinux.org>
3
# Contributor: Christian Hesse <mail@eworm.de>
4
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
5
# Contributor: Daniel Plaza <daniel.plaza.espi@gmail.com>
6
7
_pkgname=pcsclite
8
pkgname=lib32-$_pkgname
9
# https://gitlab.archlinux.org/archlinux/packaging/packages/pcsclite/-/commits/main
10
# https://salsa.debian.org/rousseau/PCSC/blob/master/ChangeLog
11
pkgver=2.5.1
12
pkgrel=1
13
pkgdesc="PC/SC Architecture smartcard middleware library (32-bit)"
14
arch=('x86_64')
15
url='https://pcsclite.apdu.fr/'
16
# https://salsa.debian.org/rousseau/PCSC/-/blob/2.0.3/COPYING
17
license=(
18
'BSD-3-Clause' # Most of it
19
'GPL-3.0-or-later' # doc/example/pcsc_demo.c, src/spy/, UnitaryTests/
20
'BSD-2-Clause' # src/auth.c, src/auth.h
21
'0BSD' # src/simclist.c, src/simclist.h
22
)
23
depends=(
24
'libsystemd.so'
25
'libudev.so'
26
'libpolkit-gobject-1.so'
27
$_pkgname
28
)
29
makedepends=(
30
'git'
31
'meson'
32
'lib32-polkit'
33
'lib32-systemd'
34
)
35
provides=(
36
'libpcsclite.so'
37
'libpcsclite_real.so'
38
'libpcscspy.so'
39
)
40
validpgpkeys=('F5E11B9FFE911146F41D953D78A1B4DFE8F9C57E') # Ludovic Rousseau <rousseau@debian.org>
41
source=(
42
"git+https://github.com/LudovicRousseau/PCSC.git?signed#tag=${pkgver}"
43
"program-suffix.patch"
44
"systemd-unit-conflicts.diff"
45
"0001-Allow-to-run-32-bit-pcscd-on-64-bit-systems.patch"
46
)
47
sha256sums=('fb396681125b89569e3513e80b11f8636dba144dae6b49d480fe292cbb759b1d'
48
'782db4be00202c5a8ea305bfbf6c8a6da17ccdbf370b3b79bb0c0eea3f4c6bf1'
49
'207a2109c954ae75ba31e607f8da587f7053c6fe2f9e3ae17090acfb0c680b36'
50
'6623cfd64ce75c3c8a4274210a437f3d192908bd3b5505f5c529c2aebd581581')
51
52
prepare() {
53
cd PCSC
54
patch -Np1 -i ../program-suffix.patch
55
# Seems pcscd-32 needs exclusive access to devices
56
patch -Np1 -i ../systemd-unit-conflicts.diff
57
patch -Np1 -i ../0001-Allow-to-run-32-bit-pcscd-on-64-bit-systems.patch
58
}
59
60
build() {
61
local meson_options=(
62
--cross-file lib32
63
-D program_suffix="-32"
64
-D libsystemd=true
65
-D libudev=true
66
-D polkit=true
67
-D serial=true
68
-D systemdunit=system
69
-D usbdropdir=/usr/lib32/pcsc/drivers
70
)
71
arch-meson PCSC build "${meson_options[@]}"
72
meson compile -C build
73
74
# namcap requires separate files for each "uncommon" license (ex: BSD* ones), so splitting the upstream COPYING file
75
awk '/David Corcoran/{flag=1} /GNU GPL v3/ {flag=0} flag' PCSC/COPYING > LICENSE.BSD-3-Clause
76
awk '/GNU GPL v3/ {flag=1} /auth.c/ {flag=0} flag' PCSC/COPYING > LICENSE.GPL-3.0-or-later
77
awk '/auth.c/ {flag=1} /simclist.c/ {flag=0} flag' PCSC/COPYING > LICENSE.BSD-2-Clause
78
awk '/simclist.c/ {flag=1} flag' PCSC/COPYING > LICENSE.0BSD
79
}
80
81
package() {
82
meson install -C build --destdir "${pkgdir}"
83
84
# Remove files shared with pcsclite
85
rm -rv "$pkgdir"/{etc,usr/{include,lib/sysusers.d,share}}
86
# pcsc-spy is just a Python script, and thus the one from 64-bit pcsclite works with this package
87
rm -v "$pkgdir"/usr/bin/pcsc-spy
88
# Keep pcscd-32 as it's useful for using with 32-bit only drivers
89
90
install -D -m0644 LICENSE.* -t "${pkgdir}"/usr/share/licenses/$pkgname
91
install -d "${pkgdir}"/usr/lib32/pcsc/drivers
92
}
93
94
# vim:set sw=2 sts=-1 et:
95
Scan history
| Scanned at (UTC) | Severity | Rules |
|---|---|---|
| 2026-08-23 11:20:29 | Low | 1 |