proton-drive-for-linux-git
LOW
maintainer Narl
0 votes
scanned 2026-09-21 11:34:50.247705
Why flagged
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
Triggered rules
Low
Few votes, recently uploaded
zero_votes_recent
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
PKGBUILD
1
# Maintainer: Nils Pukropp <contact@narl.io>
2
3
pkgname=proton-drive-for-linux-git
4
pkgver=1.11.1.r0.g860d29c
5
pkgrel=1
6
pkgdesc="Unofficial Proton Drive client: FUSE files-on-demand mount, CLI, GTK4 app, tray (git)"
7
arch=('x86_64')
8
url="https://github.com/narrrl/proton-drive-linux"
9
license=('MIT')
10
depends=('fuse3' 'gtk4' 'libadwaita' 'webkitgtk-6.0' 'dbus' 'gcc-libs' 'glibc'
11
'hicolor-icon-theme')
12
makedepends=('cargo' 'git')
13
optdepends=('perl-image-exiftool: thumbnails for camera RAW files'
14
'gnome-keyring: credential storage over the Secret Service API'
15
'kwallet: credential storage over the Secret Service API'
16
'xdg-utils: "Open folder" action in the tray menu'
17
'fzf: search-as-you-type launcher (pdfs-prompt --fzf)'
18
'foot: terminal that hosts pdfs-prompt --fzf when started from a keybinding')
19
provides=("${pkgname%-git}=$pkgver" "proton-drive-linux=$pkgver" 'pdfs')
20
conflicts=('proton-drive-linux' 'proton-drive-for-linux' 'proton-drive-for-linux-bin')
21
# LTO has broken GTK/Rust links for this workspace; the release profile keeps it off.
22
options=('!lto')
23
source=("$pkgname::git+$url.git")
24
sha256sums=('SKIP')
25
26
pkgver() {
27
cd "$pkgname"
28
git describe --long --abbrev=7 --tags 2>/dev/null |
29
sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
30
printf '0.0.0.r%s.g%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
31
}
32
33
prepare() {
34
cd "$pkgname"
35
export RUSTUP_TOOLCHAIN=stable
36
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
37
}
38
39
build() {
40
cd "$pkgname"
41
export RUSTUP_TOOLCHAIN=stable
42
export CARGO_TARGET_DIR=target
43
cargo build --frozen --release \
44
--bin pdfs \
45
--bin pdfs-tray \
46
--bin pdfs-app \
47
--bin pdfs-prompt
48
}
49
50
check() {
51
cd "$pkgname"
52
export RUSTUP_TOOLCHAIN=stable
53
export CARGO_TARGET_DIR=target
54
cargo test --frozen --workspace
55
}
56
57
package() {
58
cd "$pkgname"
59
60
install -Dm755 target/release/pdfs "$pkgdir/usr/bin/pdfs"
61
install -Dm755 target/release/pdfs-tray "$pkgdir/usr/bin/pdfs-tray"
62
install -Dm755 target/release/pdfs-app "$pkgdir/usr/bin/pdfs-app"
63
install -Dm755 target/release/pdfs-prompt "$pkgdir/usr/bin/pdfs-prompt"
64
65
install -Dm644 packaging/io.narl.proton-drive-linux.desktop \
66
"$pkgdir/usr/share/applications/io.narl.proton-drive-linux.desktop"
67
install -Dm644 packaging/io.narl.proton-drive-linux-tray.desktop \
68
"$pkgdir/etc/xdg/autostart/io.narl.proton-drive-linux-tray.desktop"
69
install -Dm644 packaging/io.narl.proton-drive-linux.svg \
70
"$pkgdir/usr/share/icons/hicolor/scalable/apps/io.narl.proton-drive-linux.svg"
71
72
# systemd user unit for the auto-mount daemon; enabled per user, not by pacman.
73
install -Dm644 packaging/proton-drive.service \
74
"$pkgdir/usr/lib/systemd/user/proton-drive.service"
75
76
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
77
install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
78
}
79
Scan history
| Scanned at (UTC) | Severity | Rules |
|---|---|---|
| 2026-09-21 11:34:50 | Low | 1 |