omnissa-horizon-html5mmr

MEDIUM
maintainer eworm 11 votes base omnissa-horizon-client scanned 2026-09-02 09:50:35.971730
View on AUR
Why flagged

One or more source=() URLs point to a host outside the trusted allowlist (github.com, gitlab.com, codeberg.org, pypi.org, …).

Triggered rules

Medium source=() URL on a non-standard host source_untrusted_domain

One or more source=() URLs point to a host outside the trusted allowlist (github.com, gitlab.com, codeberg.org, pypi.org, …).

  • PKGBUILD:25 source=("${pkgbase}-${_long_ver}.tar.gz::https://download3.omnissa.com/software/${_cart}/Omnissa-Horizon-Client-Linux-${_long_ver}.tar.gz"

PKGBUILD

1 offending line(s) highlighted
1# Maintainer: Christian Hesse <mail@eworm.de>
2
3pkgbase=omnissa-horizon-client
4pkgname=(
5 'omnissa-horizon-client'
6 'omnissa-horizon-client-next'
7 'omnissa-horizon-file-association'
8 'omnissa-horizon-html5mmr'
9 'omnissa-horizon-integrated-printing'
10 'omnissa-horizon-scanner-client'
11 'omnissa-horizon-serialport-client'
12 'omnissa-horizon-usb')
13pkgver=2603
14_build1=8.18.0
15_build2=24120621798
16_long_ver="${pkgver%.*}-${_build1}-${_build2}"
17_cart="CART27FQ1_LIN_${pkgver}_TARBALL"
18pkgrel=1
19pkgdesc='Omnissa Horizon Client - connect to Omnissa Horizon virtual desktop'
20arch=('x86_64')
21makedepends=('resvg' 'oxipng')
22options=('!debug')
23url='https://customerconnect.omnissa.com/downloads/info/slug/virtual_desktop_and_apps/omnissa_horizon_clients/8'
24license=('custom')
25source=("${pkgbase}-${_long_ver}.tar.gz::https://download3.omnissa.com/software/${_cart}/Omnissa-Horizon-Client-Linux-${_long_ver}.tar.gz"
26 'horizon-icon.svg'
27 'horizon-usb.service')
28sha256sums=('acd30479cec91ee693bbd685880fa3834f3678f8dd336511bb9d732f134f71d7'
29 'ef412bcc6d3e3d45e161861a8fb2abebc1403e7e2d84c52a16552d9091efd5b0'
30 '2e9ecddd7cd4d5f65c794065898d3b6ac8e6dd97d05114f7f3775da82263c6d2')
31
32prepare() {
33 cd "${srcdir}/Omnissa-Horizon-Client-Linux-${_long_ver}/x64/"
34
35 for TARBALL in *.tar.gz; do
36 tar xf "${TARBALL}"
37 done
38}
39
40build() {
41 cd "${srcdir}/Omnissa-Horizon-Client-Linux-${_long_ver}/x64/"
42
43 # split off 'horizon-client-next'...
44 mkdir -p 'Omnissa-Horizon-Client-Next/usr/'{'bin','lib/omnissa/horizon/bin','share/applications'}
45 mv "Omnissa-Horizon-Client-${_long_ver}.x64/usr/bin/horizon-client-next" \
46 'Omnissa-Horizon-Client-Next/usr/bin/'
47 mv "Omnissa-Horizon-Client-${_long_ver}.x64/usr/lib/omnissa/horizon/bin/horizon-client-next-bundle/" \
48 'Omnissa-Horizon-Client-Next/usr/lib/omnissa/horizon/bin/'
49 mv "Omnissa-Horizon-Client-${_long_ver}.x64/usr/share/applications/horizon-client-next.desktop" \
50 'Omnissa-Horizon-Client-Next/usr/share/applications/'
51
52 # remove duplicate libraries...
53 rm --force \
54 "Omnissa-Horizon-PCoIP-${_long_ver}.x64/usr/lib/omnissa/"lib*.so.*.*.*
55 # let's use system libstdc++ from gcc-libs...
56 rm --recursive --force \
57 "Omnissa-Horizon-PCoIP-${_long_ver}.x64/usr/lib/omnissa/gcc/"
58 # ... and even more system libraries.
59 rm --force \
60 "Omnissa-Horizon-PCoIP-${_long_ver}.x64/usr/lib/omnissa/lib"{'ffi.so','fuse.so.2','sigc-2.0.so'{,'.0'},'z.so.1'}
61 # /\ Warning: Removing the mm-libraries (lib*mm.so.*) and openssl
62 # /\7\ (libssl.so.* & libcrypto.so.*) causes segmentation faults...
63 # /_()_\
64
65 # move common files into the client package...
66 mv "Omnissa-Horizon-scannerClient-${_long_ver}.x64/usr/lib/omnissa/horizon/scannerSerialPortCommon/" \
67 "Omnissa-Horizon-Client-${_long_ver}.x64/usr/lib/omnissa/horizon/"
68 mv "Omnissa-Horizon-scannerClient-${_long_ver}.x64/usr/lib/omnissa/rdpvcbridge/" \
69 "Omnissa-Horizon-Client-${_long_ver}.x64/usr/lib/omnissa/"
70 rm --recursive --force \
71 "Omnissa-Horizon-serialportClient-${_long_ver}.x64/usr/lib/omnissa/"{'horizon/scannerSerialPortCommon/','rdpvcbridge'}
72
73 # add a Comment and StartupWMClass to desktop file, use proper icon
74 sed -i \
75 -e '/Name=Omnissa/a Comment=Connect to Omnissa Horizon View virtual machines' \
76 -e '/Name=Omnissa/a StartupWMClass=Horizon-client' \
77 -e '/^Icon=/c Icon=horizon-client' \
78 "Omnissa-Horizon-Client-${_long_ver}.x64/usr/share/applications/horizon-client.desktop"
79
80 # prepare high(er) quality icons
81 install -d "${srcdir}/icons"
82 for SIZE in 16 24 32 48 64 96 128; do
83 resvg --height "${SIZE}" --width "${SIZE}" "${srcdir}/horizon-icon.svg" -c | \
84 oxipng - > "${srcdir}/icons/horizon-client-${SIZE}.png"
85 done
86}
87
88package_omnissa-horizon-client() {
89 conflicts=('vmware-horizon-client'
90 'vmware-horizon-mmr'
91 'vmware-horizon-pcoip'
92 'vmware-horizon-rtav'
93 'vmware-horizon-smartcard'
94 'vmware-horizon-teams-optimization'
95 'vmware-horizon-tsdr')
96 replaces=('vmware-horizon-client'
97 'vmware-horizon-mmr'
98 'vmware-horizon-pcoip'
99 'vmware-horizon-rtav'
100 'vmware-horizon-smartcard'
101 'vmware-horizon-teams-optimization'
102 'vmware-horizon-tsdr')
103 depends=('binutils' 'expat' 'fuse2' 'gcc-libs' 'glib2' 'gtk3' 'libffi' 'libsigc++'
104 'libxml2-legacy' 'libxss' 'libxtst' 'zlib')
105 optdepends=('alsa-lib: audio support via alsa'
106 'freerdp: RDP remote desktop connections'
107 'libpulse: audio support via pulse sound server'
108 'omnissa-horizon-client-next: tech preview'
109 'omnissa-horizon-html5mmr: HTML5 MultiMedia Redirection'
110 'omnissa-horizon-integrated-printing: integrated printing'
111 'omnissa-horizon-scanner-client: scanner client'
112 'omnissa-horizon-serialport-client: serialport client'
113 'omnissa-horizon-usb: USB device redirection'
114 'opensc: Common Access Card (CAC)'
115 'rdesktop: RDP remote desktop connections')
116 install=omnissa-horizon-client.install
117
118 cd "${srcdir}/Omnissa-Horizon-Client-Linux-${_long_ver}/x64/"
119
120 cp -a "Omnissa-Horizon-Client-${_long_ver}.x64/usr/" "${pkgdir}/"
121 cp -a "Omnissa-Horizon-PCoIP-${_long_ver}.x64/usr/" "${pkgdir}/"
122
123 # drop duplicate libraries
124 for LIB in 'vaapi2' 'vaapi2.7' 'vdpau'; do
125 rm -rf "${pkgdir}/usr/lib/omnissa/horizon/${LIB}"
126 ln -s software "${pkgdir}/usr/lib/omnissa/horizon/${LIB}"
127 done
128
129 # link for optional dependency opensc
130 install -d "${pkgdir}/usr/lib/omnissa/horizon/pkcs11/"
131 ln -s '../../../opensc-pkcs11.so' "${pkgdir}/usr/lib/omnissa/horizon/pkcs11/libopenscpkcs11.so"
132
133 # install high(er) quality icons
134 install -D -m0644 "${srcdir}/horizon-icon.svg" \
135 "${pkgdir}/usr/share/icons/hicolor/scalable/apps/horizon-client.svg"
136 for SIZE in 16 24 32 48 64 96 128; do
137 install -D -m0644 "${srcdir}/icons/horizon-client-${SIZE}.png" \
138 "${pkgdir}/usr/share/icons/hicolor/${SIZE}x${SIZE}/apps/horizon-client.png"
139 done
140}
141
142package_omnissa-horizon-client-next() {
143 pkgdesc='Omnissa Horizon Client - connect to Omnissa Horizon virtual desktop - tech preview'
144 depends=('omnissa-horizon-client')
145
146 cd "${srcdir}/Omnissa-Horizon-Client-Linux-${_long_ver}/x64/"
147
148 cp -a 'Omnissa-Horizon-Client-Next/usr/' "${pkgdir}/"
149}
150
151package_omnissa-horizon-file-association() {
152 pkgdesc='Omnissa Horizon Client - File Association'
153 depends=('omnissa-horizon-client')
154
155 cd "${srcdir}/Omnissa-Horizon-Client-Linux-${_long_ver}/x64/"
156
157 cp -a "Omnissa-Horizon-fileAssociation-${_long_ver}.x64/usr/" "${pkgdir}/"
158}
159
160package_omnissa-horizon-html5mmr() {
161 pkgdesc='Omnissa Horizon Client - HTML5 MultiMedia Redirection'
162 depends=('omnissa-horizon-client')
163 conflicts=('vmware-horizon-html5mmr')
164 replaces=('vmware-horizon-html5mmr')
165
166 cd "${srcdir}/Omnissa-Horizon-Client-Linux-${_long_ver}/x64/"
167
168 cp -a "Omnissa-Horizon-html5mmr-${_long_ver}.x64/usr/" "${pkgdir}/"
169}
170
171package_omnissa-horizon-integrated-printing() {
172 pkgdesc='Omnissa Horizon Client - integrated printing'
173 depends=('omnissa-horizon-client' 'libcups' 'zlib')
174 conflicts=('vmware-horizon-virtual-printing' 'vmware-horizon-integrated-printing')
175 replaces=('vmware-horizon-virtual-printing' 'vmware-horizon-integrated-printing')
176
177 cd "${srcdir}/Omnissa-Horizon-Client-Linux-${_long_ver}/x64/"
178
179 cp -a "Omnissa-Horizon-integratedPrinting-${_long_ver}.x64/usr/" "${pkgdir}/"
180}
181
182package_omnissa-horizon-scanner-client() {
183 pkgdesc='Omnissa Horizon Client - scanner client'
184 depends=('omnissa-horizon-client')
185
186 cd "${srcdir}/Omnissa-Horizon-Client-Linux-${_long_ver}/x64/"
187
188 cp -a "Omnissa-Horizon-scannerClient-${_long_ver}.x64/usr/" "${pkgdir}/"
189}
190
191package_omnissa-horizon-serialport-client() {
192 pkgdesc='Omnissa Horizon Client - serialport client'
193 depends=('omnissa-horizon-client' 'libutil-linux' 'zlib' 'glib2')
194
195 cd "${srcdir}/Omnissa-Horizon-Client-Linux-${_long_ver}/x64/"
196
197 cp -a "Omnissa-Horizon-serialportClient-${_long_ver}.x64/usr/" "${pkgdir}/"
198}
199
200package_omnissa-horizon-usb() {
201 pkgdesc='Omnissa Horizon Client - USB device redirection'
202 depends=('omnissa-horizon-client' 'glib2')
203 conflicts=('vmware-horizon-usb')
204 replaces=('vmware-horizon-usb')
205 install=omnissa-horizon-usb.install
206
207 cd "${srcdir}/Omnissa-Horizon-Client-Linux-${_long_ver}/x64/"
208
209 cp -a "Omnissa-Horizon-USB-${_long_ver}.x64/usr/" "${pkgdir}/"
210
211 install -D -m0644 "${srcdir}/horizon-usb.service" "${pkgdir}/usr/lib/systemd/system/horizon-usb.service"
212}
213

Scan history

Scanned at (UTC)SeverityRules
2026-09-02 09:50:35 Medium 1
2026-06-20 00:18:46 Clean 2
2026-06-19 23:51:18 Clean 2
2026-06-19 19:07:35 Low 2
2026-06-18 16:11:54 Medium 1

Report a package

Reports go to the AURWatch maintainer (one person) and are read by hand. No login required.

0 / 4000
Your suggestion