podbox

LOW

maintainer yashi 0 votes scanned 2026-09-29 03:22:52.787385

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: yashi <https://aur.archlinux.org/account/yashi>
    
      2pkgname=podbox
    
      3pkgver=0.8.1
    
      4pkgrel=1
    
      5pkgdesc="Podman-native container environment manager"
    
      6arch=('x86_64' 'aarch64')
    
      7url="https://github.com/bethropolis/podbox"
    
      8license=('MIT')
    
      9depends=('podman')
    
      10makedepends=('rustup')
    
      11optdepends=(
    
      12  'fish: default shell in prebuilt images'
    
      13  'openssh: for SSH agent forwarding'
    
      14)
    
      15conflicts=('podbox-bin')
    
      16source=("https://github.com/bethropolis/podbox/archive/refs/tags/v$pkgver.tar.gz")
    
      17b2sums=('d9b7ef9c478f867f0134dd32e029983234e75e4019446b5e866ecf481d78a440e4c5164d548315e1fd3f379135999f521ce9396edbb02c0668c9af72229be8bc')
    
      18
    
      19# build.rs only uses the musl target if it is already installed, and otherwise
    
      20# falls back to a dynamic build that will not run in musl containers.
    
      21_musl_target() {
    
      22  case "$CARCH" in
    
      23    x86_64)  echo x86_64-unknown-linux-musl ;;
    
      24    aarch64) echo aarch64-unknown-linux-musl ;;
    
      25  esac
    
      26}
    
      27
    
      28prepare() {
    
      29  cd "$pkgname-$pkgver"
    
      30  rustup target add "$(_musl_target)"
    
      31}
    
      32
    
      33build() {
    
      34  cd "$pkgname-$pkgver"
    
      35  # No .git in a tarball, so build.rs needs the version passed in.
    
      36  PODBOX_VERSION="v$pkgver" cargo build --release --locked -p podbox-cli 2>&1 | tee build.log
    
      37  local rc="${PIPESTATUS[0]}"
    
      38  [ "$rc" -eq 0 ] || return "$rc"
    
      39
    
      40  ./target/release/podbox completions bash > podbox.bash
    
      41  ./target/release/podbox completions zsh  > podbox.zsh
    
      42  ./target/release/podbox completions fish > podbox.fish
    
      43}
    
      44
    
      45check() {
    
      46  cd "$pkgname-$pkgver"
    
      47  if ! grep -q "podbox-guest binary built (musl / static)" build.log; then
    
      48    echo "error: podbox-guest was not built static, see build.log" >&2
    
      49    return 1
    
      50  fi
    
      51}
    
      52
    
      53package() {
    
      54  cd "$pkgname-$pkgver"
    
      55
    
      56  install -Dm755 target/release/podbox "${pkgdir}/usr/bin/podbox"
    
      57  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      58
    
      59  install -Dm644 podbox.bash \
    
      60    "${pkgdir}/usr/share/bash-completion/completions/podbox"
    
      61  install -Dm644 podbox.zsh \
    
      62    "${pkgdir}/usr/share/zsh/site-functions/_podbox"
    
      63  install -Dm644 podbox.fish \
    
      64    "${pkgdir}/usr/share/fish/vendor_completions.d/podbox.fish"
    
      65}
    
      66

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-29 03:22:52	Low	1