pdrive
LOW
maintainer YourDoritos
0 votes
scanned 2026-09-11 21:24:02.517890
Why flagged
The package builds from source hosted on GitHub with a SKIP'd checksum, but the source is from the project's official repository and only data/executables from that source are installed; no remote code execution or exfiltration occurs.
Triggered rules
Low
Few votes, recently uploaded
zero_votes_recent
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
Low
AI review
llm_review
An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package builds from source hosted on GitHub with a SKIP'd checksum, but the source is from the project's official repository and only data/executables from that source are installed; no remote code execution or exfiltration occurs.
PKGBUILD
1
# Maintainer: Paul Goessmann <paul.goessmann@proton.me>
2
pkgname=pdrive
3
pkgver=0.1.0
4
pkgrel=1
5
pkgdesc='Proton Drive sync client with TUI for Linux (unofficial)'
6
arch=('x86_64' 'aarch64')
7
url='https://github.com/YourDoritos/pDrive'
8
license=('GPL-3.0-or-later')
9
depends=('glibc')
10
makedepends=('go>=1.26' 'git')
11
install=pdrive.install
12
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
13
sha256sums=('SKIP')
14
15
_srcdir="pDrive-${pkgver}"
16
17
prepare() {
18
cd "${_srcdir}"
19
export GOPATH="${srcdir}/gopath"
20
export GOFLAGS="-modcacherw"
21
go mod download
22
}
23
24
build() {
25
cd "${_srcdir}"
26
export CGO_CPPFLAGS="${CPPFLAGS}"
27
export CGO_CFLAGS="${CFLAGS}"
28
export CGO_CXXFLAGS="${CXXFLAGS}"
29
export CGO_LDFLAGS="${LDFLAGS}"
30
export GOPATH="${srcdir}/gopath"
31
export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
32
33
local _ldflags="-s -w -X main.version=${pkgver}"
34
35
go build -ldflags "${_ldflags}" -o pdrive ./cmd/pdrive
36
go build -ldflags "${_ldflags}" -o pdrived ./cmd/pdrived
37
go build -ldflags "${_ldflags}" -o pdrivectl ./cmd/pdrivectl
38
go build -ldflags "${_ldflags}" -o pdrive-gate ./cmd/pdrive-gate
39
40
# When the system Go is older than go.mod's directive (common with
41
# mise/asdf overriding /usr/bin/go), the bootstrap downloads a toolchain
42
# into the gopath modcache and marks the tree read-only. Yay's cleanup on
43
# the next upgrade then fails with hundreds of "Permission denied"
44
# warnings. GOFLAGS=-modcacherw does not cover the toolchain bootstrap, so
45
# force the tree writable here instead. (Same fix as pVPN.)
46
if [[ -d "${srcdir}/gopath" ]]; then
47
chmod -R u+w "${srcdir}/gopath" || true
48
fi
49
}
50
51
package() {
52
cd "${_srcdir}"
53
install -Dm755 pdrive "${pkgdir}/usr/bin/pdrive"
54
install -Dm755 pdrived "${pkgdir}/usr/bin/pdrived"
55
install -Dm755 pdrivectl "${pkgdir}/usr/bin/pdrivectl"
56
install -Dm755 pdrive-gate "${pkgdir}/usr/bin/pdrive-gate"
57
58
# pdrived is a user service: it runs as you, not root.
59
sed 's|ExecStart=/usr/local/bin/pdrived|ExecStart=/usr/bin/pdrived|' \
60
dist/pdrived.service | install -Dm644 /dev/stdin \
61
"${pkgdir}/usr/lib/systemd/user/pdrived.service"
62
63
# pdrive-gate is a system service and is optional; it is installed but not
64
# enabled. Nothing else in pDrive needs root.
65
sed 's|ExecStart=/usr/local/bin/pdrive-gate|ExecStart=/usr/bin/pdrive-gate|' \
66
dist/pdrive-gate.service | install -Dm644 /dev/stdin \
67
"${pkgdir}/usr/lib/systemd/system/pdrive-gate.service"
68
69
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
70
install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
71
install -Dm644 SECURITY.md "${pkgdir}/usr/share/doc/${pkgname}/SECURITY.md"
72
}
73
Scan history
| Scanned at (UTC) | Severity | Rules |
|---|---|---|
| 2026-09-11 21:24:02 | Low | 2 |