moarchy-editor

LOW

maintainer simonschubert 0 votes scanned 2026-09-28 11:20:45.263512

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Simon Schubert <simon@librem.one>
    
      2#
    
      3# Text Editor as an app: the QML tree in /usr/share/moarchy-editor, started by
    
      4# /usr/bin/moarchy-editor. That launcher opens a file in the running Omarchy
    
      5# shell when the plugin is installed there, and in its own Quickshell process
    
      6# everywhere else -- so this package needs Quickshell, not Omarchy. With
    
      7# --wait it is an $EDITOR: it returns when the file is closed.
    
      8#
    
      9# The first package of it: 0.1.0 was a shell plugin only, copied onto a phone
    
      10# by hand. 0.2.0 reads the state.json that plugin wrote.
    
      11pkgname=moarchy-editor
    
      12pkgver=0.2.0
    
      13pkgrel=1
    
      14pkgdesc='One text file at a time, and an $EDITOR that waits, for Quickshell'
    
      15arch=('any')
    
      16url='https://github.com/SimonSchubert/moarchy-apps'
    
      17license=('MIT')
    
      18# qt6-declarative (QtQuick) comes with quickshell. The kit's icons are Nerd
    
      19# Font glyphs, which namcap cannot see, so it calls that dependency unneeded.
    
      20# bash for the launcher's wait loop; coreutils' stat, touch and realpath for
    
      21# the rest, which every base install has.
    
      22depends=('quickshell' 'bash' 'ttf-jetbrains-mono-nerd' 'hicolor-icon-theme')
    
      23# A release asset that packaging/release.sh builds from apps/editor at the
    
      24# tag, with shared/kit in place of the kit link -- not GitHub's generated
    
      25# archive, whose compression has moved under pinned checksums before.
    
      26source=("$url/releases/download/editor-v$pkgver/$pkgname-$pkgver.tar.gz")
    
      27# Pinned in the commit after the tag, as every app's here is.
    
      28sha256sums=('2caa73e129f0bd88d6266391aff8a2a8bf5b22a9e2e91cabb68ac6974eff12f3')
    
      29
    
      30check() {
    
      31  cd "$pkgname-$pkgver"
    
      32  # What a file has to be to be written back exactly, and the list of files.
    
      33  # No display needed.
    
      34  QT_QPA_PLATFORM=offscreen /usr/lib/qt6/bin/qmltestrunner -input tests
    
      35}
    
      36
    
      37package() {
    
      38  cd "$pkgname-$pkgver"
    
      39
    
      40  install -d "$pkgdir/usr/share/$pkgname/kit"
    
      41  install -m644 manifest.json ./*.qml ./*.js icon.svg "$pkgdir/usr/share/$pkgname/"
    
      42  install -m644 kit/*.qml kit/*.js "$pkgdir/usr/share/$pkgname/kit/"
    
      43
    
      44  install -Dm755 bin/moarchy-editor "$pkgdir/usr/bin/moarchy-editor"
    
      45  install -Dm644 org.moarchy.Editor.desktop \
    
      46    "$pkgdir/usr/share/applications/org.moarchy.Editor.desktop"
    
      47  install -Dm644 org.moarchy.Editor.open.desktop \
    
      48    "$pkgdir/usr/share/applications/org.moarchy.Editor.open.desktop"
    
      49  install -Dm644 icon.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/org.moarchy.Editor.svg"
    
      50  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      51}
    
      52

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-28 11:20:45	Low	1