pwm-d77

CLEAN

maintainer dani-77 0 votes scanned 2026-09-27 00:07:07.510666

View on AUR

Triggered rules

Clean AI review downgraded a static finding llm_review

The static rules flagged this LOW, but an AI model (qwen/qwen3-235b-a22b-2507) reviewed the full PKGBUILD and judged it CLEAN (confidence 95%): The package builds from a legitimate source tarball hosted on the project's own GitHub repository, with a verifiable checksum; no remote code execution or malicious payloads are present.

1 higher static finding superseded - not the current verdict (shown for transparency)

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Daniel Azevedo <daniazevedo77@posteo.net>
    
      2
    
      3pkgname=pwm-d77
    
      4_name=pwm
    
      5pkgver=0.6.4
    
      6pkgrel=1
    
      7pkgdesc="PipaWindowManager, a Penrose Lib Tiling Window Manager"
    
      8arch=('x86_64')
    
      9url="https://github.com/dani-77/pwm"
    
      10license=('MIT')
    
      11provides=('pwm')
    
      12conflicts=('pwm')
    
      13depends=('libx11' 'libxft' 'dmenu' 'st' 'wireless_tools' 'dbus' 'gcc-libs' 'glibc')
    
      14makedepends=('cargo' 'pkgconf')
    
      15optdepends=(
    
      16  'slock: default screen locker'
    
      17  'libpulse: volume keys (pactl)'
    
      18  'feh: wallpaper in startup.sh'
    
      19  'conky: system monitor in startup.sh'
    
      20  'dunst: notifications in startup.sh'
    
      21  'udiskie: automounting in startup.sh'
    
      22  'xcompmgr: compositing in startup.sh'
    
      23  'xautolock: idle locking in startup.sh'
    
      24  'redshift: colour temperature in startup.sh'
    
      25  'sxhkd: extra hotkeys in startup.sh'
    
      26  'xf86-input-synaptics: touchpad tap-to-click in startup.sh'
    
      27)
    
      28backup=('etc/xdg/pwm/startup.sh')
    
      29source=("$_name-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz")
    
      30sha256sums=('33756bdb09fd9f072d78dbcf6320191d3305f33722ce133a53ce3555deab7f15')
    
      31
    
      32prepare() {
    
      33    cd "$_name-$pkgver"
    
      34    export RUSTUP_TOOLCHAIN=stable
    
      35    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      36}
    
      37
    
      38build() {
    
      39    cd "$_name-$pkgver"
    
      40    export RUSTUP_TOOLCHAIN=stable
    
      41    export CARGO_TARGET_DIR=target
    
      42    cargo build --frozen --release
    
      43}
    
      44
    
      45check() {
    
      46    cd "$_name-$pkgver"
    
      47    export RUSTUP_TOOLCHAIN=stable
    
      48    cargo test --frozen --release
    
      49}
    
      50
    
      51package() {
    
      52    cd "$_name-$pkgver"
    
      53    install -Dm755 target/release/pwm "$pkgdir/usr/bin/pwm"
    
      54    install -Dm644 pwm.desktop "$pkgdir/usr/share/xsessions/pwm.desktop"
    
      55    install -d "$pkgdir/etc/xdg/pwm"
    
      56    cp -r etc/xdg/pwm/. "$pkgdir/etc/xdg/pwm/"
    
      57    install -Dm644 usr/share/pwm/config.toml.example \
    
      58        "$pkgdir/usr/share/pwm/config.toml.example"
    
      59    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      60}
    
      61

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-27 00:07:07	Clean	2
2026-09-26 23:16:08	Low	1