morgan-git

LOW

maintainer martillo.bolas 0 votes scanned 2026-10-18 13:22:09.532316

View on AUR

Why flagged

Package builds from a public git repository of a desktop shell for Hyprland with normal AUR packaging practices; low severity due to few votes and recent upload, but no malicious patterns detected.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 90%): Package builds from a public git repository of a desktop shell for Hyprland with normal AUR packaging practices; low severity due to few votes and recent upload, but no malicious patterns detected.

PKGBUILD

      1# Paquete de Arch de morgan, compilado desde la punta de main. El de la última versión ya
    
      2# compilada es morgan-bin (dist/arch/morgan-bin). Sin paquete: install.sh, en la raíz del repo.
    
      3#
    
      4#   makepkg -si
    
      5#
    
      6# El árbol que se instala lo arma dist/empaquetar, el mismo que usa morgan-bin.
    
      7#
    
      8# Lo que el paquete no puede hacer por cada usuario lo hace `morgan setup` (lo dice
    
      9# morgan.install al instalar).
    
      10
    
      11pkgname=morgan-git
    
      12_nombre=morgan
    
      13pkgver=0.1.0.r0.ge30ec2e
    
      14pkgrel=1
    
      15pkgdesc='Shell de escritorio para Hyprland: barra, centro de control, notificaciones, launcher, OSD y bloqueo'
    
      16arch=('x86_64' 'aarch64')
    
      17url='https://github.com/ImJustDoingMyPart/morgan'
    
      18# El código, GPL; el tema y las plantillas de /usr/share/morgan, MIT (con sus créditos).
    
      19license=('GPL-3.0-or-later' 'MIT')
    
      20depends=(
    
      21    'hyprland>=0.56'
    
      22    'gtk4>=1:4.22'
    
      23    'gtk4-layer-shell'
    
      24    'libpulse'
    
      25    'glib2'
    
      26    'pam'
    
      27    'systemd'
    
      28    'curl'
    
      29    'wl-clipboard'
    
      30)
    
      31makedepends=('cargo' 'git' 'hyprland-protocols')
    
      32optdepends=(
    
      33    'matugen: temas (también los curados: las plantillas pasan por matugen)'
    
      34    'awww: fondos de pantalla'
    
      35    'libvips: miniaturas de la banda de fondos'
    
      36    'hyprsunset: luz nocturna'
    
      37    'ddcutil: brillo de monitores externos (DDC/CI)'
    
      38    'hyprshot: capturas de pantalla'
    
      39    'cliphist: launcher, portapapeles'
    
      40    'wtype: launcher, escribir símbolos'
    
      41    'libqalculate: calculadora'
    
      42    'rofimoji: launcher, datos de los símbolos'
    
      43    'libcanberra: sonidos del sistema'
    
      44    'uwsm: lanzar apps como unidades de systemd'
    
      45    'gpu-screen-recorder-ui: indicador y control de grabación'
    
      46    'papirus-folders: color de las carpetas del tema de íconos'
    
      47    'jq: morgan-cuota (cuotas de Claude Code y Antigravity)'
    
      48)
    
      49provides=('morgan' 'notification-daemon')
    
      50conflicts=('morgan' 'morgan-bin')
    
      51backup=('etc/pam.d/morgan-lock')
    
      52install=morgan.install
    
      53source=("$_nombre::git+$url.git")
    
      54sha256sums=('SKIP')
    
      55
    
      56pkgver() {
    
      57    cd "$_nombre"
    
      58    # Con una etiqueta vX.Y.Z: X.Y.Z.rN.gHASH (ordena después de morgan-bin X.Y.Z); sin
    
      59    # etiquetas, rN.HASH.
    
      60    if git describe --tags --match 'v*' >/dev/null 2>&1; then
    
      61        git describe --long --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      62    else
    
      63        printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
    
      64    fi
    
      65}
    
      66
    
      67prepare() {
    
      68    cd "$_nombre"
    
      69    export RUSTUP_TOOLCHAIN=stable
    
      70    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      71}
    
      72
    
      73build() {
    
      74    cd "$_nombre"
    
      75    export RUSTUP_TOOLCHAIN=stable
    
      76    export CARGO_TARGET_DIR=target
    
      77    cargo build --frozen --release -p morgan -p morganctl -p morgan-lock
    
      78}
    
      79
    
      80package() {
    
      81    cd "$_nombre"
    
      82    dist/empaquetar "$pkgdir" target/release
    
      83    mv "$pkgdir/usr/share/licenses/morgan" "$pkgdir/usr/share/licenses/$pkgname"
    
      84}
    
      85

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-18 13:22:09	Low	2