pocketlink-git

LOW

maintainer Rasi 0 votes scanned 2026-10-08 22:09:59.830246

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Rasi <rasi@xssn.at>
    
      2
    
      3pkgname=pocketlink-git
    
      4_pkgname=pocketlink
    
      5pkgver=0.1.0.r0.ga04e04e
    
      6pkgrel=1
    
      7pkgdesc='Lightweight phone companion for sway, niri & co: notifications, clipboard, files, media remote and calls'
    
      8arch=('x86_64' 'aarch64')
    
      9url='https://github.com/carnager/pocketlink'
    
      10license=('GPL-3.0-or-later')
    
      11depends=('glibc' 'wl-clipboard' 'xdg-utils')
    
      12makedepends=('git' 'go')
    
      13optdepends=(
    
      14  'wireplumber: lower the volume during phone calls (wpctl)'
    
      15  'dms-shell: panel widget for pairing and settings'
    
      16)
    
      17provides=("$_pkgname")
    
      18conflicts=("$_pkgname")
    
      19source=("git+$url.git")
    
      20sha256sums=('SKIP')
    
      21
    
      22pkgver() {
    
      23  cd "$_pkgname"
    
      24  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      25}
    
      26
    
      27prepare() {
    
      28  cd "$_pkgname"
    
      29  go mod download -modcacherw
    
      30}
    
      31
    
      32build() {
    
      33  cd "$_pkgname"
    
      34  export CGO_CPPFLAGS="$CPPFLAGS"
    
      35  export CGO_CFLAGS="$CFLAGS"
    
      36  export CGO_CXXFLAGS="$CXXFLAGS"
    
      37  export CGO_LDFLAGS="$LDFLAGS"
    
      38  export GOFLAGS='-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw'
    
      39  go build -o build/ ./cmd/pocketlink
    
      40}
    
      41
    
      42check() {
    
      43  cd "$_pkgname"
    
      44  go test ./...
    
      45}
    
      46
    
      47package() {
    
      48  cd "$_pkgname"
    
      49  install -Dm755 build/pocketlink -t "$pkgdir/usr/bin/"
    
      50
    
      51  # The repo's unit points at ~/.local/bin for source installs.
    
      52  sed 's|^ExecStart=.*|ExecStart=/usr/bin/pocketlink daemon|' contrib/pocketlink.service |
    
      53    install -Dm644 /dev/stdin "$pkgdir/usr/lib/systemd/user/pocketlink.service"
    
      54
    
      55  # DankMaterialShell's system-wide plugin directory.
    
      56  install -Dm644 contrib/dms/pocketlink/* -t "$pkgdir/etc/xdg/quickshell/dms-plugins/pocketlink/"
    
      57
    
      58  install -Dm644 README.md -t "$pkgdir/usr/share/doc/$_pkgname/"
    
      59}
    
      60

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-08 22:09:59	Low	1
2026-10-08 20:09:40	Low	1