nexchat-git

LOW

maintainer 1ay1 0 votes scanned 2026-10-23 01:36:19.947355

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Ayush Bhat <tfeayush@gmail.com>
    
      2
    
      3pkgname=nexchat-git
    
      4_pkgname=nexchat
    
      5# nexchat's own numbering started at 0.1.0, below the 2.16.2 it carried from
    
      6# HexChat before: the epoch keeps pacman upgrading
    
      7epoch=1
    
      8pkgver=0.2.1.r2.g25eb9e05
    
      9pkgrel=1
    
      10pkgdesc="IRC client: HexChat continued on GTK4, with a terminal UI (git master)"
    
      11arch=('x86_64' 'aarch64')
    
      12url="https://github.com/1ay1/nexchat"
    
      13license=('GPL-2.0-or-later')
    
      14depends=('gtk4' 'glib2' 'openssl' 'dbus-glib' 'libcanberra' 'iso-codes' 'pciutils' 'wayland')
    
      15makedepends=('git' 'meson' 'ninja' 'cmake' 'python' 'perl' 'luajit' 'python-cffi'
    
      16             'wayland-protocols' 'desktop-file-utils')
    
      17optdepends=('enchant: spell checking'
    
      18            'perl: Perl scripts'
    
      19            'python: Python scripts'
    
      20            'python-cffi: Python scripts'
    
      21            'luajit: Lua scripts')
    
      22provides=("$_pkgname")
    
      23conflicts=("$_pkgname")
    
      24# maya draws the terminal UI (nexchat --tui); its own jaal submodule isn't used
    
      25source=("git+https://github.com/1ay1/nexchat.git"
    
      26        "git+https://github.com/1ay1/maya.git")
    
      27sha256sums=('SKIP' 'SKIP')
    
      28
    
      29prepare() {
    
      30	cd "$_pkgname"
    
      31	git submodule init subprojects/maya
    
      32	git config submodule.subprojects/maya.url "$srcdir/maya"
    
      33	git -c protocol.file.allow=always submodule update subprojects/maya
    
      34}
    
      35
    
      36pkgver() {
    
      37	cd "$_pkgname"
    
      38	# 0.1.0.r<commits since the meson version changed>.g<hash>
    
      39	local ver
    
      40	ver=$(sed -n "s/^  version: '\(.*\)',/\1/p" meson.build)
    
      41	printf '%s.r%s.g%s' "$ver" \
    
      42		"$(git rev-list --count "$(git log -n1 --format=%H -S"version: '$ver'" -- meson.build)"..HEAD)" \
    
      43		"$(git rev-parse --short HEAD)"
    
      44}
    
      45
    
      46build() {
    
      47	# HexChat can be installed too: no hexchat-named plugin files from us
    
      48	arch-meson "$_pkgname" build \
    
      49		-Dinstall-hexchat-compat=false \
    
      50		-Dtext-frontend=true \
    
      51		-Dtui=enabled \
    
      52		-Dwith-lua=luajit \
    
      53		-Dwith-perl=perl \
    
      54		-Dwith-python=python3
    
      55	meson compile -C build
    
      56}
    
      57
    
      58check() {
    
      59	# the ones that need no display (the GUI tests need Xvfb and more)
    
      60	meson test -C build --no-rebuild --print-errorlogs \
    
      61		palette-roundtrip smoke-text hostile-text echo-message batch \
    
      62		chathistory lastlog-logs reply multiline migrate-config
    
      63}
    
      64
    
      65package() {
    
      66	meson install -C build --destdir "$pkgdir"
    
      67}
    
      68

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-23 01:36:19	Low	1