melody-agent-git
LOW
maintainer Rasi
0 votes
base
melody-git
scanned 2026-09-20 19:33:19.533630
Why flagged
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
Triggered rules
Low
Few votes, recently uploaded
zero_votes_recent
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
PKGBUILD
1
# Maintainer: Rasmus Steinke <rasi@xssn.at>
2
pkgbase=melody-git
3
pkgname=(melody-git melodyd-git melody-agent-git melody-tui-git melody-cli-git
4
melody-musiclist-git melody-lrcmatch-git melody-watcher-git melody-rofi-git)
5
pkgver=r116.gacab9f7
6
pkgrel=1
7
pkgdesc='Music server and clients with MPD support (built from HEAD)'
8
arch=(x86_64 aarch64)
9
url='https://github.com/carnager/melody-music'
10
license=(GPL-3.0-only)
11
makedepends=(git go)
12
checkdepends=(ffmpeg mpv)
13
source=("melody::git+https://github.com/carnager/melody-music.git")
14
sha256sums=('SKIP')
15
16
pkgver() {
17
cd melody
18
printf 'r%s.g%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
19
}
20
21
build() {
22
cd melody
23
export CGO_ENABLED=1
24
export GOFLAGS='-trimpath -mod=readonly -buildvcs=false'
25
./build
26
}
27
28
check() {
29
cd melody
30
go test ./...
31
}
32
33
_install_binary() {
34
install -Dm755 "$srcdir/melody/bin/$1" "$pkgdir/usr/bin/$1"
35
install -Dm644 "$srcdir/melody/docs/clients.md" "$pkgdir/usr/share/doc/$pkgname/clients.md"
36
install -Dm644 "$srcdir/melody/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
37
}
38
39
package_melody-git() {
40
pkgdesc='All Melody components (metapackage)'
41
depends=(melodyd-git melody-agent-git melody-tui-git melody-cli-git
42
melody-musiclist-git melody-lrcmatch-git melody-watcher-git melody-rofi-git)
43
}
44
45
package_melodyd-git() {
46
pkgdesc='Melody music server with MPD support'
47
depends=(glibc ffmpeg mpv)
48
optdepends=('flac: embed downloaded lyrics into FLAC files')
49
provides=(melodyd)
50
conflicts=(melodyd)
51
install=melody.install
52
_install_binary melodyd
53
install -Dm644 "$srcdir/melody/melodyd/melodyd.service" "$pkgdir/usr/lib/systemd/user/melodyd.service"
54
install -Dm644 "$srcdir/melody/docs/melodyd.md" "$pkgdir/usr/share/doc/$pkgname/melodyd.md"
55
}
56
57
package_melody-agent-git() {
58
pkgdesc='Remote playback agent for Melody'
59
depends=(glibc mpv)
60
provides=(melody-agent)
61
conflicts=(melody-agent)
62
_install_binary melody-agent
63
}
64
65
package_melody-tui-git() {
66
pkgdesc='Terminal UI for Melody'
67
depends=(glibc)
68
provides=(melody-tui)
69
conflicts=(melody-tui)
70
_install_binary melody-tui
71
}
72
73
package_melody-cli-git() {
74
pkgdesc='Command-line client for Melody'
75
depends=(glibc)
76
provides=(melody-cli)
77
conflicts=(melody-cli)
78
_install_binary melody-cli
79
}
80
81
package_melody-musiclist-git() {
82
pkgdesc='Static music list exporter for Melody'
83
depends=(glibc openssh)
84
provides=(melody-musiclist)
85
conflicts=(melody-musiclist)
86
_install_binary melody-musiclist
87
}
88
89
package_melody-lrcmatch-git() {
90
pkgdesc='Offline lyrics matcher for Melody'
91
depends=(glibc)
92
provides=(melody-lrcmatch)
93
conflicts=(melody-lrcmatch)
94
_install_binary melody-lrcmatch
95
}
96
97
package_melody-watcher-git() {
98
pkgdesc='Filesystem watcher for a remote Melody library'
99
depends=(glibc)
100
provides=(melody-watcher)
101
conflicts=(melody-watcher)
102
_install_binary melody-watcher
103
}
104
105
package_melody-rofi-git() {
106
pkgdesc='Menu client for Melody'
107
depends=(glibc)
108
optdepends=('rofi: default menu launcher (custom launchers can be configured)')
109
provides=(melody-rofi)
110
conflicts=(melody-rofi)
111
_install_binary melody-rofi
112
}
113
Scan history
| Scanned at (UTC) | Severity | Rules |
|---|---|---|
| 2026-09-20 19:33:19 | Low | 1 |