python-pan-os-upgrade-assurance

LOW

maintainer evilstack 0 votes scanned 2026-10-25 03:41:34.818471

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Michael Gates <michael at belowthesalt . us>
    
      2pkgname=python-pan-os-upgrade-assurance
    
      3_name=pan-os-upgrade-assurance
    
      4pkgver=2.1.1
    
      5pkgrel=1
    
      6pkgdesc="Libraries for Palo Alto Networks PAN-OS Upgrade Assurance"
    
      7arch=('any')
    
      8url="https://github.com/PaloAltoNetworks/${_name}"
    
      9license=('ISC')
    
      10depends=('python' 'python-pan-os-python' 'python-xmltodict' 'python-pyopenssl' 'python-packaging' 'python-typing_extensions')
    
      11makedepends=('python-build' 'python-installer' 'python-poetry')
    
      12checkdepends=('python-pytest' 'python-deepdiff')
    
      13source=("v${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
    
      14sha256sums=('5b7b1d0cc0c270b74865d1ebc472056372a02c307af99ca5f1faeb4e6ea2bef9')
    
      15
    
      16build() {
    
      17  cd "${_name}-${pkgver}"
    
      18  python -m build --wheel --no-isolation
    
      19}
    
      20
    
      21check() {
    
      22  cd "${_name}-${pkgver}"
    
      23  python -m installer --destdir=test_dir dist/*.whl
    
      24  local site_packages
    
      25  site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
    
      26  PYTHONPATH="test_dir/${site_packages}" python -c "import panos_upgrade_assurance; from panos_upgrade_assurance.firewall_proxy import FirewallProxy; print('Import check passed')"
    
      27  PYTHONPATH="test_dir/${site_packages}" pytest --deselect=tests/test_standards.py -o addopts="" -x --tb=short
    
      28}
    
      29
    
      30package() {
    
      31  cd "${_name}-${pkgver}"
    
      32  python -m installer --destdir="${pkgdir}" dist/*.whl
    
      33  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
    
      34}
    
      35

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-25 03:41:34	Low	1