pam_rssh-jetm

LOW

maintainer jetm 0 votes scanned 2026-10-23 03:36:21.010368

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Javier Tia <floss@jetm.me>
    
      2# Based on the AUR pam_rssh PKGBUILD by peelz <peelz.dev+arch@gmail.com>
    
      3
    
      4# pam_rssh with one change: a security-key (sk-ecdsa / sk-ed25519) signature
    
      5# whose U2F flags byte has the user-presence bit clear is rejected, so sudo
    
      6# through ssh-agent needs a physical touch even when the agent signs without
    
      7# one. See touch-required.patch. Both sources are pinned to commits, as in the
    
      8# AUR package; bump _commit and _ssh_agent_rs_commit together with pkgver.
    
      9
    
      10_commit="e8dd046c423f85df266c23bcc3d7033bfee81255"
    
      11_ssh_agent_rs_commit="802b94ccf2e00ac33a3863300d0769f02b62d807"
    
      12_upstream="pam_rssh"
    
      13pkgname="pam_rssh-jetm"
    
      14pkgver="1.2.1"
    
      15pkgrel="1"
    
      16pkgdesc="A PAM module that provides ssh-agent based authentication, requiring user presence for security keys"
    
      17url="https://github.com/z4yx/pam_rssh"
    
      18arch=("x86_64")
    
      19license=("MIT")
    
      20depends=(
    
      21  "openssl"
    
      22  "pam"
    
      23)
    
      24makedepends=(
    
      25  "git"
    
      26  "cargo"
    
      27)
    
      28provides=("pam_rssh")
    
      29conflicts=("pam_rssh")
    
      30source=(
    
      31  "${_upstream}::git+https://github.com/z4yx/pam_rssh.git#commit=${_commit}"
    
      32  "ssh-agent.rs::git+https://github.com/z4yx/ssh-agent.rs.git#commit=${_ssh_agent_rs_commit}"
    
      33  "touch-required.patch"
    
      34)
    
      35sha256sums=(
    
      36  "SKIP"
    
      37  "SKIP"
    
      38  "defee089c443b132fa168c11eb9d88f49f250540dc4934e710dd800ae3a36f92"
    
      39)
    
      40
    
      41prepare() {
    
      42  cd "${srcdir}/${_upstream}"
    
      43  git submodule init
    
      44  git config submodule.dep/ssh-agent.rs.url "${srcdir}/ssh-agent.rs"
    
      45  git -c protocol.allow=never -c protocol.file.allow=always submodule update
    
      46  patch -Np1 -i "${srcdir}/touch-required.patch"
    
      47  export RUSTUP_TOOLCHAIN=stable
    
      48  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      49}
    
      50
    
      51build() {
    
      52  cd "${srcdir}/${_upstream}"
    
      53  export RUSTUP_TOOLCHAIN=stable
    
      54  export CARGO_TARGET_DIR=target
    
      55  cargo build --frozen --release --all-features
    
      56}
    
      57
    
      58check() {
    
      59  cd "${srcdir}/${_upstream}"
    
      60  export RUSTUP_TOOLCHAIN=stable
    
      61  export CARGO_TARGET_DIR=target
    
      62  # The sshagent_* tests talk to a live ssh-agent holding keys, which a build
    
      63  # chroot does not have; every other unit test runs.
    
      64  cargo test --frozen --all-features -- --skip sshagent_
    
      65}
    
      66
    
      67package() {
    
      68  cd "${srcdir}/${_upstream}"
    
      69  install -Dm0755 target/release/libpam_rssh.so \
    
      70    "${pkgdir}/usr/lib/security/pam_rssh.so"
    
      71  install -Dm0644 README.md \
    
      72    "${pkgdir}/usr/share/doc/${pkgname}/README.md"
    
      73  install -Dm0644 LICENSE \
    
      74    "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      75}
    
      76

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-23 03:36:21	Low	1
2026-10-23 01:36:19	Low	1