padtune

LOW

maintainer Deddroid 0 votes scanned 2026-10-20 21:29:05.029414

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: deddroid <deddo9412@gmail.com>
    
      2pkgname=padtune
    
      3pkgver=0.1.0
    
      4pkgrel=1
    
      5pkgdesc="Unofficial configurator for BIGBIG WON controllers (Rainbow 2 Pro and family): buttons, sticks, triggers, lights, macros, polling rate"
    
      6arch=('x86_64')
    
      7url="https://github.com/deddroid/padtune"
    
      8license=('MIT')
    
      9depends=('gcc-libs' 'glibc' 'systemd-libs' 'libglvnd' 'libxkbcommon')
    
      10makedepends=('cargo')
    
      11optdepends=('wayland: native Wayland window'
    
      12            'libx11: X11 window')
    
      13options=('!lto')
    
      14source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
    
      15sha256sums=('a871eda11572960f9b80877f5de0482c162320c3c05d7200987866872642c610')
    
      16
    
      17prepare() {
    
      18  cd "$pkgname-$pkgver"
    
      19  export RUSTUP_TOOLCHAIN=stable
    
      20  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      21}
    
      22
    
      23build() {
    
      24  cd "$pkgname-$pkgver"
    
      25  export RUSTUP_TOOLCHAIN=stable
    
      26  export CARGO_TARGET_DIR=target
    
      27  export RUSTFLAGS="--remap-path-prefix=$srcdir=/build --remap-path-prefix=${CARGO_HOME:-$HOME/.cargo}=/cargo"
    
      28  cargo build --frozen --release
    
      29}
    
      30
    
      31check() {
    
      32  cd "$pkgname-$pkgver"
    
      33  export RUSTUP_TOOLCHAIN=stable
    
      34  export RUSTFLAGS="--remap-path-prefix=$srcdir=/build --remap-path-prefix=${CARGO_HOME:-$HOME/.cargo}=/cargo"
    
      35  cargo test --frozen --release
    
      36}
    
      37
    
      38package() {
    
      39  cd "$pkgname-$pkgver"
    
      40  install -Dm755 target/release/padtune target/release/padtune-gui -t "$pkgdir/usr/bin/"
    
      41  install -Dm644 packaging/linux/padtune.desktop -t "$pkgdir/usr/share/applications/"
    
      42  install -Dm644 packaging/linux/70-padtune.rules -t "$pkgdir/usr/lib/udev/rules.d/"
    
      43  for s in 16 32 48 64 128 256 512; do
    
      44    install -Dm644 "assets/icon-$s.png" "$pkgdir/usr/share/icons/hicolor/${s}x${s}/apps/padtune.png"
    
      45  done
    
      46  install -Dm644 assets/icon.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/padtune.svg"
    
      47  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
    
      48  install -Dm644 README.md README.it.md CHANGELOG.md docs/PROTOCOL.md -t "$pkgdir/usr/share/doc/$pkgname/"
    
      49}
    
      50

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-20 21:29:05	Low	1