prismlauncher-offline-git

LOW

maintainer Vendetta1871 0 votes scanned 2026-09-07 03:13:17.703764

View on AUR

Why flagged

Package builds from source using a git repository of a Prism Launcher fork with offline support, has SKIP'd checksums but uses a publicly accessible and plausibly maintained GitHub repo, no evidence of malicious behavior or remote code execution.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 90%): Package builds from source using a git repository of a Prism Launcher fork with offline support, has SKIP'd checksums but uses a publicly accessible and plausibly maintained GitHub repo, no evidence of malicious behavior or remote code execution.

PKGBUILD

      1# Maintainer: Vendetta1871 <conqueror.v.v.v.v.v@gmail.com>
    
      2
    
      3pkgname=prismlauncher-offline-git
    
      4pkgver=11.0.3.r7.gd393323fd
    
      5pkgrel=1
    
      6pkgdesc="Prism Launcher fork with offline account support enabled (git version)"
    
      7arch=('x86_64')
    
      8url="https://github.com/Diegiwg/PrismLauncher-Cracked"
    
      9license=('GPL-3.0-only')
    
      10depends=(
    
      11    cmark
    
      12    gcc-libs
    
      13    glibc
    
      14    hicolor-icon-theme
    
      15    libarchive
    
      16    libgl
    
      17    qrencode
    
      18    qt6-base
    
      19    qt6-imageformats
    
      20    qt6-networkauth
    
      21    qt6-svg
    
      22    qt6-wayland
    
      23    tomlplusplus
    
      24    zlib
    
      25)
    
      26makedepends=(
    
      27    cmake
    
      28    extra-cmake-modules
    
      29    gamemode
    
      30    git
    
      31    jdk17-openjdk
    
      32    ninja
    
      33    scdoc
    
      34    vulkan-headers
    
      35)
    
      36optdepends=(
    
      37    'java-runtime: use system Java instead of the bundled downloader'
    
      38    'java-runtime=8: for older Minecraft versions'
    
      39    'glfw: to use system GLFW libraries'
    
      40    'openal: to use system OpenAL libraries'
    
      41    'xorg-xrandr: for older Minecraft versions'
    
      42    'gamemode: to optimize gameplay'
    
      43    'flite: Minecraft voice narration'
    
      44)
    
      45provides=('prismlauncher' 'prismlauncher-offline')
    
      46conflicts=('prismlauncher' 'prismlauncher-offline')
    
      47# LTO costs a lot of build time and memory here for no measurable gain
    
      48options=('!lto')
    
      49
    
      50source=(
    
      51    "git+${url}.git"
    
      52    'git+https://github.com/PrismLauncher/libnbtplusplus.git'
    
      53)
    
      54sha256sums=('SKIP'
    
      55            'SKIP')
    
      56
    
      57pkgver() {
    
      58    cd "$srcdir/PrismLauncher-Cracked"
    
      59    if _desc=$(git describe --long --tags 2>/dev/null); then
    
      60        printf '%s' "$_desc" | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
    
      61    else
    
      62        printf '0.r%s.g%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
    
      63    fi
    
      64}
    
      65
    
      66prepare() {
    
      67    cd "$srcdir/PrismLauncher-Cracked"
    
      68    git submodule init
    
      69    # use the clone makepkg already fetched instead of hitting the network again
    
      70    git config submodule.libraries/libnbtplusplus.url "$srcdir/libnbtplusplus"
    
      71    git config submodule.flatpak/shared-modules.active false
    
      72    git -c protocol.file.allow=always submodule update
    
      73}
    
      74
    
      75build() {
    
      76    export PATH="/usr/lib/jvm/java-17-openjdk/bin:$PATH"
    
      77
    
      78    cmake -S PrismLauncher-Cracked -B build -G Ninja \
    
      79        -DCMAKE_BUILD_TYPE='None' \
    
      80        -DCMAKE_INSTALL_PREFIX='/usr' \
    
      81        -DLauncher_BUILD_PLATFORM='archlinux' \
    
      82        -DLauncher_APP_BINARY_NAME='prismlauncher' \
    
      83        -DLauncher_QT_VERSION_MAJOR='6' \
    
      84        -DLauncher_ENABLE_JAVA_DOWNLOADER=ON \
    
      85        -DBUILD_TESTING=OFF \
    
      86        -DCMAKE_C_FLAGS="$CFLAGS -DNDEBUG" \
    
      87        -DCMAKE_CXX_FLAGS="$CXXFLAGS -DNDEBUG" \
    
      88        -Wno-dev
    
      89    cmake --build build
    
      90}
    
      91
    
      92package() {
    
      93    DESTDIR="$pkgdir" cmake --install build
    
      94    install -Dm644 "$srcdir/PrismLauncher-Cracked/LICENSE" \
    
      95        "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      96}
    
      97

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-07 03:13:17	Low	2