omnidiff

LOW

maintainer barbuk 0 votes scanned 2026-11-02 08:02:24.858082

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Julien Virey <julien.virey+aur@gmail.com>
    
      2# Maintainer: Marko Ivankovic <marko@ivankovic.me>
    
      3
    
      4pkgname=omnidiff
    
      5pkgver=0.3.0
    
      6pkgrel=1
    
      7pkgdesc="Fast, robust, accurate content-aware diffing"
    
      8arch=('x86_64' 'aarch64')
    
      9url="https://github.com/ivankovic/omnidiff"
    
      10license=('AGPL-3.0-only')
    
      11depends=('gcc-libs' 'glibc')
    
      12makedepends=('cargo')
    
      13options=(!lto !debug)
    
      14source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      15sha256sums=('82046f16077ecbb8122818bd9ea6ee1a0f01c0ca4650b037afbf610e155f33e5')
    
      16
    
      17prepare() {
    
      18	cd "$pkgname-$pkgver"
    
      19	export RUSTUP_TOOLCHAIN=stable
    
      20	cargo fetch --locked --target $(rustc --print host-tuple)
    
      21}
    
      22
    
      23build() {
    
      24	cd "$pkgname-$pkgver"
    
      25	export RUSTUP_TOOLCHAIN=stable
    
      26	export CARGO_TARGET_DIR=target
    
      27	cargo build --frozen --release --bin omnidiff
    
      28}
    
      29
    
      30package() {
    
      31	cd "$pkgname-$pkgver"
    
      32	local bin="target/release/$pkgname"
    
      33
    
      34	install -Dm0755 "$bin" "$pkgdir/usr/bin/$pkgname"
    
      35
    
      36	"$bin" util man | install -Dm0644 /dev/stdin "$pkgdir/usr/share/man/man1/$pkgname.1"
    
      37	"$bin" util completions bash | install -Dm0644 /dev/stdin \
    
      38		"$pkgdir/usr/share/bash-completion/completions/$pkgname"
    
      39	"$bin" util completions zsh | install -Dm0644 /dev/stdin \
    
      40		"$pkgdir/usr/share/zsh/site-functions/_$pkgname"
    
      41	"$bin" util completions fish | install -Dm0644 /dev/stdin \
    
      42		"$pkgdir/usr/share/fish/vendor_completions.d/$pkgname.fish"
    
      43
    
      44	install -Dm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      45	install -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
    
      46}
    
      47

Scan history

Scanned at (UTC)	Severity	Rules
2026-11-02 08:02:24	Low	1