pip-player-bin

LOW

maintainer zxp19821005 0 votes scanned 2026-09-28 07:20:27.447771

View on AUR

Why flagged

The package installs a prebuilt Electron app from the project's official GitHub releases, which is normal for binary packages; the source is verifiable and the build process only repackages and patches paths, with no evidence of malicious behavior.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package installs a prebuilt Electron app from the project's official GitHub releases, which is normal for binary packages; the source is verifiable and the build process only repackages and patches paths, with no evidence of malicious behavior.

PKGBUILD

      1# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
    
      2pkgname=pip-player-bin
    
      3_pkgname='PiP Player'
    
      4pkgver=1.2.4
    
      5pkgrel=1
    
      6_electronversion=31
    
      7pkgrel=1
    
      8pkgdesc="A simple application to play PiP(Picture-in-Picture) with any links that you like."
    
      9arch=('x86_64')
    
      10url="https://github.com/WickyPlays/pip-player"
    
      11license=('MIT')
    
      12provides=("${pkgname%-bin}=${pkgver}")
    
      13conflicts=("${pkgname%-bin}")
    
      14depends=(
    
      15    "electron${_electronversion}"
    
      16)
    
      17makedepends=(
    
      18    'asar'
    
      19)
    
      20source=(
    
      21    "${pkgname%-bin}-${pkgver}-x86_64.deb::${url}/releases/download/v${pkgver}/${pkgname%-bin}_${pkgver}_amd64.deb"
    
      22    "LICENSE-${pkgver}::https://raw.githubusercontent.com/WickyPlays/pip-player/v${pkgver}/LICENSE"
    
      23    "${pkgname%-bin}.sh"
    
      24)
    
      25sha256sums=('6d47519f7241a42a6337463eb5108f390f210138a94dc6756c40cf567fe1ca34'
    
      26            'cafd4c46a3b1cccb587dbbab8d1cefb20ff240ff7e282e14f897e2919dfb78fa'
    
      27            'bd5358d8f323d3c2c2f0733364ee4ea55f551dd86ba0be2a76846210b60897fc')
    
      28_get_app_dir() {
    
      29    find "${srcdir}" -type f -name "resources.pak" -exec dirname {} + | head -n 1
    
      30}
    
      31_check_electron_version() {
    
      32    echo "Verifying Electron version..."
    
      33    local _main_exe=$(find "$(_get_app_dir)" -maxdepth 1 -type f -executable -printf '%s %p\n' | sort -nr | head -1 | cut -d' ' -f2-)
    
      34    [[ -z "${_main_exe}" ]] && echo -e "\033[1;33mNote: Could not find Electron binary.\033[0m" && return
    
      35    local _elec_ver=$(strings "${_main_exe}" | grep -oP 'Electron/\K[0-9]+' | head -1)
    
      36    [[ -z "${_elec_ver}" ]] && echo -e "\033[1;33mNote: Could not determine Electron version.\033[0m" && return
    
      37    [[ "${_elec_ver}" != "${_electronversion}" ]] &&
    
      38        echo -e "\033[1;31mWarning: Electron version mismatch! Detected: ${_elec_ver}, Expected: ${_electronversion}\033[0m" ||
    
      39        echo -e "Electron version verified: \033[1;31m${_elec_ver}\033[0m"
    
      40}
    
      41prepare() {
    
      42    sed -i -e "
    
      43        s/@electronversion@/${_electronversion}/g
    
      44        s/@appname@/${pkgname%-bin}/g
    
      45        s/@runname@/app.asar/g
    
      46        s/@cfgdirname@/${_pkgname}/g
    
      47    " "${srcdir}/${pkgname%-bin}.sh"
    
      48    bsdtar -xf "${srcdir}/data."*
    
      49    _check_electron_version
    
      50    local _app_dir=$(_get_app_dir)
    
      51    asar e "${_app_dir}/resources/app.asar" "${srcdir}/app.asar.unpacked"
    
      52    find "${srcdir}/app.asar.unpacked/dist" -type f -exec sed -i "s/process.resourcesPath/\'\/usr\/lib\/${pkgname%-bin}\'/g" {} +
    
      53    asar p "${srcdir}/app.asar.unpacked" "${_app_dir}/resources/app.asar"
    
      54    sed -i "s/\/opt\/${_pkgname}\///g" "${srcdir}/usr/share/applications/${pkgname%-bin}.desktop"
    
      55}
    
      56package() {
    
      57    install -Dm755 "${srcdir}/${pkgname%-bin}.sh" "${pkgdir}/usr/bin/${pkgname%-bin}"
    
      58    install -Dm755 -d "${pkgdir}/usr/lib/${pkgname%-bin}"
    
      59    local _app_dir=$(_get_app_dir)
    
      60    cp -a "${_app_dir}/resources/"* "${pkgdir}/usr/lib/${pkgname%-bin}/"
    
      61    install -Dm644 "${srcdir}/usr/share/applications/${pkgname%-bin}.desktop" -t "${pkgdir}/usr/share/applications"
    
      62    find "${srcdir}" -type f \( -name "*.png" -o -name "*.svg" \) -path "*share/icons/*" | while read -r _i; do
    
      63        _extension="${_i##*.}"
    
      64        _icon_path="${_i#*share/icons/}"
    
      65        _target_dir="/usr/share/icons/$(dirname "${_icon_path}")"
    
      66        install -Dm644 "${_i}" "${pkgdir}${_target_dir}/${pkgname%-bin}.${_extension}"
    
      67    done
    
      68    install -Dm644 "${srcdir}/LICENSE-${pkgver}" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      69}
    
      70

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-28 07:20:27	Low	2