onair-dra

LOW

maintainer SteamedFish 0 votes scanned 2026-10-21 15:32:06.139547

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: SteamedFish <steamedfish@hotmail.com>
    
      2#
    
      3# DRA/DRA+ audio decoder add-on for OnAir (CDR radio sound).
    
      4#
    
      5# OnAir ships no DRA decoder (patent/licence status unverified, see
    
      6# docs/CODECS.md "DRA+ (CDR sound)") but dlopens libonair_dra.so at
    
      7# runtime when found. This package builds it from the MIT-licensed
    
      8# decoder in maliwen2015/ffmpeg_cavs_dra using OnAir's own
    
      9# tools/addons/dra, and installs it where OnAir looks for it
    
      10# (/usr/lib/onair = <bindir>/../lib/onair, searched before the user
    
      11# codecs folder ~/.local/share/onair/codecs).
    
      12#
    
      13# Whether you may use this decoder depends on the patent rules where
    
      14# you live; check them first (as upstream notes).
    
      15
    
      16pkgname=onair-dra
    
      17pkgver=0.2.8
    
      18pkgrel=2
    
      19pkgdesc="DRA/DRA+ audio decoder add-on for OnAir (CDR sound)"
    
      20arch=('x86_64' 'aarch64')
    
      21url="https://github.com/adswill/OnAir"
    
      22license=('MIT')  # the decoder (dradec.c, from maliwen2015/ffmpeg_cavs_dra); OnAir's build glue is GPL-3.0-or-later
    
      23depends=('glibc')
    
      24makedepends=('cmake' 'python')
    
      25source=("OnAir-$pkgver.tar.gz::https://github.com/adswill/OnAir/archive/refs/tags/v$pkgver.tar.gz"
    
      26        "ffmpeg-7.1.2_cavs_dra.patch::https://raw.githubusercontent.com/maliwen2015/ffmpeg_cavs_dra/eb94ceb887b47b6ecfbda9da43273dd65246df1e/ffmpeg-7.1.2_cavs_dra.patch"
    
      27        "LICENSE::https://raw.githubusercontent.com/maliwen2015/ffmpeg_cavs_dra/eb94ceb887b47b6ecfbda9da43273dd65246df1e/LICENSE")
    
      28sha256sums=('31526fc45e3b359572993b88ab5448b4cba298d2226befec9934de0e2410a62a'
    
      29            '1d1cac53cc2d19af39de854db186985fb653e820b0d071844a1e529550c08e40'
    
      30            'cac0ae34bd88bc4347c3901c3d6e9715ee64ae9b2ec8e027b0892ecd67db98f4')
    
      31
    
      32build() {
    
      33    cd "OnAir-$pkgver/tools/addons/dra"
    
      34    # extract_dra.py normally downloads the patch itself; point it at the
    
      35    # pinned copy from source[] instead. It verifies the patch is the
    
      36    # version it knows and refuses anything else.
    
      37    python3 extract_dra.py "$srcdir/ffmpeg-7.1.2_cavs_dra.patch"
    
      38    cmake -S . -B build -DDRA_SRC=dra_src -DCMAKE_BUILD_TYPE=None
    
      39    cmake --build build
    
      40}
    
      41
    
      42package() {
    
      43    install -Dm755 "OnAir-$pkgver/tools/addons/dra/build/libonair_dra.so" "$pkgdir/usr/lib/onair/libonair_dra.so"
    
      44    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      45}
    
      46

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-21 15:32:06	Low	1