models-git

LOW

maintainer shbernal 0 votes scanned 2026-10-29 17:53:05.425985

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: shbernal <shbernal.01@gmail.com>
    
      2
    
      3_pkgname=models
    
      4pkgname=${_pkgname}-git
    
      5pkgver=0.14.1.r1575.g416a823
    
      6pkgrel=1
    
      7pkgdesc='TUI and CLI for browsing AI models, benchmarks, coding agents and provider statuses'
    
      8arch=('x86_64' 'aarch64')
    
      9url='https://github.com/reyamira/models'
    
      10license=('MIT')
    
      11depends=('glibc' 'libgcc')
    
      12makedepends=('cargo' 'git')
    
      13provides=("${_pkgname}")
    
      14conflicts=("${_pkgname}")
    
      15options=('!lto')
    
      16source=("${_pkgname}::git+${url}.git")
    
      17sha256sums=('SKIP')
    
      18
    
      19pkgver() {
    
      20  cd "${_pkgname}"
    
      21
    
      22  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      23}
    
      24
    
      25prepare() {
    
      26  cd "${_pkgname}"
    
      27
    
      28  export RUSTUP_TOOLCHAIN=stable
    
      29  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      30}
    
      31
    
      32build() {
    
      33  cd "${_pkgname}"
    
      34
    
      35  export RUSTUP_TOOLCHAIN=stable
    
      36  export CARGO_TARGET_DIR=target
    
      37  cargo build --frozen --release
    
      38
    
      39  local shell
    
      40  for shell in bash fish zsh; do
    
      41    target/release/models completions "${shell}" > "completions.${shell}"
    
      42  done
    
      43}
    
      44
    
      45check() {
    
      46  cd "${_pkgname}"
    
      47
    
      48  export RUSTUP_TOOLCHAIN=stable
    
      49  # Asserts a model count band that upstream's data refreshes outgrow
    
      50  cargo test --frozen -- --skip test_committed_aa_json_deserializes_and_helpers_match
    
      51}
    
      52
    
      53package() {
    
      54  cd "${_pkgname}"
    
      55
    
      56  install -Dm755 target/release/models "${pkgdir}/usr/bin/models"
    
      57  install -Dm644 completions.bash "${pkgdir}/usr/share/bash-completion/completions/models"
    
      58  install -Dm644 completions.fish "${pkgdir}/usr/share/fish/vendor_completions.d/models.fish"
    
      59  install -Dm644 completions.zsh "${pkgdir}/usr/share/zsh/site-functions/_models"
    
      60  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      61  install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
    
      62}
    
      63

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-29 17:53:05	Low	1