palemoon

LOW

maintainer WorMzy 145 votes scanned 2026-11-01 00:21:48.120785

View on AUR

Why flagged

The source is a git checkout from the project's official repository on repo.palemoon.org, which is the legitimate hosting for Pale Moon; building from source is normal for AUR packages, and the host, while not a major forge, is specific to the project.

Triggered rules

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The source is a git checkout from the project's official repository on repo.palemoon.org, which is the legitimate hosting for Pale Moon; building from source is normal for AUR packages, and the host, while not a major forge, is specific to the project.

1 higher static finding superseded - not the current verdict (shown for transparency)

Medium source=() URL on a non-standard host source_untrusted_domain

One or more source=() URLs point to a host outside the trusted allowlist (github.com, gitlab.com, codeberg.org, pypi.org, …).

PKGBUILD:52 source=(git+"https://repo.palemoon.org/MoonchildProductions/${_repo}?signed#commit=${_commit}"

PKGBUILD

1 offending line(s) highlighted

      1# Maintainer:  WorMzy Tykashi <wormzy.tykashi@gmail.com>
    
      2# Contributor: artiom <a.mv at gmx dot fr>
    
      3# Contributor: ilikenwf
    
      4# Contributor: American_Jesus
    
      5# Contributor: Mufflone
    
      6# Contributor: switchnode
    
      7pkgname=palemoon
    
      8_repo=Pale-Moon
    
      9epoch=1
    
      10pkgver=35.0.2
    
      11# Commit ID can be found at https://repo.palemoon.org/MoonchildProductions/Pale-Moon/tags
    
      12_commit=964e969389
    
      13pkgrel=1
    
      14pkgdesc="Open source web browser based on Firefox focusing on efficiency."
    
      15arch=('i686' 'x86_64')
    
      16url="https://www.palemoon.org/"
    
      17license=('MPL-2.0')
    
      18depends=(
    
      19  'alsa-lib'
    
      20  'at-spi2-core'
    
      21  'bash'
    
      22  'cairo'
    
      23  'dbus'
    
      24  'fontconfig'
    
      25  'freetype2'
    
      26  'gdk-pixbuf2'
    
      27  'glib2'
    
      28  'glibc'
    
      29  'gtk2'
    
      30  'hicolor-icon-theme'
    
      31  'libgcc'
    
      32  'libstdc++'
    
      33  'libx11'
    
      34  'libxcb'
    
      35  'libxext'
    
      36  'libxrender'
    
      37  'libxt'
    
      38  'pango'
    
      39)
    
      40makedepends=(
    
      41  'git'
    
      42  'libpulse'
    
      43  'nasm'
    
      44  'python'
    
      45  'tar'
    
      46  'unzip'
    
      47  'yasm'
    
      48  'zip'
    
      49)
    
      50optdepends=('libpulse: PulseAudio audio driver'
    
      51            'ffmpeg: various video and audio support')
    
      52source=(git+"https://repo.palemoon.org/MoonchildProductions/${_repo}?signed#commit=${_commit}"
    
      53        git+"https://repo.palemoon.org/MoonchildProductions/UXP"
    
      54        mozconfig.in)
    
      55validpgpkeys=('3DAD8CD107197488D2A2A0BD40481E7B8FCF9CEC')
    
      56sha1sums=('5794fe0b1fe96a90a405ac935b07f70883ab716a'
    
      57          'SKIP'
    
      58          'a45ac7de3b664dcadb0917a975ee0b859385b719')
    
      59sha256sums=('a317040b1916b7f5170236c7a96d25f3b77be868bf7e0e4c7ae1b1b5a137631d'
    
      60            'SKIP'
    
      61            'd74ba2d07f5ddb9a8268c64745995a310f5aa2033ca3c8634a22e0cbcf0fa3c2')
    
      62
    
      63prepare() {
    
      64  sed 's#%SRCDIR%#'"${srcdir}"'#g' mozconfig.in > mozconfig
    
      65  cd ${_repo}
    
      66  git submodule init
    
      67  git config submodule.platform.url "${srcdir}/UXP"
    
      68  git -c protocol.file.allow=always submodule update
    
      69}
    
      70
    
      71build() {
    
      72  cd ${_repo}
    
      73
    
      74  # Remove option not supported by ld.gold to prevent configure failure
    
      75  export LDFLAGS="${LDFLAGS/-Wl,-z,pack-relative-relocs/}"
    
      76  export MOZBUILD_STATE_PATH="${srcdir}/mozbuild"
    
      77  export MOZCONFIG="${srcdir}/mozconfig"
    
      78  export CPPFLAGS="${CPPFLAGS} -O2"
    
      79
    
      80  ./mach build
    
      81}
    
      82
    
      83package() {
    
      84  cd pmbuild
    
      85  make package
    
      86  cd dist
    
      87  install -d "${pkgdir}"/usr/{bin,lib}
    
      88  cp -r palemoon/ "${pkgdir}/usr/lib/${pkgname}"
    
      89  ln -s "../lib/${pkgname}/palemoon" "${pkgdir}/usr/bin/palemoon"
    
      90
    
      91  # icons
    
      92  install -Dm644 palemoon/browser/chrome/icons/default/default16.png \
    
      93    "${pkgdir}/usr/share/icons/hicolor/16x16/apps/${pkgname}.png"
    
      94  install -Dm644 palemoon/browser/chrome/icons/default/default32.png \
    
      95    "${pkgdir}/usr/share/icons/hicolor/32x32/apps/${pkgname}.png"
    
      96  install -Dm644 palemoon/browser/chrome/icons/default/default48.png \
    
      97    "${pkgdir}/usr/share/icons/hicolor/48x48/apps/${pkgname}.png"
    
      98  install -Dm644 palemoon/browser/icons/mozicon128.png \
    
      99    "${pkgdir}/usr/share/icons/hicolor/128x128/apps/${pkgname}.png"
    
      100
    
      101  # install desktop file
    
      102  install -Dm644 "${srcdir}/${_repo}/palemoon/branding/official/palemoon.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
    
      103}
    
      104

Scan history

Scanned at (UTC)	Severity	Rules
2026-11-01 00:21:48	Low	2
2026-10-31 00:07:41	Low	2
2026-10-30 00:29:30	Low	2
2026-10-29 00:13:55	Low	2
2026-10-28 00:06:54	Low	2
2026-10-27 23:48:54	Low	2
2026-10-27 00:23:28	Low	2
2026-10-26 00:12:40	Low	2
2026-10-25 00:20:48	Low	2
2026-10-24 00:14:55	Low	2
2026-10-23 00:02:19	Low	2
2026-10-22 00:13:10	Low	2
2026-10-21 00:12:50	Low	2
2026-10-20 00:10:31	Low	2
2026-10-19 00:03:55	Low	2
2026-10-18 00:06:55	Low	2
2026-10-17 00:21:55	Low	2
2026-10-16 00:12:47	Low	2
2026-10-15 00:28:05	Low	2
2026-10-14 00:06:47	Low	2