mlp-gui

LOW

maintainer MasketLP 0 votes scanned 2026-09-21 19:35:51.541891

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: MasketLP
    
      2#
    
      3# pkgver is rewritten from the release tag, and checksums by updpkgsums, by
    
      4# packaging/aur/publish.sh on every release.
    
      5pkgname=mlp-gui
    
      6pkgver=0.5.0
    
      7pkgrel=1
    
      8pkgdesc='Desktop app to encrypt and decrypt files with AES-256-GCM (GUI for mlp)'
    
      9arch=('x86_64' 'aarch64')
    
      10url='https://github.com/EldinBegano/mask-decryption'
    
      11license=('GPL-3.0-or-later')
    
      12depends=('glibc' 'hicolor-icon-theme' 'libglvnd' 'libx11' 'libxcursor' 'libxi'
    
      13         'libxinerama' 'libxkbcommon' 'libxrandr' 'libxxf86vm' 'wayland')
    
      14makedepends=('go' 'xorgproto')
    
      15checkdepends=('desktop-file-utils')
    
      16optdepends=('mlp: command-line interface using the same keyfile')
    
      17options=('!lto' '!debug')
    
      18source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      19sha256sums=('64c4c12f8cd9d5d7216a1be382daba1892707f475da14cadb36994bc2a862ed0')
    
      20
    
      21prepare() {
    
      22  cd "mask-decryption-$pkgver"
    
      23  export GOPATH="$srcdir/gopath"
    
      24  export GOFLAGS='-modcacherw'
    
      25  go list -deps ./cmd/mlp-gui > /dev/null
    
      26}
    
      27
    
      28build() {
    
      29  cd "mask-decryption-$pkgver"
    
      30  export GOPATH="$srcdir/gopath"
    
      31  export CGO_CPPFLAGS="${CPPFLAGS}"
    
      32  export CGO_CFLAGS="${CFLAGS}"
    
      33  export CGO_CXXFLAGS="${CXXFLAGS}"
    
      34  export CGO_LDFLAGS="${LDFLAGS}"
    
      35  export GOFLAGS='-buildmode=pie -trimpath -mod=readonly -modcacherw'
    
      36  go build -o mlp-gui \
    
      37    -ldflags "-linkmode external -extldflags \"${LDFLAGS}\" -X main.version=${pkgver}" \
    
      38    ./cmd/mlp-gui
    
      39}
    
      40
    
      41check() {
    
      42  cd "mask-decryption-$pkgver"
    
      43  # The window itself can't open in a build chroot; check the parts that can run.
    
      44  test "$(./mlp-gui --version)" = "mlp-gui $pkgver"
    
      45  desktop-file-validate cmd/mlp-gui/assets/mlp-gui.desktop
    
      46}
    
      47
    
      48package() {
    
      49  cd "mask-decryption-$pkgver"
    
      50  install -Dm755 mlp-gui "$pkgdir/usr/bin/mlp-gui"
    
      51  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      52  install -Dm644 cmd/mlp-gui/assets/mlp-gui.desktop "$pkgdir/usr/share/applications/mlp-gui.desktop"
    
      53  install -Dm644 cmd/mlp-gui/assets/mlp-gui.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/mlp-gui.svg"
    
      54}
    
      55

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-21 19:35:51	Low	1