mips64-elf-gcc-stage1

maintainer simer · 2 votes · scanned 2026-08-03 00:08:14.047287

LOW

Why flagged The source URLs point to official project domains (gcc.gnu.org and libisl.sourceforge.io), which are legitimate hosts for GCC and ISL, despite not being on a standard whitelist; the package builds a stage1 cross-compiler from trusted upstream sources, posing no execution risk beyond normal AUR builds.

Triggered rules

LOW AI review downgraded a static finding llm_review

The static rules flagged this MEDIUM, but an AI model (qwen/qwen3-235b-a22b-07-25) reviewed the full PKGBUILD and judged it LOW (confidence 95%): The source URLs point to official project domains (gcc.gnu.org and libisl.sourceforge.io), which are legitimate hosts for GCC and ISL, despite not being on a standard whitelist; the package builds a stage1 cross-compiler from trusted upstream sources, posing no execution risk beyond normal AUR builds.

1 higher static finding superseded - not the current verdict (shown for transparency)

MEDIUM source=() URL on a non-standard host source_untrusted_domain

One or more source=() URLs point to a host outside the trusted allowlist (github.com, gitlab.com, codeberg.org, pypi.org, …).

PKGBUILD:18 "https://libisl.sourceforge.io/isl-${_islver}.tar.xz"

PKGBUILD

1 offending line(s) highlighted

      1# Maintainer: Simon Eriksson <simon.eriksson.1187+aur AT gmail.com>
    
      2# Contributor: Joey Dumont <joey.dumont@gmail.com>
    
      3
    
      4_target=mips64-elf
    
      5pkgname=${_target}-gcc-stage1
    
      6pkgver=14.4.0
    
      7_islver=0.26
    
      8pkgrel=1
    
      9pkgdesc="The GNU Compiler Collection. Stage 1 for toolchain building (${_target})"
    
      10arch=('x86_64')
    
      11license=('GPL' 'LGPL' 'FDL' 'custom')
    
      12url="http://www.gnu.org/software/gcc/"
    
      13depends=('libmpc' 'zstd' )
    
      14makedepends=('gmp' 'mpfr' "${_target}-binutils")
    
      15optdepends=("${_target}-newlib: Standard C library optimized for embedded systems")
    
      16options=('!emptydirs' '!strip')
    
      17source=("http://gcc.gnu.org/pub/gcc/releases/gcc-${pkgver}/gcc-${pkgver}.tar.xz"
    
      18        "https://libisl.sourceforge.io/isl-${_islver}.tar.xz"
    
      19        "mabi32.patch")
    
      20sha256sums=('752b6f567beac83159c77a7680b1316bdd784738bff9a9d070112c09da90f6d9'
    
      21            'a0b5cb06d24f9fa9e77b55fabbe9a3c94a336190345c2555f9915bb38e976504'
    
      22            '86c06dfb12295e665204441ca17440d4e597da24b6cffad052c94268ec562169')
    
      23
    
      24prepare() {
    
      25  cd gcc-${pkgver}
    
      26
    
      27  # link isl for in-tree builds
    
      28  ln -sf ../isl-$_islver isl
    
      29
    
      30  # Do not run fixincludes
    
      31  sed -i 's@\./fixinc\.sh@-c true@' gcc/Makefile.in
    
      32
    
      33  # hack! - some configure tests for header files using "$CPP $CPPFLAGS"
    
      34  sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" {libiberty,gcc}/configure
    
      35
    
      36  # patch multilib support for mabi=32
    
      37  patch --strip=1 --input="${srcdir}"/mabi32.patch
    
      38
    
      39  rm -rf "$srcdir"/build-gcc
    
      40  mkdir "$srcdir"/build-gcc
    
      41}
    
      42
    
      43build() {
    
      44  cd build-gcc
    
      45
    
      46  export CFLAGS_FOR_TARGET="-G0 -Os -pipe"
    
      47  export CXXFLAGS_FOR_TARGET="-G0 -Os -pipe"
    
      48
    
      49  CFLAGS=${CFLAGS/-Werror=format-security/}
    
      50  CXXFLAGS=${CXXFLAGS/-Werror=format-security/}
    
      51
    
      52  "${srcdir}"/gcc-${pkgver}/configure \
    
      53    --prefix=/usr \
    
      54    --target=${_target} \
    
      55    --host="$CHOST" \
    
      56    --build="$CHOST" \
    
      57    --with-arch=from-abi \
    
      58    --with-sysroot=/usr/${_target} \
    
      59    --libdir=/usr/lib \
    
      60    --libexecdir=/usr/lib \
    
      61    --with-gnu-as \
    
      62    --with-gnu-ld \
    
      63    --with-python-dir=share/gcc-${_target} \
    
      64    --with-newlib \
    
      65    --without-headers \
    
      66    --without-included-gettext \
    
      67    --enable-checking=release \
    
      68    --enable-languages=c \
    
      69    --enable-lto \
    
      70    --enable-multilib \
    
      71    --enable-plugin \
    
      72    --disable-decimal-float \
    
      73    --disable-gold \
    
      74    --disable-libatomic \
    
      75    --disable-libgcj \
    
      76    --disable-libgomp \
    
      77    --disable-libitm \
    
      78    --disable-libquadmath \
    
      79    --disable-libquadmath-support \
    
      80    --disable-libsanitizer \
    
      81    --disable-libssp \
    
      82    --disable-libunwind-exceptions \
    
      83    --disable-libvtv \
    
      84    --disable-nls \
    
      85    --disable-shared \
    
      86    --disable-werror
    
      87
    
      88  make all-gcc all-target-libgcc
    
      89}
    
      90
    
      91package() {
    
      92  cd build-gcc
    
      93
    
      94  make install-strip-gcc install-strip-target-libgcc DESTDIR="$pkgdir"
    
      95
    
      96  # Remove files that conflict with host gcc package
    
      97  rm -r "$pkgdir"/usr/{include,share}
    
      98}
    
      99

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-03 00:08:14	LOW	2
2026-08-02 00:16:08	LOW	2
2026-08-01 00:11:18	LOW	2
2026-07-31 00:14:10	LOW	2
2026-07-30 00:17:23	LOW	2
2026-07-29 00:25:53	LOW	2
2026-07-28 00:07:28	LOW	2
2026-07-27 00:24:32	LOW	2
2026-07-26 00:07:32	LOW	2
2026-07-25 00:13:44	LOW	2
2026-07-24 00:02:28	LOW	2
2026-07-23 00:14:47	LOW	2
2026-07-22 00:29:32	LOW	2
2026-07-21 00:24:15	LOW	2
2026-07-20 00:19:49	LOW	2
2026-07-19 00:17:08	LOW	2
2026-07-18 00:14:48	LOW	2
2026-07-17 00:06:16	LOW	2
2026-07-16 00:05:41	LOW	2
2026-07-15 00:09:25	LOW	2