lightway-core-doc-git

LOW

maintainer dbermond 0 votes base lightway-core-git scanned 2026-09-17 00:27:14.276658

View on AUR

Why flagged

The package builds from the project's own source repositories and official release infrastructure; the flagged pip/external install via variable is actually a gem install of a specific, versioned, trusted Ruby tool (ceedling) required for building the project, posing no supply-chain risk.

Triggered rules

Low AI review downgraded a static finding llm_review

The static rules flagged this MEDIUM, but an AI model (qwen/qwen3-235b-a22b-07-25) reviewed the full PKGBUILD and judged it LOW (confidence 90%): The package builds from the project's own source repositories and official release infrastructure; the flagged pip/external install via variable is actually a gem install of a specific, versioned, trusted Ruby tool (ceedling) required for building the project, posing no supply-chain risk.

PKGBUILD:47 gem install --no-user-install --install-dir "$_ruby_root" ceedling -v "$_ceedling_ver"

1 higher static finding superseded - not the current verdict (shown for transparency)

Medium External install via pipx/uv/poetry/cargo/go/gem alt_pkg_manager_install

A non-pip/npm package manager (pipx, uv, poetry, cargo install, go install, gem, conda…) fetches and builds an external package at build time, outside source=() and makepkg's checksums.

PKGBUILD:47 gem install --no-user-install --install-dir "$_ruby_root" ceedling -v "$_ceedling_ver"

PKGBUILD

1 offending line(s) highlighted

      1# Maintainer: Daniel Bermond <dbermond@archlinux.org>
    
      2
    
      3pkgbase=lightway-core-git
    
      4pkgname=('lightway-core-git' 'lightway-core-doc-git')
    
      5pkgver=1.17.5.r0.gcf9ba8a
    
      6pkgrel=2
    
      7_ruby_ver=3.1.6
    
      8_ceedling_ver=0.31.1
    
      9pkgdesc='A VPN protocol by ExpressVPN (git version)'
    
      10arch=('x86_64')
    
      11url='https://www.expressvpn.com/lightway/'
    
      12license=('GPL-2.0-or-later')
    
      13makedepends=('git' 'cmake' 'doxygen' 'graphviz')
    
      14source=('git+https://github.com/expressvpn/lightway-core.git'
    
      15        'git+https://github.com/wolfSSL/wolfssl.git'
    
      16        "https://cache.ruby-lang.org/pub/ruby/${_ruby_ver%.*}/ruby-${_ruby_ver}.tar.xz"
    
      17        '010-lightway-core-disable-werror-on-wolfssl.patch')
    
      18sha256sums=('SKIP'
    
      19            'SKIP'
    
      20            '597bd1849f252d8a6863cb5d38014ac54152b508c36dca156f6356a9e63c6102'
    
      21            'fd82affc9e605a7963e5b4908d8decc877980ac007f9ba5aabeccf9019cf5727')
    
      22
    
      23prepare() {
    
      24    local _wolfssl_tag
    
      25    _wolfssl_tag="$(awk '/HE_WOLFSSL_TAG/ { print $3 }' lightway-core/3rd_party_deps.yml)"
    
      26    git -C wolfssl config --local advice.detachedHead false
    
      27    git -C wolfssl checkout --quiet "$_wolfssl_tag"
    
      28    
    
      29    patch -d wolfssl -Np1 -i "${srcdir}/010-lightway-core-disable-werror-on-wolfssl.patch"
    
      30    
    
      31    mkdir -p lightway-core/third_party
    
      32    cp -af wolfssl lightway-core/third_party
    
      33}
    
      34
    
      35pkgver() {
    
      36    git -C lightway-core describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
    
      37}
    
      38
    
      39build() {
    
      40    local _ruby_root="${srcdir}/ruby/${_ruby_ver}"
    
      41    export GEM_HOME="$_ruby_root"
    
      42    export GEM_PATH="$_ruby_root"
    
      43    export PATH="${_ruby_root}/bin${PATH:+":${PATH}"}"
    
      44    cd "ruby-${_ruby_ver}"
    
      45    ./configure --prefix="$_ruby_root" --enable-shared
    
      46    make install
    
      47    gem install --no-user-install --install-dir "$_ruby_root" ceedling -v "$_ceedling_ver"
    
      48    
    
      49    export CFLAGS+=' -ffat-lto-objects'
    
      50    [ -z "$LC_ALL" ] && export LC_ALL='C'
    
      51    cd ../lightway-core
    
      52    ceedling release project:linux
    
      53    doxygen
    
      54}
    
      55
    
      56check() {
    
      57    local _ruby_root="${srcdir}/ruby/${_ruby_ver}"
    
      58    export GEM_HOME="$_ruby_root"
    
      59    export GEM_PATH="$_ruby_root"
    
      60    export PATH="${_ruby_root}/bin${PATH:+":${PATH}"}"
    
      61    
    
      62    cd lightway-core
    
      63    ceedling test project:linux
    
      64}
    
      65
    
      66package_lightway-core-git() {
    
      67    provides=('lightway-core')
    
      68    conflicts=('lightway-core')
    
      69    
    
      70    install -D -m644 lightway-core/build/release/*.a -t "${pkgdir}/usr/lib"
    
      71    install -d -m755 "${pkgdir}/usr/include"
    
      72    cp -dr --no-preserve='ownership' lightway-core/public "${pkgdir}/usr/include/libhelium"
    
      73}
    
      74
    
      75package_lightway-core-doc-git() {
    
      76    pkgdesc="$(sed 's/(\(git\)/(documentation; \1/' <<< "$pkgdesc")"
    
      77    arch=('any')
    
      78    provides=('lightway-core-doc')
    
      79    conflicts=('lightway-core-doc')
    
      80    
    
      81    install -d -m755 "${pkgdir}/usr/share/doc"
    
      82    cp -dr --no-preserve='ownership' lightway-core/html "${pkgdir}/usr/share/doc/lightway-core"
    
      83}
    
      84

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-17 00:27:14	Low	2
2026-09-16 00:03:17	Low	2
2026-09-15 00:25:31	Low	2
2026-09-14 00:27:57	Low	2
2026-09-13 00:19:54	Low	2
2026-09-12 00:25:17	Low	2
2026-09-11 00:19:22	Low	2
2026-09-10 00:22:44	Low	2
2026-09-09 00:04:09	Low	2
2026-09-08 00:18:08	Low	2
2026-09-07 00:30:15	Low	2
2026-09-06 00:17:06	Low	2
2026-09-05 00:16:27	Low	2
2026-09-04 00:03:13	Low	2
2026-09-03 00:15:47	Low	2
2026-09-02 00:02:31	Low	2
2026-09-01 00:11:19	Low	2
2026-08-31 00:19:57	Low	2
2026-08-30 00:04:14	Low	2
2026-08-29 00:29:17	Low	2