python-dapr

CLEAN

maintainer medaminezghal 1 votes scanned 2026-09-26 00:12:15.973514

View on AUR

Triggered rules

Clean AI review downgraded a static finding llm_review

The static rules flagged this LOW, but an AI model (qwen/qwen3-235b-a22b-2507) reviewed the full PKGBUILD and judged it CLEAN (confidence 95%): The package builds the official Dapr Python SDK from its canonical GitHub repository, applies a benign patch for test compatibility, and follows standard Python packaging practices; no remote code execution, untrusted binaries, or malicious payloads are present.

1 higher static finding superseded - not the current verdict (shown for transparency)

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Mohamed Amine Zghal (medaminezghal) <medaminezghal at outlook dot com>
    
      2
    
      3_name=dapr
    
      4pkgname=python-$_name
    
      5pkgver=1.18.3
    
      6pkgrel=1
    
      7pkgdesc='The official release of Dapr Python SDK.'
    
      8arch=('any')
    
      9url='https://github.com/dapr/python-sdk'
    
      10license=('Apache-2.0')
    
      11depends=('python'
    
      12         'python-protobuf'
    
      13         'python-grpcio'
    
      14         'python-grpcio-status'
    
      15         'python-aiohttp'
    
      16         'python-dateutil'
    
      17         'python-typing_extensions')
    
      18makedepends=('python-hatchling'
    
      19             'python-build'
    
      20             'python-installer'
    
      21             'python-wheel'
    
      22             'git')
    
      23checkdepends=('python-opentelemetry-sdk'
    
      24              'python-httpx'
    
      25              'python-cryptography'
    
      26              'python-flask'
    
      27              'python-pytest'
    
      28              'python-pytest-asyncio'
    
      29              'python-pydantic'
    
      30              'python-fastapi')
    
      31source=("$_name::git+$url.git#tag=v$pkgver"
    
      32        "fix-certs-pyopenssl.patch")
    
      33sha256sums=('00a20294b62fb7b628b06fb454dfedf41801f7979b62da11821d99cb93af11e7'
    
      34            '9953c6bc1f9c3162144840a1f450044a5d1b6ffd4db26ccfe4aa48302ef02ec5')
    
      35
    
      36prepare() {
    
      37  cd "$srcdir"/$_name
    
      38  # pyOpenSSL >= 26.2 removed X509.add_extensions used by tests/clients/certs.py;
    
      39  # backport upstream's switch to cryptography (6cce46c, #1111)
    
      40  patch -Np1 -i "$srcdir"/fix-certs-pyopenssl.patch
    
      41}
    
      42
    
      43build() {
    
      44  cd "$srcdir"/$_name
    
      45  python -m build --wheel --no-isolation
    
      46  python -m build --wheel --no-isolation ext/$_name-ext-fastapi
    
      47}
    
      48
    
      49check() {
    
      50  local pytest_options=(
    
      51    -vv
    
      52    --disable-warnings
    
      53    --import-mode=importlib
    
      54    --ignore=tests/integration
    
      55    --ignore=tests/examples
    
      56  )
    
      57  cd "$srcdir"/$_name
    
      58  python -m venv --system-site-packages test-env
    
      59  test-env/bin/python -m installer dist/*.whl
    
      60  test-env/bin/python -m installer ext/$_name-ext-fastapi/dist/*.whl
    
      61  test-env/bin/python -P -m pytest "${pytest_options[@]}" tests
    
      62}
    
      63
    
      64package() {
    
      65  cd "$srcdir"/$_name
    
      66  python -m installer --destdir="$pkgdir" dist/*.whl
    
      67}
    
      68

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-26 00:12:15	Clean	2
2026-09-25 23:13:47	Low	1