netsukuku-rs

LOW

maintainer robertfoster 0 votes scanned 2026-08-27 21:33:25.272816

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: robertfoster
    
      2pkgname=netsukuku-rs
    
      3pkgver=0.1.2 # renovate: datasource=github-tags depName=M0Rf30/netsukuku-rs
    
      4pkgrel=2
    
      5pkgdesc="Rust reimplementation of the Netsukuku mesh routing protocol: QSPN v2, Hooking, Coordinator, PeerServices, ANDNA"
    
      6arch=('x86_64' 'aarch64')
    
      7url="https://github.com/M0Rf30/netsukuku-rs"
    
      8license=('GPL-3.0-or-later')
    
      9makedepends=('rust' 'cargo')
    
      10backup=('etc/ntkd/ntkd.toml')
    
      11options=(!lto)
    
      12source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz"
    
      13  ntkd.service
    
      14  ntkd.toml)
    
      15sha256sums=('918d430453130b50a1d8d97edd404e019900df8c12ff1b3fa40b4313d9f1ceba'
    
      16  '0535fc523edaaaa8ce23888d4c3db13500a94988fdb20a5826d59f6da6698810'
    
      17  'b16a6805a87698c43a8fdf7bba699ebccf495aa24d110a49a6291bea335e76c0')
    
      18
    
      19prepare() {
    
      20  cd "${pkgname}-${pkgver}"
    
      21  export RUSTUP_TOOLCHAIN=stable
    
      22  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
    
      23}
    
      24
    
      25build() {
    
      26  cd "${pkgname}-${pkgver}"
    
      27  export RUSTUP_TOOLCHAIN=stable
    
      28  export CARGO_TARGET_DIR=target
    
      29  export RUSTFLAGS="${RUSTFLAGS-} --remap-path-prefix=${srcdir}=/ --remap-path-prefix=${CARGO_HOME:-$HOME/.cargo}=/"
    
      30  cargo build --frozen --profile dist -p ntkd
    
      31}
    
      32
    
      33package() {
    
      34  cd "${pkgname}-${pkgver}"
    
      35  install -Dm0755 target/dist/ntkd \
    
      36    "$pkgdir/usr/bin/ntkd"
    
      37  install -Dm644 LICENSE \
    
      38    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      39  install -Dm644 README.md \
    
      40    "$pkgdir/usr/share/doc/$pkgname/README.md"
    
      41  install -Dm644 "$srcdir/ntkd.service" \
    
      42    "$pkgdir/usr/lib/systemd/system/ntkd.service"
    
      43  install -Dm644 "$srcdir/ntkd.toml" \
    
      44    "$pkgdir/etc/ntkd/ntkd.toml"
    
      45}
    
      46

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-27 21:33:25	Low	1