lightcraft-git

LOW

maintainer alerque 0 votes scanned 2026-10-07 14:05:47.471701

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Caleb Maclennan <caleb@alerque.com>
    
      2
    
      3pkgname=lightcraft-git
    
      4_pkgname=${pkgname%-git}
    
      5pkgver=0.2.1.r70.gfb9fb77
    
      6pkgrel=1
    
      7url="https://getartcraft.com/apps/$_pkgname"
    
      8_url="https://github.com/storytold/$_pkgname"
    
      9pkgdesc='vibe coded clean-room reimplementation of Adobe Lightroom'
    
      10arch=(x86_64)
    
      11license=(MIT Apache-2.0)
    
      12depends=(glibc # libc.so libm.so
    
      13         hicolor-icon-theme
    
      14         libgcc)
    
      15makedepends=(cargo
    
      16             git)
    
      17provides=("$_pkgname=$pkgver")
    
      18conflicts=("$_pkgname")
    
      19source=("git+$_url.git")
    
      20sha256sums=('SKIP')
    
      21
    
      22_srcenv() {
    
      23	cd "$_pkgname"
    
      24	export CARGO_HOME="$srcdir"
    
      25	export CARGO_PROFILE_RELEASE_DEBUG=2
    
      26	export CARGO_PROFILE_RELEASE_STRIP=false
    
      27	export CARGO_PROFILE_RELEASE_LTO=thin
    
      28	export CARGO_PROFILE_RELEASE_CODEGEN_UNITS=1
    
      29	export CARGO_PROFILE_RELEASE_OPT_LEVEL=3
    
      30	export CARGO_TARGET_DIR=target
    
      31	export RUSTUP_TOOLCHAIN=stable
    
      32	CFLAGS+=' -fno-lto'
    
      33}
    
      34
    
      35_icons=(512 256 128 64 48 32 16)
    
      36
    
      37prepare() {
    
      38	_srcenv
    
      39	cargo fetch --locked --target host-tuple
    
      40}
    
      41
    
      42pkgver() {
    
      43	cd "$_pkgname"
    
      44	git describe --long --tags --abbrev=7 --match="v*" HEAD |
    
      45			sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      46}
    
      47
    
      48build() {
    
      49	_srcenv
    
      50	cargo build --frozen --release
    
      51}
    
      52
    
      53package() {
    
      54	depends+=(libgcc_s.so)
    
      55	cd "$_pkgname"
    
      56	install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$_pkgname"{,-cli}
    
      57	install -Dm0644 -t "$pkgdir/usr/share/applications/" "packaging/linux/ai.storyteller.$_pkgname.desktop"
    
      58	install -Dm0644 -t "$pkgdir/usr/share/mime/packages/" "packaging/linux/ai.storyteller.$_pkgname.mime.xml"
    
      59	install -Dm0644 -t "$pkgdir/usr/share/icons/hicolor/scalable/" assets/app-icon/hicolor/scalable/apps/ai.storyteller.$_pkgname.svg
    
      60	for s in ${_icons[@]}; do
    
      61		local dim="${s}x${s}"
    
      62		install -Dm0644 -t "$pkgdir/usr/share/icons/hicolor/$dim/apps/" assets/app-icon/hicolor/$dim/apps/ai.storyteller.$_pkgname.png
    
      63	done
    
      64	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE-{APACHE,MIT}
    
      65}
    
      66

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-07 14:05:47	Low	1