linux-trackpad-driver-git
LOW
maintainer aaronroque
0 votes
scanned 2026-10-18 01:20:44.235951
Why flagged
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
Triggered rules
Low
Few votes, recently uploaded
zero_votes_recent
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
PKGBUILD
1
# Maintainer: Aaron Roque Fonseca <https://github.com/aaronroquefonseca>
2
# AUR package `linux-trackpad-driver-git` (VCS snapshot of main).
3
#
4
# Publish: copy this file as PKGBUILD plus ltd.install into the separate AUR
5
# repo `linux-trackpad-driver-git`, then `makepkg --printsrcinfo > .SRCINFO`.
6
# Do not repush for mere pkgver bumps (see AUR VCS guidelines); pkgver()
7
# auto-updates on build. Pre-first-tag fallback is plain `r<revcount>.<hash>`
8
# so it sorts below the first `0.1.0.r...` tag build (no version rollback).
9
10
pkgname=linux-trackpad-driver-git
11
pkgver=r214.b01ae61
12
pkgrel=1
13
pkgdesc="Extensible userspace Linux driver for enhanced trackpad functionality, currently supporting Apple Magic Trackpad 2 — git snapshot"
14
arch=('x86_64' 'aarch64')
15
url="https://github.com/aaronroquefonseca/linux-trackpad-driver"
16
license=('MIT' 'Apache-2.0')
17
depends=('gcc-libs' 'glibc' 'systemd')
18
makedepends=('cargo' 'git')
19
optdepends=('libinput: pointer/palm processing for passthrough events and hwdb quirks (see INSTALL.md "hwdb note")')
20
provides=('linux-trackpad-driver')
21
conflicts=('linux-trackpad-driver' 'linux-trackpad-driver-bin')
22
backup=('etc/linux-trackpad-driver/config.toml')
23
install=ltd.install
24
source=("${pkgname}::git+https://github.com/aaronroquefonseca/linux-trackpad-driver.git")
25
sha256sums=('SKIP')
26
27
pkgver() {
28
cd "${pkgname}"
29
( set -o pipefail
30
git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
31
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
32
)
33
}
34
35
prepare() {
36
cd "${pkgname}"
37
export RUSTUP_TOOLCHAIN=stable
38
cargo fetch --locked --target "$(rustc -vV | sed -n 's|host: ||p')"
39
}
40
41
build() {
42
cd "${pkgname}"
43
export RUSTUP_TOOLCHAIN=stable
44
export CARGO_TARGET_DIR=target
45
cargo build --frozen --release --all-features
46
}
47
48
check() {
49
cd "${pkgname}"
50
export RUSTUP_TOOLCHAIN=stable
51
cargo test --frozen --all-features
52
}
53
54
package() {
55
cd "${pkgname}"
56
57
install -Dm755 "target/release/ltd" "${pkgdir}/usr/bin/ltd"
58
install -Dm644 "config/default.toml" "${pkgdir}/etc/linux-trackpad-driver/config.toml"
59
install -Dm644 "udev/99-linux-trackpad-driver.rules" "${pkgdir}/usr/lib/udev/rules.d/99-linux-trackpad-driver.rules"
60
install -Dm644 "systemd/linux-trackpad-driver.service" "${pkgdir}/usr/lib/systemd/system/linux-trackpad-driver.service"
61
install -Dm644 "systemd/linux-trackpad-driver-reconnect@.service" "${pkgdir}/usr/lib/systemd/system/linux-trackpad-driver-reconnect@.service"
62
install -Dm644 "systemd/linux-trackpad-driver-resume.service" "${pkgdir}/usr/lib/systemd/system/linux-trackpad-driver-resume.service"
63
install -Dm755 "systemd/system-sleep/ltd-resume" "${pkgdir}/usr/lib/systemd/system-sleep/ltd-resume"
64
install -Dm644 "LICENSE-MIT" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-MIT"
65
install -Dm644 "LICENSE-APACHE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-APACHE"
66
}
67
Scan history
| Scanned at (UTC) | Severity | Rules |
|---|---|---|
| 2026-10-18 01:20:44 | Low | 1 |