pittore-studio

LOW

maintainer Felitendo 0 votes scanned 2026-10-19 03:23:49.568814

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Felitendo
    
      2# Contributor: Pittore Studio
    
      3# This PKGBUILD is updated automatically:
    
      4# https://github.com/Felitendo/PKGBUILDS
    
      5
    
      6pkgname=pittore-studio
    
      7pkgver=0.1.6
    
      8pkgrel=1
    
      9pkgdesc="Layer-based photo editor for Linux"
    
      10arch=('x86_64')
    
      11url="https://github.com/Event-Horizon-desktop-environment/pittore-studio"
    
      12license=('MIT')
    
      13# Upstream's own list (packaging/arch/PKGBUILD), checked by pkg.sh on every
    
      14# new version. lcms2 is required, not optional: without it meson drops the
    
      15# Qt application target.
    
      16depends=('fontconfig' 'freetype2' 'harfbuzz' 'lcms2' 'libjpeg-turbo' 'libtiff'
    
      17         'libwebp' 'qrencode' 'qt6-base' 'qt6-svg' 'tomlplusplus' 'zlib' 'zstd')
    
      18# the HIP backend is a plugin, dlopened once the runtime is installed
    
      19optdepends=('hip-runtime-amd: AMD GPU compute backend (ROCm HIP runtime)')
    
      20# cuda and hip-runtime-amd carry nvcc and hipcc; meson looks in /opt/cuda/bin
    
      21# and /opt/rocm/bin, so neither has to be on PATH. Both are build-time only:
    
      22# the CUDA runtime is linked statically and HIP is dlopened at runtime.
    
      23makedepends=('cuda' 'hip-runtime-amd' 'meson' 'ninja' 'pkgconf')
    
      24# !lto: makepkg's -flto makes BFD ld fail the final link with "copy relocation
    
      25# against non-copyable protected symbol" on Qt6's staticMetaObject symbols
    
      26options=('!lto')
    
      27source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
    
      28sha256sums=('df5e251718e1e7bdb1b96d8096d62a5f63557c1db63b45f0b011bbbebd172768')
    
      29
    
      30build() {
    
      31  # The GPU target lists are upstream's own, from the build that produces the
    
      32  # release assets. The "native" default would probe the build machine's card,
    
      33  # which needs a driver present and ties the package to that one GPU.
    
      34  meson setup build "$pkgname-$pkgver" --prefix=/usr -Dbuildtype=release \
    
      35    -Dbackend-cuda=enabled \
    
      36    -Dcuda-archs=sm_75,sm_80,sm_86,sm_89,sm_90,sm_100,sm_120,+ptx \
    
      37    -Dbackend-hip=enabled \
    
      38    -Dhip-archs=gfx906,gfx908,gfx90a,gfx942,gfx950,gfx1010,gfx1012,gfx1030,gfx1031,gfx1032,gfx1100,gfx1101,gfx1102,gfx1103,gfx1150,gfx1151,gfx1200,gfx1201 \
    
      39    -Donnxruntime=disabled -Dapp=enabled
    
      40  # Only what gets installed. Building everything would pull in the test tree,
    
      41  # which compiles app_state.cpp (~1GB per translation unit) into every test
    
      42  # binary.
    
      43  ninja -C build src/app/painter src/app/pittore-mcp \
    
      44    src/engine/compute/libpittore-hip.so
    
      45}
    
      46
    
      47package() {
    
      48  DESTDIR="$pkgdir" meson install -C build --no-rebuild
    
      49  # upstream's meson install ships no license text
    
      50  install -Dm644 "$pkgname-$pkgver/LICENSE" \
    
      51    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      52}
    
      53

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-19 03:23:49	Low	1