python-bencode2

LOW

maintainer marmis 0 votes scanned 2026-08-19 03:41:13.749572

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: marmis <tiagodepalves@gmail.com>
    
      2# Contributor: "marmis" Tiago de Paula <tiagodepalves@gmail.com>
    
      3
    
      4pkgname=python-bencode2
    
      5pkgdesc='A fast and correct bencode serialize/deserialize library in python'
    
      6pkgver=0.3.33
    
      7pkgrel=1
    
      8url='https://github.com/trim21/bencode-py'
    
      9arch=(aarch64 armv7h i486 i686 pentium4 riscv64 x86_64)
    
      10license=('MIT')
    
      11checkdepends=('python-pytest')
    
      12makedepends=(
    
      13  'git'
    
      14  'meson'
    
      15  'meson-python'
    
      16  'ninja'
    
      17  'python-build'
    
      18  'python-flit-core'
    
      19  'python-installer'
    
      20)
    
      21depends=(
    
      22  'glibc'
    
      23  'libgcc'
    
      24  'libstdc++'
    
      25  'python'
    
      26  'python-typing_extensions'
    
      27)
    
      28source=("git+https://github.com/trim21/bencode-py.git#tag=v${pkgver}"
    
      29        "git+https://github.com/gharveymn/small_vector.git#tag=v0.10.2"
    
      30        "git+https://github.com/fmtlib/fmt.git#tag=12.2.0")
    
      31b2sums=('78422099c620cfdf9259fb6e86d78e93aeeb98ce4c6feb802ea641120c8baaf734c55cb5577a1705ff80baa6807056ee0a46721215c4767958e7530f619caebc'
    
      32        'f5c8a7830b0cda273aae4cb8bb8e76b099d1521caf36f9365337ec5b7cfac027c73aaab956770278cc4620a7220d22226083b156958973a383ce8aa9da2ba7be'
    
      33        'e095e1d8e2d95a08f8d6430360e76e9b24a4e213ee83adeeeabf93de09dde325c8e2c4bbbab0907d79f77a21ef5db55ca25f836173f3cd94aecb0cc214fc596d')
    
      34
    
      35prepare() {
    
      36  cd bencode-py
    
      37
    
      38  git submodule init
    
      39  git config submodule.vendor/small_vector.url ../small_vector
    
      40  git config submodule.vendor/fmt.url ../fmt
    
      41  git -c protocol.file.allow=always submodule update
    
      42
    
      43  # unpin build dependencies
    
      44  sed -i -E '
    
      45    s/flit-core==/flit-core>=/
    
      46    s/meson-python==/meson-python>=/
    
      47    s/meson\[ninja\]==/meson>=/
    
      48  ' pyproject.toml
    
      49}
    
      50
    
      51build() {
    
      52  cd bencode-py
    
      53
    
      54  python -m build --wheel --no-isolation \
    
      55    --config-setting setup-args='-Dbuildtype=debugoptimized'
    
      56}
    
      57
    
      58check() {
    
      59  cd bencode-py
    
      60
    
      61  python -m venv --system-site-packages test-env
    
      62  test-env/bin/python -m installer dist/*.whl
    
      63
    
      64  test-env/bin/python -m pytest tests/
    
      65}
    
      66
    
      67package() {
    
      68  cd bencode-py
    
      69
    
      70  python -m installer --destdir "${pkgdir}" dist/*.whl
    
      71
    
      72  install -vD -t "${pkgdir}/usr/share/licenses/${pkgname}/" -m644 LICENSE*
    
      73}
    
      74

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-19 03:41:13	Low	1