proton-drive-for-linux

LOW

maintainer Narl 1 votes scanned 2026-09-21 11:34:50.247705

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Nils Pukropp <contact@narl.io>
    
      2
    
      3pkgname=proton-drive-for-linux
    
      4pkgver=1.11.1
    
      5pkgrel=1
    
      6pkgdesc="Unofficial Proton Drive client: files-on-demand FUSE mount, CLI, GTK4 app and tray"
    
      7arch=('x86_64')
    
      8url="https://github.com/narrrl/proton-drive-linux"
    
      9license=('MIT')
    
      10depends=('fuse3' 'gtk4' 'libadwaita' 'webkitgtk-6.0' 'dbus' 'gcc-libs' 'glibc'
    
      11         'hicolor-icon-theme')
    
      12makedepends=('cargo')
    
      13optdepends=('perl-image-exiftool: thumbnails for camera RAW files'
    
      14            'gnome-keyring: credential storage over the Secret Service API'
    
      15            'kwallet: credential storage over the Secret Service API'
    
      16            'xdg-utils: "Open folder" action in the tray menu'
    
      17            'fzf: search-as-you-type launcher (pdfs-prompt --fzf)'
    
      18            'foot: terminal that hosts pdfs-prompt --fzf when started from a keybinding')
    
      19provides=("proton-drive-linux=$pkgver" 'pdfs')
    
      20conflicts=('proton-drive-linux' 'proton-drive-for-linux-bin' 'proton-drive-for-linux-git')
    
      21# LTO has broken GTK/Rust links for this workspace; the release profile keeps it off.
    
      22options=('!lto')
    
      23source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      24sha256sums=('1481379b2b70102ea6345a00b1092f73511f6ba99d6fba9a3f185ad6d28caaf2')
    
      25
    
      26_srcname="proton-drive-linux-$pkgver"
    
      27
    
      28prepare() {
    
      29  cd "$_srcname"
    
      30  export RUSTUP_TOOLCHAIN=stable
    
      31  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      32}
    
      33
    
      34build() {
    
      35  cd "$_srcname"
    
      36  export RUSTUP_TOOLCHAIN=stable
    
      37  export CARGO_TARGET_DIR=target
    
      38  cargo build --frozen --release \
    
      39    --bin pdfs \
    
      40    --bin pdfs-tray \
    
      41    --bin pdfs-app \
    
      42    --bin pdfs-prompt
    
      43}
    
      44
    
      45check() {
    
      46  cd "$_srcname"
    
      47  export RUSTUP_TOOLCHAIN=stable
    
      48  export CARGO_TARGET_DIR=target
    
      49  cargo test --frozen --workspace
    
      50}
    
      51
    
      52package() {
    
      53  cd "$_srcname"
    
      54
    
      55  install -Dm755 target/release/pdfs        "$pkgdir/usr/bin/pdfs"
    
      56  install -Dm755 target/release/pdfs-tray   "$pkgdir/usr/bin/pdfs-tray"
    
      57  install -Dm755 target/release/pdfs-app    "$pkgdir/usr/bin/pdfs-app"
    
      58  install -Dm755 target/release/pdfs-prompt "$pkgdir/usr/bin/pdfs-prompt"
    
      59
    
      60  install -Dm644 packaging/io.narl.proton-drive-linux.desktop \
    
      61    "$pkgdir/usr/share/applications/io.narl.proton-drive-linux.desktop"
    
      62  install -Dm644 packaging/io.narl.proton-drive-linux-tray.desktop \
    
      63    "$pkgdir/etc/xdg/autostart/io.narl.proton-drive-linux-tray.desktop"
    
      64  install -Dm644 packaging/io.narl.proton-drive-linux.svg \
    
      65    "$pkgdir/usr/share/icons/hicolor/scalable/apps/io.narl.proton-drive-linux.svg"
    
      66
    
      67  # systemd user unit for the auto-mount daemon; enabled per user, not by pacman.
    
      68  install -Dm644 packaging/proton-drive.service \
    
      69    "$pkgdir/usr/lib/systemd/user/proton-drive.service"
    
      70
    
      71  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      72  install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
    
      73}
    
      74

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-21 11:34:50	Low	1