mozc-ut-full-common

LOW
maintainer brli 8 votes base mozc-ut-full scanned 2026-09-17 00:27:14.276658
View on AUR
Why flagged

The package downloads source code and data files from project-owned GitHub repositories and Wikimedia; the non-whitelisted hosts are GitHub and wikimedia.org, which are legitimate for these projects, and the downloaded content consists of source code and public data, not prebuilt executables or executable payloads.

Triggered rules

Low AI review downgraded a static finding llm_review

The static rules flagged this MEDIUM, but an AI model (qwen/qwen3-235b-a22b-07-25) reviewed the full PKGBUILD and judged it LOW (confidence 95%): The package downloads source code and data files from project-owned GitHub repositories and Wikimedia; the non-whitelisted hosts are GitHub and wikimedia.org, which are legitimate for these projects, and the downloaded content consists of source code and public data, not prebuilt executables or executable payloads.

1 higher static finding superseded - not the current verdict (shown for transparency)
Medium source=() URL on a non-standard host source_untrusted_domain

One or more source=() URLs point to a host outside the trusted allowlist (github.com, gitlab.com, codeberg.org, pypi.org, …).

  • PKGBUILD:40 git+https://chromium.googlesource.com/breakpad/breakpad
  • PKGBUILD:47 jawiki-latest-pages-articles-multistream-index-${_utdicdate}.txt.bz2::https://dumps.wikimedia.org/jawiki/latest/jawiki-latest-pages-articles-multistream-index.txt.bz2)

PKGBUILD

2 offending line(s) highlighted
1# $Id$
2# shellcheck disable=SC2034,SC2148,SC2154
3# Maintainer: BrLi <brli at chakralinux dot org>
4# Contributor: Jiachen Yang <farseerfc@archlinux.org>
5# Contributor: Felix Yan <felixonmars@archlinux.org>
6# Contributor: ponsfoot <cabezon dot hashimoto at gmail dot com>
7# Contributor: UTUMI Hirosi <utuhiro78 at yahoo dot co dot jp>
8# Contributor: Hiroyuki Komatsu: providing Japan Post zipcode snapshots
9
10## Mozc compile option
11_bldtype='Release'
12_zipcode_rel=202110
13
14# Ut Dictionary
15_utdicdate=20260503
16_dict=(alt-cannadic
17 edict2
18 jawiki
19 neologd
20 personal-names
21 place-names
22 skk-jisyo
23 sudachidict)
24
25pkgbase=mozc-ut-full
26pkgname=("$pkgbase-common" "ibus-$pkgbase" "fcitx5-$pkgbase" "emacs-$pkgbase")
27pkgver=3.33.6133.102.20260503
28pkgrel=2
29arch=('x86_64')
30url="https://github.com/fcitx/mozc"
31license=('custom')
32makedepends=('bazel' 'git' 'python' 'python-six' 'pkg-config' 'curl' 'mesa' 'subversion' 'qt6-base' 'clang' 'fcitx5' 'emacs' 'ibus')
33source=(git+https://github.com/fcitx/mozc.git#commit=a897811b9865e084963dd7ca81e2186ddc7f6403
34 # 2023-07-13: osdn.net is unstable due to Amazon
35 "https://github.com/hiroyuki-komatsu/japanpost_zipcode/raw/refs/heads/main/ken_all.zip"
36 "https://github.com/hiroyuki-komatsu/japanpost_zipcode/raw/refs/heads/main/jigyosyo.zip"
37 # "https://gitlab.com/BrLi/brli-aur/-/raw/fcitx5-mozc-ut/x-ken-all-${_zipcode_rel}.zip"
38 # "https://gitlab.com/BrLi/brli-aur/-/raw/fcitx5-mozc-ut/jigyosyo-${_zipcode_rel}.zip"
39 git+https://github.com/abseil/abseil-cpp.git
40 git+https://chromium.googlesource.com/breakpad/breakpad
41 git+https://github.com/google/googletest.git
42 git+https://chromium.googlesource.com/external/gyp
43 git+https://github.com/hiroyuki-komatsu/japanese-usage-dictionary.git
44 git+https://github.com/open-source-parsers/jsoncpp.git
45 git+https://github.com/google/protobuf.git
46 git+https://github.com/utuhiro78/merge-ut-dictionaries.git
47 jawiki-latest-pages-articles-multistream-index-${_utdicdate}.txt.bz2::https://dumps.wikimedia.org/jawiki/latest/jawiki-latest-pages-articles-multistream-index.txt.bz2)
48noextract=(jawiki-latest-pages-articles-multistream-index-${_utdicdate}.txt.bz2)
49for dict in "${_dict[@]}"; do
50 source+=("mozcdic-ut-${dict}-${_utdicdate}.txt.bz2"::"https://github.com/utuhiro78/mozcdic-ut-${dict}/raw/main/mozcdic-ut-${dict}.txt.bz2")
51 noextract+=("mozcdic-ut-${dict}-${_utdicdate}.txt.bz2")
52done
53sha512sums=('312e94e71bc2445ab8593d96a4311adddedbbf4e9bcf3a36deb95fac93ed74853e2cbe210593cb2cc859c18885d8e52dcac4183703f91bb43b9250747413941b'
54 'd893c137569f008202ec7f7d1871c35641b9c5d502cf35c588ea0a95950af9e2dff891181d5c76ed905201016da6aa855d74c99267d739bd4a966ccda10d6b53'
55 'b99066b666e77babb34d09622261ce2df9ac92d030302487c9873babaf7d25d5519639484a619b87fef1db299ff3f288c63ad04e2b8ae34a81a30d68311c1da4'
56 'SKIP'
57 'SKIP'
58 'SKIP'
59 'SKIP'
60 'SKIP'
61 'SKIP'
62 'SKIP'
63 'SKIP'
64 '68fafd5ad35656b4a7819a3fe15d8c8bdd7d93be57feec7632d6ac3cbb2bbd44dbc57255c74c14f8a38f699bf73f57630e0874c4e317e73eade1353e8034c206'
65 '258549a55dc6d6f8331c08940de7d5784430efe27d64efb66b0b07888d686b5ba72cad95fe8ff836d68a90a5a919493a4fd7c36bb682e8734fa2884369831da6'
66 'd4570230fbec418e6c8dfe16e92d3582768ee6025f0c942a35b605445ed2a2b481c5db0b768feb152b04c5f7b63ec42b0ef01964b0cd4b433a760e344321afae'
67 '4fd70121cdfa9bd3af9b478e953f89bbdea569df2b7c7650543589b71f88aa820e8c8d00a26885b45e3440b48b3bcd0986465203f15daa77cccd1b6911d4b3d1'
68 '2c3317d00faa52980c0069f0655e83681606b6e259044129149bff2ba1b7f17dbfdeeaad832b6d0b2f4935c7fd40bfefec54bbfe04bf189c5868847cc63065f6'
69 '9507bcce1739b97be8cb3164caeab8600f71e53a1b63e55f89815ab2e0cc79aff4b466509613e8bba6f6fae64a99e17f523d5fd75c395893d4b8cfe8bbdad7d2'
70 'fc1a778174f6f2220769dd611fe1669d282f66a0365b6c1b766602554166fbaf61aa3d2b3f19c408984541fa703ad4accd04a85f1e02c101cc41aa805e0cd736'
71 '4841eeee6c073f9d40cb0ca16798918b8a535491b166f3e024228261e7c2d597910c40f5c611205fd17e88034cedbe0298363778007a4c2c254762b40398ec3d'
72 '39faea2085c88f91fd2efbed79bb235979319299dd028b41e5f2b9be613b273828a12af1416907f88cfa9feeb0a74ba46059ae03e4e9b6b1d6100195edf6b74a')
73
74pkgver() {
75 cd "${srcdir}/mozc" || exit
76 source <(grep = src/version.bzl | tr -d ' ')
77 printf "%s.%s.%s.%s.%s" "$MAJOR" "$MINOR" "$BUILD_OSS" "$((REVISION + 2))" "$_utdicdate"
78}
79
80prepare() {
81 mv KEN_ALL.CSV x-ken-all.csv
82
83 cd "$srcdir/mozc" || exit
84
85 # comment out shell-incompatible code, revert at build()
86 sed 's,DEFAULT_BUILD_LABEL_MACOS,#DEFAULT_BUILD_LABEL_MACOS,' -i src/version.bzl
87
88 git config -f .gitmodules submodule.src/third_party/abseil-cpp.url "$srcdir/abseil-cpp"
89 git config -f .gitmodules submodule.src/third_party/breakpad.url "$srcdir/breakpad"
90 git config -f .gitmodules submodule.src/third_party/gtest.url "$srcdir/googletest"
91 git config -f .gitmodules submodule.src/third_party/gyp.url "$srcdir/gyp"
92 git config -f .gitmodules submodule.src/third_party/japanese_usage_dictionary.url "$srcdir/japanese-usage-dictionary"
93 git config -f .gitmodules submodule.src/third_party/jsoncpp.url "$srcdir/jsoncpp"
94 git config -f .gitmodules submodule.src/third_party/protobuf.url "$srcdir/protobuf"
95 git -c protocol.file.allow=always submodule update --init
96
97 cd src || exit
98 echo 'Generating zip code seed...'
99 PYTHONPATH="$PWD:$PYTHONPATH" python dictionary/gen_zip_code_seed.py --zip_code="${srcdir}/x-ken-all.csv" --jigyosyo="${srcdir}/JIGYOSYO.CSV" >>data/dictionary_oss/dictionary09.txt
100 echo 'Done.'
101
102 # fix mozc icon for kimpanel
103 sed -i 's|PREFIX|/usr|' unix/fcitx5/mozc.conf
104
105 # UT Dictionary steps, rewrite of `sh make.sh`
106 cd "${srcdir}/merge-ut-dictionaries/src/merge" || exit
107 # disable unsuitable_words filter
108 echo '' >../common/unsuitable_words.txt
109 # do things offline
110 mv -v "$srcdir/jawiki-latest-pages-articles-multistream-index-${_utdicdate}.txt.bz2" jawiki-20260501-pages-articles-multistream-index.txt.bz2
111 for dict in "${_dict[@]}"; do
112 sed "/^\#${dict/-/_}/ s,\#${dict/-/_},${dict/-/_}," -i make.sh
113 sed "s,git clone --depth 1 https://github.com/utuhiro78/mozcdic-ut-${dict}.git,install -Dm644 \"${srcdir}/mozcdic-ut-${dict}-${_utdicdate}.txt.bz2\" \"mozcdic-ut-${dict}/mozcdic-ut-${dict}.txt.bz2\",g" -i make.sh
114 done
115 sh make.sh
116 # Add the UT dictionary to original Mozc dictionary tree
117 cat mozcdic-ut.txt >>"$srcdir/mozc/src/data/dictionary_oss/dictionary00.txt"
118}
119
120build() {
121 # revert prior inline replace in prepare()
122 sed 's,#DEFAULT_BUILD_LABEL_MACOS,DEFAULT_BUILD_LABEL_MACOS,' -i mozc/src/version.bzl
123
124 # Fix compatibility with google-glog 0.3.3 (symbol conflict)
125 CFLAGS="${CFLAGS} -fvisibility=hidden"
126 CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
127
128 cd mozc/src || exit
129
130 _targets="unix/fcitx5:fcitx5-mozc.so server:mozc_server gui/tool:mozc_tool renderer/qt:mozc_renderer unix/ibus:ibus_mozc unix/emacs:mozc_emacs_helper"
131
132 unset ANDROID_NDK_HOME
133 unset ANDROID_HOME
134 export JAVA_HOME='/usr/lib/jvm/java-21-openjdk/'
135 export QT_BASE_PATH=/usr/include/qt
136
137 bazel build --compilation_mode opt --config stable_channel --config release_build --config oss_linux $_targets
138}
139
140package_mozc-ut-full-common() {
141 pkgdesc="A Japanese Input Method for Chromium OS, Windows, Mac and Linux (the Open Source Edition of Google Japanese Input)"
142 optdepends=('qt6-base: Display GUI of mozc_tool')
143 options=('!docs')
144 export PREFIX="$pkgdir/usr"
145 export _bldtype
146 cd mozc/src || exit
147
148 # BSD-3-Clause
149 sed -n 1,29p unix/fcitx5/fcitx_key_translator.h >Fcitx5
150 sed -i -e 's|^\/\/[ ]\?||g' Fcitx5
151 install -Dm644 Fcitx5 "${pkgdir}"/usr/share/licenses/${pkgname}/Fcitx5
152 # BSD-3-Clause
153 sed -n 67,94p data/installer/credits_en.html >Mozc
154 install -Dm644 Mozc "${pkgdir}"/usr/share/licenses/${pkgname}/Mozc
155 # BSD-3-Clause
156 sed -n 317,344p data/installer/credits_en.html >Breakpad
157 install -Dm644 Breakpad "${pkgdir}"/usr/share/licenses/${pkgname}/Breakpad
158 # NAIST-2003
159 sed -n 355,424p data/installer/credits_en.html >IPAdic
160 install -Dm644 IPAdic "${pkgdir}"/usr/share/licenses/${pkgname}/IPAdic
161 # BSD-2-Clause
162 sed -n 435,457p data/installer/credits_en.html >Japanese-Usage-Dictionary
163 install -Dm644 Japanese-Usage-Dictionary "${pkgdir}"/usr/share/licenses/${pkgname}/Japanese-Usage-Dictionary
164 # Public Domain Data
165 sed -n 468,470p data/installer/credits_en.html >Okinawa-Dictionary
166 install -Dm644 Okinawa-Dictionary "${pkgdir}"/usr/share/licenses/${pkgname}/Okinawa-Dictionary
167 # BSD-3-Clause
168 sed -n 481,513p data/installer/credits_en.html >Protocol-Buffers
169 install -Dm644 Protocol-Buffers "${pkgdir}"/usr/share/licenses/${pkgname}/Protocol-Buffers
170 # MIT
171 sed -n 698,704p data/installer/credits_en.html >Tamachi-Phonetic-Kanji-Alphabet
172 install -Dm644 Tamachi-Phonetic-Kanji-Alphabet "${pkgdir}"/usr/share/licenses/${pkgname}/Tamachi-Phonetic-Kanji-Alphabet
173 # MIT
174 sed -n 762,782p data/installer/credits_en.html >Windows-Implementation-Library
175 sed -i -e 's|^[ \t]*||g' Windows-Implementation-Library
176 install -Dm644 Windows-Implementation-Library "${pkgdir}"/usr/share/licenses/${pkgname}/Windows-Implementation-Library
177
178 ../scripts/install_server_bazel
179}
180
181package_fcitx5-mozc-ut-full() {
182 pkgdesc="Fcitx5 module for Mozc with UT dictionary"
183 depends=('fcitx5' "$pkgbase-common")
184 provides=('fcitx5-mozc')
185 replaces=('fcitx5-mozc')
186 conflicts=('fcitx-mozc' 'fcitx5-mozc')
187
188 export PREFIX="$pkgdir/usr"
189 export _bldtype
190 cd mozc/src || exit
191
192 ../scripts/install_fcitx5_bazel
193}
194
195package_ibus-mozc-ut-full() {
196 pkgdesc="IBus engine module for Mozc with UT dictionary"
197 depends=('ibus' "$pkgbase-common")
198 conflicts=('ibus-mozc')
199 replaces=('ibus-mozc')
200
201 export _bldtype
202 cd "${srcdir}/mozc/src" || exit
203 install -D -m 755 bazel-bin/unix/ibus/ibus_mozc "$pkgdir/usr/lib/ibus-mozc/ibus-engine-mozc"
204 install -D -m 644 bazel-bin/unix/ibus/mozc.xml "$pkgdir/usr/share/ibus/component/mozc.xml"
205 install -D -m 755 bazel-bin/renderer/qt/mozc_renderer "$pkgdir/usr/lib/mozc/mozc_renderer"
206
207 cd bazel-bin/unix || exit
208 unzip -o icons.zip
209
210 install -Dm644 mozc.png "${pkgdir}/usr/share/ibus-mozc/product_icon.png"
211 install -Dm644 alpha_full.svg "${pkgdir}/usr/share/ibus-mozc/alpha_full.svg"
212 install -Dm644 alpha_half.svg "${pkgdir}/usr/share/ibus-mozc/alpha_half.svg"
213 install -Dm644 direct.svg "${pkgdir}/usr/share/ibus-mozc/direct.svg"
214 install -Dm644 hiragana.svg "${pkgdir}/usr/share/ibus-mozc/hiragana.svg"
215 install -Dm644 katakana_full.svg "${pkgdir}/usr/share/ibus-mozc/katakana_full.svg"
216 install -Dm644 katakana_half.svg "${pkgdir}/usr/share/ibus-mozc/katakana_half.svg"
217 install -Dm644 outlined/dictionary.svg "${pkgdir}/usr/share/ibus-mozc/dictionary.svg"
218 install -Dm644 outlined/properties.svg "${pkgdir}/usr/share/ibus-mozc/properties.svg"
219 install -Dm644 outlined/tool.svg "${pkgdir}/usr/share/ibus-mozc/tool.svg"
220}
221
222package_emacs-mozc-ut-full() {
223 pkgdesc="Emacs engine module for Mozc with UT dictionary"
224 depends=('emacs' "$pkgbase-common")
225 replaces=('emacs-mozc')
226 conflicts=('emacs-mozc')
227
228 export _bldtype
229 cd "${srcdir}/mozc/src" || exit
230 install -Dm755 bazel-bin/unix/emacs/mozc_emacs_helper "$pkgdir/usr/bin/mozc_emacs_helper"
231 install -Dm644 unix/emacs/mozc.el "$pkgdir/usr/share/emacs/site-lisp/emacs-mozc/mozc.el"
232}
233

Scan history

Scanned at (UTC)SeverityRules
2026-09-17 00:27:14 Low 2
2026-09-16 00:03:17 Low 2
2026-09-15 00:25:31 Low 2
2026-09-14 00:27:57 Low 2
2026-09-13 00:19:54 Low 2
2026-09-12 00:25:17 Low 2
2026-09-11 00:19:22 Low 2
2026-09-10 00:22:44 Low 2
2026-09-09 00:04:09 Low 2
2026-09-08 00:18:08 Low 2
2026-09-07 00:30:15 Low 2
2026-09-06 00:17:06 Low 2
2026-09-05 00:16:27 Low 2
2026-09-04 00:03:13 Low 2
2026-09-03 00:15:47 Low 2
2026-09-02 00:02:31 Low 2
2026-09-01 00:11:19 Low 2
2026-08-31 00:19:57 Low 2
2026-08-30 00:04:14 Low 2
2026-08-29 00:29:17 Low 2

Report a package

Reports go to the AURWatch maintainer (one person) and are read by hand. No login required.

0 / 4000
Your suggestion