omafil-git

LOW

maintainer dawitworku 0 votes scanned 2026-09-12 11:11:46.143552

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Dawit Worku <dawitworkujima@gmail.com>
    
      2pkgname=omafil-git
    
      3pkgver=0.1.0
    
      4pkgrel=1
    
      5pkgdesc="File manager that follows your Omarchy theme"
    
      6arch=('x86_64')
    
      7url="https://github.com/dawitlabs/omafil"
    
      8license=('MIT')
    
      9depends=('webkit2gtk-4.1' 'gtk3' 'poppler' 'udisks2' 'xdg-utils' 'libnotify')
    
      10makedepends=('git' 'rust' 'bun-bin')
    
      11optdepends=('omarchy: theme and editor integration')
    
      12provides=('omafil')
    
      13# !debug: the release profile already sets strip = true, so makepkg's debug
    
      14# symbols are generated and then discarded, and generating them at peak LTO
    
      15# memory is what pushes the link over on smaller machines.
    
      16# !lto: makepkg's global -flto breaks the C sources in zstd-sys, leaving
    
      17# undefined ZSTD_* symbols at link time. Cargo's own lto = true still applies.
    
      18options=('!debug' '!lto')
    
      19conflicts=('omafil')
    
      20source=("git+${url}.git")
    
      21sha256sums=('SKIP')
    
      22
    
      23pkgver() {
    
      24  cd "${srcdir}/omafil"
    
      25  printf '%s.r%s.%s' \
    
      26    "$(sed -n 's/.*"version": "\([^"]*\)".*/\1/p' src-tauri/tauri.conf.json | head -1)" \
    
      27    "$(git rev-list --count HEAD)" \
    
      28    "$(git rev-parse --short HEAD)"
    
      29}
    
      30
    
      31build() {
    
      32  cd "${srcdir}/omafil/src"
    
      33  bun install --frozen-lockfile
    
      34  bun run build
    
      35
    
      36  # tauri.conf.json's beforeBuildCommand only runs under the tauri CLI, so the
    
      37  # frontend is built above and this is a plain cargo release build.
    
      38  cd "${srcdir}/omafil/src-tauri"
    
      39  cargo build --release --locked
    
      40}
    
      41
    
      42check() {
    
      43  cd "${srcdir}/omafil/src-tauri"
    
      44  cargo test --release --locked
    
      45}
    
      46
    
      47package() {
    
      48  cd "${srcdir}/omafil"
    
      49  install -Dm755 src-tauri/target/release/omafil "${pkgdir}/usr/bin/omafil"
    
      50  install -Dm644 packaging/omafil.desktop "${pkgdir}/usr/share/applications/omafil.desktop"
    
      51  install -Dm644 src-tauri/icons/128x128.png "${pkgdir}/usr/share/icons/hicolor/128x128/apps/omafil.png"
    
      52  install -Dm644 src-tauri/icons/32x32.png "${pkgdir}/usr/share/icons/hicolor/32x32/apps/omafil.png"
    
      53  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      54  install -Dm644 README.md "${pkgdir}/usr/share/doc/omafil/README.md"
    
      55}
    
      56

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-12 11:11:46	Low	1