msga-git

LOW

maintainer trojdev 0 votes scanned 2026-10-17 09:17:40.511065

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: trojdev <troj at newo dot live>
    
      2pkgname=msga-git
    
      3pkgver=40.r709.g37e8ad7
    
      4pkgrel=1
    
      5pkgdesc='Fast, lightweight native Slack client'
    
      6arch=('x86_64')
    
      7url='https://github.com/punarinta/make-slack-great-again'
    
      8license=('GPL-3.0-only')
    
      9depends=(
    
      10  'dbus'
    
      11  'freetype2'
    
      12  'gcc-libs'
    
      13  'glibc'
    
      14  'harfbuzz'
    
      15  'libxcb'
    
      16  'libxkbcommon'
    
      17  'systemd-libs'
    
      18  'wayland'
    
      19  'xcb-util'
    
      20  'xcb-util-cursor'
    
      21  'xcb-util-image'
    
      22  'xcb-util-renderutil'
    
      23  'hicolor-icon-theme'
    
      24  'libxkbcommon-x11'
    
      25)
    
      26makedepends=(
    
      27  'cmake'
    
      28  'git'
    
      29  'ninja'
    
      30  'pkgconf'
    
      31)
    
      32provides=('msga')
    
      33conflicts=('msga' 'msga-bin')
    
      34source=("${pkgname}::git+${url}.git")
    
      35sha256sums=('SKIP')
    
      36
    
      37pkgver() {
    
      38  cd "$srcdir/$pkgname"
    
      39
    
      40  local upstream_version commit revision
    
      41
    
      42  upstream_version=$(sed -nE \
    
      43    's/^[[:space:]]*set\(MSGA_VERSION[[:space:]]+([0-9]+).*/\1/p' \
    
      44    version.cmake | head -n1)
    
      45
    
      46  [[ -n "$upstream_version" ]] || {
    
      47    printf '%s\n' "ERROR: Could not determine MSGA_VERSION from version.cmake" >&2
    
      48    return 1
    
      49  }
    
      50
    
      51  revision=$(git rev-list --count HEAD)
    
      52  commit=$(git rev-parse --short=7 HEAD)
    
      53
    
      54  printf '%s.r%s.g%s\n' "$upstream_version" "$revision" "$commit"
    
      55}
    
      56
    
      57build() {
    
      58  cd "${srcdir}/${pkgname}"
    
      59
    
      60  cmake -S . -B build -G Ninja \
    
      61    -DCMAKE_BUILD_TYPE=MinSizeRel \
    
      62    -DCMAKE_INSTALL_PREFIX=/usr \
    
      63    -DMSGA_SELF_UPDATE=OFF \
    
      64    -DMSGA_INSTALL_LAUNCHER=OFF \
    
      65    -DMSGA_SIZE_MAP=OFF \
    
      66    -DMSGA_BUILD_TESTS=OFF \
    
      67    -DMSGA_DEMO=OFF
    
      68
    
      69  cmake --build build
    
      70}
    
      71
    
      72package() {
    
      73  cd "${srcdir}/${pkgname}"
    
      74
    
      75  install -Dm755 build/msga \
    
      76    "${pkgdir}/usr/bin/msga"
    
      77
    
      78  install -Dm644 gfx/msga.desktop \
    
      79    "${pkgdir}/usr/share/applications/msga.desktop"
    
      80
    
      81  install -Dm644 gfx/icon.svg \
    
      82    "${pkgdir}/usr/share/icons/hicolor/scalable/apps/msga.svg"
    
      83
    
      84  install -Dm644 LICENSE \
    
      85    "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      86
    
      87  install -Dm644 THIRD_PARTY_LICENSES \
    
      88    "${pkgdir}/usr/share/licenses/${pkgname}/THIRD_PARTY_LICENSES"
    
      89}
    
      90

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-17 09:17:40	Low	1