pittore-studio-git

LOW

maintainer Felitendo 0 votes scanned 2026-10-19 03:23:49.568814

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Felitendo
    
      2# Contributor: Pittore Studio
    
      3# This PKGBUILD is updated automatically:
    
      4# https://github.com/Felitendo/PKGBUILDS
    
      5
    
      6pkgname=pittore-studio-git
    
      7pkgver=0.1.6.r1.gc97f85d
    
      8pkgrel=1
    
      9pkgdesc="Layer-based photo editor for Linux (git)"
    
      10arch=('x86_64')
    
      11url="https://github.com/Event-Horizon-desktop-environment/pittore-studio"
    
      12license=('MIT')
    
      13# Same build as pittore-studio, see that package for the lists and the flags.
    
      14depends=('fontconfig' 'freetype2' 'harfbuzz' 'lcms2' 'libjpeg-turbo' 'libtiff'
    
      15         'libwebp' 'qrencode' 'qt6-base' 'qt6-svg' 'tomlplusplus' 'zlib' 'zstd')
    
      16optdepends=('hip-runtime-amd: AMD GPU compute backend (ROCm HIP runtime)')
    
      17makedepends=('cuda' 'git' 'hip-runtime-amd' 'meson' 'ninja' 'pkgconf')
    
      18# !lto: makepkg's -flto makes BFD ld fail the final link with "copy relocation
    
      19# against non-copyable protected symbol" on Qt6's staticMetaObject symbols
    
      20options=('!lto')
    
      21provides=('pittore-studio')
    
      22conflicts=('pittore-studio')
    
      23source=("${pkgname}::git+${url}.git")
    
      24sha256sums=('SKIP')
    
      25
    
      26pkgver() {
    
      27  cd "$pkgname"
    
      28  # --tags: upstream's release tags are lightweight, so a plain describe finds
    
      29  # nothing. --match keeps the rolling and latest tags from swallowing it.
    
      30  git describe --long --tags --abbrev=7 --match 'v[0-9]*' \
    
      31    | sed 's/^v//; s/\([^-]*-g\)/r\1/; s/-/./g'
    
      32}
    
      33
    
      34build() {
    
      35  # The GPU target lists are upstream's own, from the build that produces the
    
      36  # release assets. The "native" default would probe the build machine's card,
    
      37  # which needs a driver present and ties the package to that one GPU.
    
      38  meson setup build "$pkgname" --prefix=/usr -Dbuildtype=release \
    
      39    -Dbackend-cuda=enabled \
    
      40    -Dcuda-archs=sm_75,sm_80,sm_86,sm_89,sm_90,sm_100,sm_120,+ptx \
    
      41    -Dbackend-hip=enabled \
    
      42    -Dhip-archs=gfx906,gfx908,gfx90a,gfx942,gfx950,gfx1010,gfx1012,gfx1030,gfx1031,gfx1032,gfx1100,gfx1101,gfx1102,gfx1103,gfx1150,gfx1151,gfx1200,gfx1201 \
    
      43    -Donnxruntime=disabled -Dapp=enabled
    
      44  # Only what gets installed. Building everything would pull in the test tree,
    
      45  # which compiles app_state.cpp (~1GB per translation unit) into every test
    
      46  # binary.
    
      47  ninja -C build src/app/painter src/app/pittore-mcp \
    
      48    src/engine/compute/libpittore-hip.so
    
      49}
    
      50
    
      51package() {
    
      52  DESTDIR="$pkgdir" meson install -C build --no-rebuild
    
      53  # upstream's meson install ships no license text
    
      54  install -Dm644 "$pkgname/LICENSE" \
    
      55    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      56}
    
      57

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-19 03:23:49	Low	1