moarchy-contacts

LOW

maintainer simonschubert 0 votes scanned 2026-09-28 11:20:45.263512

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Simon Schubert <simon@librem.one>
    
      2#
    
      3# Contacts as an app: the QML tree in /usr/share/moarchy-contacts, started by
    
      4# /usr/bin/moarchy-contacts. That launcher opens it in the running Omarchy
    
      5# shell when the plugin is installed there, and as its own Quickshell process
    
      6# everywhere else -- so this package needs Quickshell, not Omarchy.
    
      7#
    
      8# 0.1.0 was a shell plugin, copied onto the phone by a script and never
    
      9# packaged; 0.2.0 is the first package, reading and writing the same
    
      10# ~/.local/share/moarchy-contacts/contacts.json.
    
      11pkgname=moarchy-contacts
    
      12pkgver=0.2.0
    
      13pkgrel=1
    
      14pkgdesc='A name, a number, an email and a note, in one file, for Quickshell'
    
      15arch=('any')
    
      16url='https://github.com/SimonSchubert/moarchy-apps'
    
      17license=('MIT')
    
      18# qt6-declarative (QtQuick) comes with quickshell. The kit's icons are Nerd
    
      19# Font glyphs, which namcap cannot see, so it calls that dependency unneeded.
    
      20depends=('quickshell' 'ttf-jetbrains-mono-nerd' 'hicolor-icon-theme')
    
      21# A release asset that packaging/release.sh builds from apps/contacts at the
    
      22# tag, with shared/kit in place of the kit link.
    
      23source=("$url/releases/download/contacts-v$pkgver/$pkgname-$pkgver.tar.gz")
    
      24# Pinned in the commit after the tag, as every app's here is.
    
      25sha256sums=('be7430d958a32db2a8af98c3c6b6248e30ccd99acc252cde8b157b2484d5583d')
    
      26
    
      27check() {
    
      28  cd "$pkgname-$pkgver"
    
      29  # The book and the file. No display needed.
    
      30  QT_QPA_PLATFORM=offscreen /usr/lib/qt6/bin/qmltestrunner -input tests
    
      31}
    
      32
    
      33package() {
    
      34  cd "$pkgname-$pkgver"
    
      35
    
      36  install -d "$pkgdir/usr/share/$pkgname/kit"
    
      37  install -m644 manifest.json ./*.qml ./*.js icon.svg "$pkgdir/usr/share/$pkgname/"
    
      38  install -m644 kit/*.qml kit/*.js "$pkgdir/usr/share/$pkgname/kit/"
    
      39
    
      40  install -Dm755 bin/moarchy-contacts "$pkgdir/usr/bin/moarchy-contacts"
    
      41  install -Dm644 org.moarchy.Contacts.desktop \
    
      42    "$pkgdir/usr/share/applications/org.moarchy.Contacts.desktop"
    
      43  install -Dm644 icon.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/org.moarchy.Contacts.svg"
    
      44  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      45}
    
      46

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-28 11:20:45	Low	1