python-pan-python

LOW

maintainer evilstack 0 votes scanned 2026-10-23 05:36:55.005421

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# shellcheck shell=bash
    
      2# Maintainer: Michael Gates \\michael et belowthesalt us\\
    
      3pkgname=python-pan-python
    
      4_name=pan-python
    
      5_altname=pan_python
    
      6pkgver=0.26.0
    
      7pkgrel=1
    
      8pkgdesc="Multi-tool set for Palo Alto Networks PAN-OS, Panorama, WildFire and AutoFocus"
    
      9arch=('any')
    
      10url="https://github.com/kevinsteves/${_name}"
    
      11license=('ISC')
    
      12depends=('python')
    
      13makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
    
      14
    
      15# wfapi uses certifi's CA bundle instead of the system store if
    
      16# certifi is installed (likely) and ssl_context is None (default).
    
      17# Behind TLS decryption, pass your own ssl_context (e.g., /etc/ssl/certs).
    
      18optdepends=('python-requests: HTTP backend used automatically if present (else urllib)'
    
      19            'python-certifi: CA bundle for WildFire API certificate verification (overrides system CA store)')
    
      20source=("${_name}-${pkgver}.tar.gz::${url}/releases/download/v${pkgver}/${_altname}-${pkgver}.tar.gz")
    
      21sha256sums=('0a0ea34279b745e8e3d55df015e18ab299051ffdd519128d9340ff7aae4e2392')
    
      22
    
      23build() {
    
      24  cd "${_altname}-${pkgver}"
    
      25  python -m build --wheel --no-isolation
    
      26}
    
      27
    
      28package() {
    
      29  cd "${_altname}-${pkgver}"
    
      30  python -m installer --destdir="${pkgdir}" dist/*.whl
    
      31  install -Dm644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
    
      32}
    
      33
    
      34check() {
    
      35  cd "${_altname}-${pkgver}"
    
      36  python -m installer --destdir=test_dir dist/*.whl
    
      37  local site_packages
    
      38  site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
    
      39  PYTHONPATH="test_dir/${site_packages}" python -c "import pan.xapi, pan.licapi, pan.wfapi, pan.afapi"
    
      40}
    
      41

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-23 05:36:55	Low	1