mpv-sidebarsubtitles

LOW

maintainer lucas007 0 votes scanned 2026-09-12 17:12:25.717441

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: lucaszhou007@163.com>
    
      2pkgname=mpv-sidebarsubtitles
    
      3pkgver=1.0.8
    
      4pkgrel=4
    
      5pkgdesc="Show subtitle lines in a sidebar for mpv, with uosc integration"
    
      6arch=('any')
    
      7url="https://github.com/magnumpv/sidebarsubtitles"
    
      8license=('MIT')
    
      9depends=('mpv' 'mpv-uosc' 'ffmpeg')
    
      10makedepends=('git')
    
      11source=(
    
      12    "git+https://github.com/magnumpv/sidebarsubtitles.git#commit=248a5459207795b2375fe4da56e86663481c7382"
    
      13    "uosc-sidebarsubtitles.patch"
    
      14    "linux-compat.patch"
    
      15    "apply-patch.sh"
    
      16    "mpv-sidebarsubtitles.hook"
    
      17)
    
      18sha256sums=(
    
      19    'SKIP'
    
      20    '372e7cd9a3318e5816bed8a0ac9ead3ee8514f23c3d526188de22db69ed72a9c'
    
      21    'b809be6eacb80e354d26c7e88dad0dbb93d02efc9e71cdb05a1427d708f3826e'
    
      22    '1d3a78fe44cc0a25417f754e575f92f2ed3a5348aa882c37b02563def38818a9'
    
      23    '05349ff8913aa6d61334fb8c4c4e2e43a3d31bc6672e7c6129363de3c53bfa16'
    
      24)
    
      25install="${pkgname}.install"
    
      26
    
      27prepare() {
    
      28    cd "${srcdir}/sidebarsubtitles"
    
      29    # Fix Linux compatibility: upstream uses powershell to create temp dir
    
      30    # and has the path separator logic inverted.
    
      31    patch -p1 -i "${srcdir}/linux-compat.patch"
    
      32}
    
      33
    
      34package() {
    
      35    cd "${srcdir}/sidebarsubtitles"
    
      36
    
      37    # Install the script to /etc/mpv/scripts/ (mpv auto-scans this dir)
    
      38    install -d "${pkgdir}/etc/mpv/scripts/sidebarsubtitles"
    
      39    install -m644 sidebarsubtitles/*.lua sidebarsubtitles/*.json \
    
      40        "${pkgdir}/etc/mpv/scripts/sidebarsubtitles/"
    
      41
    
      42    # Install the uosc integration patch and the apply/revert helper script
    
      43    install -d "${pkgdir}/usr/share/${pkgname}"
    
      44    install -m644 "${srcdir}/uosc-sidebarsubtitles.patch" \
    
      45        "${pkgdir}/usr/share/${pkgname}/"
    
      46    install -m755 "${srcdir}/apply-patch.sh" \
    
      47        "${pkgdir}/usr/share/${pkgname}/"
    
      48
    
      49    # Pacman hook: re-apply the patch when mpv-uosc is installed/upgraded
    
      50    install -Dm644 "${srcdir}/mpv-sidebarsubtitles.hook" \
    
      51        "${pkgdir}/usr/share/libalpm/hooks/mpv-sidebarsubtitles.hook"
    
      52
    
      53    # Install license
    
      54    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      55}
    
      56

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-12 17:12:25	Low	1