libfprint-goodix55b4

LOW

maintainer alireza6677 1 votes scanned 2026-10-24 05:39:24.161025

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Alireza S.N. <alireza6677@gmail.com>
    
      2#
    
      3# Drop-in replacement for Arch's libfprint: upstream libfprint 1.94.10 with
    
      4# all of its drivers plus goodix55b4 (Goodix 27c6:55b4, native Milan matcher).
    
      5# fprintd uses it directly. Prints enrolled with other 55b4 drivers
    
      6# (goodixtls55x4/SIGFM) are not compatible: delete them and re-enroll.
    
      7#
    
      8# Also installs the libfprint examples as goodix55b4-{img-capture,enroll,
    
      9# verify,identify,manage-prints} (stop fprintd first; they need root for USB).
    
      10#
    
      11# Published on the AUR as libfprint-goodix55b4. To build from this repo:
    
      12#   git clone https://github.com/TheWeirdDev/libfprint-goodix55b4-milan.git
    
      13#   cd libfprint-goodix55b4-milan/packaging/arch && makepkg -si
    
      14
    
      15pkgname=libfprint-goodix55b4
    
      16pkgver=1.94.10.m2
    
      17pkgrel=2
    
      18pkgdesc="libfprint with the Goodix 27c6:55b4 driver using the native Milan matcher"
    
      19arch=('x86_64')
    
      20url="https://github.com/TheWeirdDev/libfprint-goodix55b4-milan"
    
      21license=('LGPL-2.1-or-later')
    
      22depends=('glib2' 'libgusb' 'libgudev' 'openssl' 'pixman' 'libdeflate' 'systemd-libs')
    
      23makedepends=('git' 'meson' 'ninja' 'python' 'patchelf' 'gobject-introspection' 'systemd')
    
      24provides=('libfprint=1.94.10' 'libfprint-2.so')
    
      25conflicts=('libfprint' 'libfprint-goodix55b4-milan')
    
      26_libfprint_commit=0c97a47d8ef405cd577b87058c1e89cae9d242e7 # v1.94.10
    
      27_repo_url=https://github.com/TheWeirdDev/libfprint-goodix55b4-milan.git
    
      28source=("libfprint::git+https://gitlab.freedesktop.org/libfprint/libfprint.git#commit=${_libfprint_commit}"
    
      29        "driver::git+${_repo_url}#tag=v${pkgver}")
    
      30sha256sums=('SKIP' 'SKIP')
    
      31
    
      32_examples=(img-capture enroll verify identify manage-prints)
    
      33
    
      34prepare() {
    
      35  python3 -I "$srcdir/driver/scripts/integrate.py" "$srcdir/libfprint"
    
      36}
    
      37
    
      38build() {
    
      39  arch-meson libfprint build \
    
      40    -Dudev_rules_dir=/usr/lib/udev/rules.d \
    
      41    -Ddoc=false \
    
      42    -Dinstalled-tests=false \
    
      43    -Dgtk-examples=false
    
      44  meson compile -C build
    
      45}
    
      46
    
      47check() {
    
      48  # integrate.py must have moved 55b4 from the "unsupported" list to the
    
      49  # goodix55b4 driver. (The autosuspend hwdb itself ships with systemd.)
    
      50  grep -q '^usb:v27C6p55B4' libfprint/data/autosuspend.hwdb
    
      51  ! grep -q '0x55b4' libfprint/libfprint/fprint-list-udev-hwdb.c
    
      52}
    
      53
    
      54package() {
    
      55  meson install -C build --destdir "$pkgdir"
    
      56
    
      57  install -d "$pkgdir/usr/bin"
    
      58  local e
    
      59  for e in "${_examples[@]}"; do
    
      60    install -m755 "build/examples/$e" "$pkgdir/usr/bin/goodix55b4-$e"
    
      61    # Drop the build-tree RUNPATH; the system libfprint is this package.
    
      62    patchelf --remove-rpath "$pkgdir/usr/bin/goodix55b4-$e"
    
      63  done
    
      64
    
      65  install -Dm644 "$srcdir/driver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      66}
    
      67

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-24 05:39:24	Low	1
2026-10-23 00:02:19	Clean	2
2026-10-22 19:36:04	Low	1