luatos-mcp-git

LOW
maintainer taotieren 0 votes base luatos-cli-git scanned 2026-09-10 09:20:32.972965
View on AUR
Why flagged
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
Triggered rules

Low Few votes, recently uploaded zero_votes_recent
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
PKGBUILD

      1# Maintainer: taotieren <admin@taotieren.com>
    
      2
    
      3pkgbase=luatos-cli-git
    
      4pkgname=(luatos-cli-git luatos-mcp-git luatos-log-ffi-git)
    
      5pkgver=1.11.0.r0.g22a8f95
    
      6pkgrel=1
    
      7pkgdesc="LuatOS command-line toolset (pure Rust)-brushing, logging, project management, firmware resources and builds"
    
      8arch=($CARCH)
    
      9url="https://github.com/wendal/luatos-cli"
    
      10license=('MIT')
    
      11depends=(
    
      12    glibc
    
      13    libbz2.so
    
      14    libgcc_s.so
    
      15    liblzma.so
    
      16    systemd-libs
    
      17)
    
      18makedepends=(
    
      19    git
    
      20    rust
    
      21    pkgconf
    
      22)
    
      23optdepends=(
    
      24    "ch343ser-dkms"
    
      25    "libftdi: A library to talk to FTDI chips"
    
      26)
    
      27backup=()
    
      28options=('!lto')
    
      29install=
    
      30source=("${pkgbase}::git+${url}.git"
    
      31        luatos-cli.install
    
      32        luatos-mcp.install
    
      33        luatos-log-ffi.install)
    
      34sha256sums=('SKIP'
    
      35            '028878803a8de1324da183486e04457b413417d6af7396f86deae87929232904'
    
      36            '62097f257e96bb89ba585211451b6df9d168f96842289d757a190c34465b9ac7'
    
      37            '6c38d27bc0d64be9576a0189ab750fb762205622886ed35725d177a4f6f4526d')
    
      38
    
      39pkgver() {
    
      40    cd "${srcdir}/${pkgbase}"
    
      41    (
    
      42        set -o pipefail
    
      43        git describe --long --tag --abbrev=7 2>/dev/null | sed 's/^v//g;s/\([^-]*-g\)/r\1/;s/-/./g' ||
    
      44            printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
    
      45    )
    
      46}
    
      47
    
      48prepare() {
    
      49    git -C "${srcdir}/${pkgbase}" clean -dfx
    
      50    cd "${srcdir}/${pkgbase}/"
    
      51    cargo update -w
    
      52    cargo fetch --locked --target host-tuple
    
      53    cargo fetch --target "$CARCH-unknown-linux-gnu"
    
      54}
    
      55
    
      56build() {
    
      57    cd "${srcdir}/${pkgbase}/"
    
      58
    
      59    export RUSTUP_TOOLCHAIN=stable
    
      60    export CARGO_TARGET_DIR=target
    
      61
    
      62    cargo build --release --all-features
    
      63    # cargo build --release --all-features -p luatos-cli
    
      64}
    
      65
    
      66# check() {
    
      67#     cd "${srcdir}/${pkgbase}/"
    
      68
    
      69#     export RUSTUP_TOOLCHAIN=stable
    
      70#     cargo test --all-features
    
      71# }
    
      72
    
      73package_luatos-cli-git() {
    
      74    provides=(${pkgname%-git})
    
      75    conflicts=(${pkgname%-git})
    
      76    replaces=()
    
      77    install=${pkgname%-git}.install
    
      78    cd "${srcdir}/${pkgbase}/"
    
      79
    
      80    export RUSTUP_TOOLCHAIN=stable
    
      81    install -Dm0644 LICENSE* -t "${pkgdir}/usr/share/licenses/${pkgname}/"
    
      82    install -Dm0644 *.md -t "${pkgdir}/usr/share/doc/${pkgname}/"
    
      83    cp -rv docs "${pkgdir}/usr/share/doc/${pkgname}/"
    
      84    install -Dm0755 "target/release/${pkgname%-git}" -t "${pkgdir}/usr/bin/"
    
      85}
    
      86
    
      87package_luatos-mcp-git() {
    
      88    pkgdesc="LuatOS MCP server - exposes flash/log/project tools to AI agents over stdio"
    
      89    provides=(${pkgname%-git})
    
      90    conflicts=(${pkgname%-git})
    
      91    replaces=()
    
      92    depends+=(
    
      93        luatos-cli
    
      94    )
    
      95    install=${pkgname%-git}.install
    
      96    cd "${srcdir}/${pkgbase}/"
    
      97
    
      98    install -Dm0644 LICENSE* -t "${pkgdir}/usr/share/licenses/${pkgname}/"
    
      99    install -Dm0755 "target/release/${pkgname%-git}" -t "${pkgdir}/usr/bin/"
    
      100}
    
      101
    
      102package_luatos-log-ffi-git() {
    
      103    pkgdesc="C ABI export of luatos-log SOC binary log decoder (Air1601/CCM4211)"
    
      104    provides=(libluatos_log_ffi.so)
    
      105    conflicts=(libluatos_log_ffi.so)
    
      106    replaces=()
    
      107    depends=(
    
      108        glibc
    
      109        libgcc_s.so
    
      110    )
    
      111    install=${pkgname%-git}.install
    
      112    cd "${srcdir}/${pkgbase}/"
    
      113
    
      114    export RUSTUP_TOOLCHAIN=stable
    
      115    install -vDm0644 LICENSE* -t "${pkgdir}/usr/share/licenses/${pkgname}/"
    
      116    install -vDm0644 *.md -t "${pkgdir}/usr/share/doc/${pkgname}/"
    
      117
    
      118    install -vDm0755 "target/release/libluatos_log_ffi.so" -t "${pkgdir}/usr/lib/"
    
      119    install -vDm0644 "crates/luatos-log-ffi/include/luatos_log.h" -t "${pkgdir}/usr/include/"
    
      120
    
      121    install -vDm0644 /dev/stdin "${pkgdir}/usr/lib/pkgconfig/${pkgname%-git}.pc" <<EOF
    
      122prefix=/usr
    
      123exec_prefix=\${prefix}
    
      124libdir=\${prefix}/lib
    
      125includedir=\${prefix}/include
    
      126
    
      127Name: ${pkgname%-git}
    
      128Description: ${pkgdesc}
    
      129Version: ${pkgver%%.r*}
    
      130URL: ${url}
    
      131Libs: -L\${libdir} -lluatos_log_ffi
    
      132Cflags: -I\${includedir}
    
      133EOF
    
      134
    
      135    install -vDm0644 /dev/stdin "${pkgdir}/usr/lib/cmake/${pkgname%-git}/${pkgname%-git}Config.cmake" <<EOF
    
      136# ${pkgname%-git}Config.cmake -- CMake package configuration
    
      137#
    
      138# Imported target:
    
      139#   ${pkgname%-git}::${pkgname%-git}      shared library, C ABI
    
      140#
    
      141# Usage:
    
      142#   find_package(${pkgname%-git} REQUIRED)
    
      143#   target_link_libraries(my_app PRIVATE ${pkgname%-git}::${pkgname%-git})
    
      144#
    
      145# Decoded symbols: luatos_soclog_analyze(), pySoclogAnalyze() (alias),
    
      146#                  luatos_soclog_version()
    
      147
    
      148get_filename_component(_luatos_log_ffi_dir "\${CMAKE_CURRENT_LIST_FILE}" DIRECTORY)
    
      149get_filename_component(_luatos_log_ffi_prefix "\${_luatos_log_ffi_dir}/../../.." ABSOLUTE)
    
      150
    
      151if(NOT TARGET ${pkgname%-git}::${pkgname%-git})
    
      152  add_library(${pkgname%-git}::${pkgname%-git} SHARED IMPORTED)
    
      153  set_target_properties(${pkgname%-git}::${pkgname%-git} PROPERTIES
    
      154    IMPORTED_LOCATION "\${_luatos_log_ffi_prefix}/lib/libluatos_log_ffi.so"
    
      155    INTERFACE_INCLUDE_DIRECTORIES "\${_luatos_log_ffi_prefix}/include"
    
      156  )
    
      157endif()
    
      158
    
      159set(${pkgname%-git}_FOUND TRUE)
    
      160set(${pkgname%-git}_VERSION "${pkgver%%.r*}")
    
      161set(${pkgname%-git}_INCLUDE_DIRS "\${_luatos_log_ffi_prefix}/include")
    
      162set(${pkgname%-git}_LIBRARIES "\${_luatos_log_ffi_prefix}/lib/libluatos_log_ffi.so")
    
      163EOF
    
      164
    
      165    install -vDm0644 /dev/stdin "${pkgdir}/usr/lib/cmake/${pkgname%-git}/${pkgname%-git}ConfigVersion.cmake" <<EOF
    
      166set(PACKAGE_VERSION "${pkgver%%.r*}")
    
      167
    
      168if(PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION)
    
      169  set(PACKAGE_VERSION_COMPATIBLE FALSE)
    
      170else()
    
      171  set(PACKAGE_VERSION_COMPATIBLE TRUE)
    
      172  if(PACKAGE_FIND_VERSION VERSION_EQUAL PACKAGE_VERSION)
    
      173    set(PACKAGE_VERSION_EXACT TRUE)
    
      174  endif()
    
      175endif()
    
      176EOF
    
      177}
    
      178
Scan history

Scanned at (UTC)	Severity	Rules
2026-09-10 09:20:32	Low	1