openshell

LOW

maintainer chadsr 1 votes scanned 2026-08-19 19:42:09.088000

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: chadsr <git at ross dot ch>
    
      2
    
      3pkgname=openshell
    
      4pkgver=0.0.109 # renovate: datasource=github-releases depName=NVIDIA/OpenShell
    
      5pkgrel=1
    
      6pkgdesc="The safe, private runtime for autonomous AI agents."
    
      7arch=('x86_64' 'aarch64')
    
      8url='https://github.com/NVIDIA/OpenShell'
    
      9license=('Apache-2.0')
    
      10install=openshell.install
    
      11depends=('z3' 'sqlite')
    
      12makedepends=(
    
      13	'cargo'
    
      14	'clang'  # z3-sys (libclang for bindgen)
    
      15	'cmake'  # protobuf-src builds protoc via cmake
    
      16	'pandoc' # man pages from deploy/man/*.md
    
      17)
    
      18optdepends=(
    
      19	'bash-completion: bash completions'
    
      20	'docker: compute driver'
    
      21	'podman: compute driver'
    
      22)
    
      23conflicts=("$pkgname-bin" "$pkgname-git")
    
      24options=('!lto')
    
      25source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      26b2sums=('7eb66a222e15d58fc317f2c07a9e3e897c1edf97014152923ec46a0f52c9020e8ecbbd69df0129eeca49aa98522e8d0ea357877295f9525efea50b9d0c7f70a7')
    
      27
    
      28prepare() {
    
      29	cd "OpenShell-$pkgver"
    
      30
    
      31	cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      32}
    
      33
    
      34build() {
    
      35	cd "OpenShell-$pkgver"
    
      36	export CARGO_TARGET_DIR=target
    
      37	export LIBSQLITE3_SYS_USE_PKG_CONFIG=1
    
      38	export OPENSHELL_GIT_VERSION="$pkgver"
    
      39	export OPENSHELL_IMAGE_TAG="$pkgver"
    
      40
    
      41	# --no-default-features disables telemetry
    
      42	cargo build --frozen --release --no-default-features \
    
      43		-p openshell-cli \
    
      44		-p openshell-server
    
      45
    
      46	# man pages (markdown -> roff via pandoc, matching the RPM)
    
      47	pandoc -s -t man deploy/man/openshell.1.md -o openshell.1
    
      48	pandoc -s -t man deploy/man/openshell-gateway.8.md -o openshell-gateway.8
    
      49
    
      50	# shell completions
    
      51	target/release/openshell completions bash >openshell.bash
    
      52	target/release/openshell completions zsh >_openshell
    
      53	target/release/openshell completions fish >openshell.fish
    
      54}
    
      55
    
      56check() {
    
      57	cd "OpenShell-$pkgver"
    
      58	export CARGO_TARGET_DIR=target
    
      59	export LIBSQLITE3_SYS_USE_PKG_CONFIG=1
    
      60	export OPENSHELL_GIT_VERSION="$pkgver"
    
      61	export OPENSHELL_IMAGE_TAG="$pkgver"
    
      62
    
      63	cargo test --frozen --lib \
    
      64		-p openshell-cli \
    
      65		-p openshell-server
    
      66}
    
      67
    
      68package() {
    
      69	cd "OpenShell-$pkgver"
    
      70	install -Dm0755 target/release/openshell -t "$pkgdir/usr/bin/"
    
      71	install -Dm0755 target/release/openshell-gateway -t "$pkgdir/usr/bin/"
    
      72
    
      73	install -Dm0644 deploy/deb/openshell-gateway.service \
    
      74		"$pkgdir/usr/lib/systemd/user/openshell-gateway.service"
    
      75
    
      76	install -Dm0644 deploy/rpm/gateway.toml.default \
    
      77		"$pkgdir/usr/share/openshell-gateway/gateway.toml.default"
    
      78
    
      79	install -Dm0644 openshell.1 "$pkgdir/usr/share/man/man1/openshell.1"
    
      80	install -Dm0644 openshell-gateway.8 "$pkgdir/usr/share/man/man8/openshell-gateway.8"
    
      81
    
      82	install -Dm0644 openshell.bash "$pkgdir/usr/share/bash-completion/completions/openshell"
    
      83	install -Dm0644 _openshell "$pkgdir/usr/share/zsh/site-functions/_openshell"
    
      84	install -Dm0644 openshell.fish "$pkgdir/usr/share/fish/vendor_completions.d/openshell.fish"
    
      85
    
      86	install -Dm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      87}
    
      88

Changes since previous scan

--- PKGBUILD @ 2026-08-17 00:18
+++ PKGBUILD @ 2026-08-19 19:42
@@ -1,7 +1,7 @@
 # Maintainer: chadsr <git at ross dot ch>
 
 pkgname=openshell
-pkgver=0.0.106 # renovate: datasource=github-releases depName=NVIDIA/OpenShell
+pkgver=0.0.109 # renovate: datasource=github-releases depName=NVIDIA/OpenShell
 pkgrel=1
 pkgdesc="The safe, private runtime for autonomous AI agents."
 arch=('x86_64' 'aarch64')
@@ -23,7 +23,7 @@
 conflicts=("$pkgname-bin" "$pkgname-git")
 options=('!lto')
 source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
-b2sums=('267e3d74401bb8cd4c3a9cc37b17b8ef6671a6490cccff9daa0c6e1d58b783afcf30e62bc64b29190e68a2e0b4c5b2ee5ec39ce552475e38c359aaf7ab98679e')
+b2sums=('7eb66a222e15d58fc317f2c07a9e3e897c1edf97014152923ec46a0f52c9020e8ecbbd69df0129eeca49aa98522e8d0ea357877295f9525efea50b9d0c7f70a7')
 
 prepare() {
 	cd "OpenShell-$pkgver"

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-19 19:42:09	Low	1
2026-08-17 00:18:29	Clean	2
2026-08-16 11:32:23	Low	1
2026-08-14 00:03:41	Clean	2
2026-08-13 23:27:02	Low	1
2026-08-13 00:17:07	Clean	2
2026-08-12 19:24:47	Low	1
2026-08-12 00:27:08	Clean	2
2026-08-11 23:21:47	Low	1
2026-08-11 21:21:47	Low	1
2026-08-11 17:21:34	Low	1