pgtui

LOW

maintainer agony4001 0 votes scanned 2026-10-24 15:40:54.697274

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: agony <27015 at riseup dot net>
    
      2
    
      3pkgname=pgtui
    
      4pkgver=0.3.0
    
      5pkgrel=1
    
      6pkgdesc="Simple terminal UI for PostgreSQL"
    
      7arch=('x86_64' 'aarch64')
    
      8url="https://github.com/pgplex/pgtui"
    
      9license=('MIT')
    
      10depends=('glibc' 'sqlite')
    
      11makedepends=('go')
    
      12optdepends=('wl-clipboard: clipboard support on Wayland'
    
      13            'xclip: clipboard support on X11')
    
      14options=('!lto')
    
      15source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
    
      16sha256sums=('8640afd41927abcf8cb510c0b85276af4e038ed7b984c6b7cdaa2bd73fb7b043')
    
      17
    
      18prepare() {
    
      19  cd "${pkgname}-${pkgver}"
    
      20  mkdir -p build
    
      21  export GOPATH="${srcdir}"
    
      22  go mod download -modcacherw
    
      23}
    
      24
    
      25build() {
    
      26  cd "${pkgname}-${pkgver}"
    
      27  export CGO_CPPFLAGS="${CPPFLAGS}"
    
      28  export CGO_CFLAGS="${CFLAGS}"
    
      29  export CGO_CXXFLAGS="${CXXFLAGS}"
    
      30  export CGO_LDFLAGS="${LDFLAGS}"
    
      31  export GOPATH="${srcdir}"
    
      32  export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
    
      33  # go-sqlite3 needs cgo; libsqlite3 links the system SQLite
    
      34  go build -tags libsqlite3 -o build ./cmd/...
    
      35}
    
      36
    
      37check() {
    
      38  cd "${pkgname}-${pkgver}"
    
      39  export GOPATH="${srcdir}"
    
      40  export GOFLAGS="-mod=readonly -modcacherw"
    
      41  go test -tags libsqlite3 ./...
    
      42}
    
      43
    
      44package() {
    
      45  cd "${pkgname}-${pkgver}"
    
      46  install -Dm755 build/pgtui -t "${pkgdir}/usr/bin"
    
      47  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
    
      48  install -Dm644 README.md docs/USER_GUIDE.md config/default.yaml -t "${pkgdir}/usr/share/doc/${pkgname}"
    
      49}
    
      50

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-24 15:40:54	Low	1