python-pdf-inspector

LOW

maintainer nvidiahater 0 votes scanned 2026-09-08 05:16:12.985842

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1pkgname=python-pdf-inspector
    
      2pkgver=1.18.0
    
      3pkgrel=1
    
      4pkgdesc="Python bindings for PDF classification and Markdown extraction with OCR"
    
      5arch=('x86_64' 'aarch64')
    
      6url="https://github.com/firecrawl/pdf-inspector"
    
      7license=('MIT' 'BSD-3-Clause')
    
      8depends=('ca-certificates' 'gcc-libs' 'glibc' 'python')
    
      9makedepends=('cargo' 'python-build' 'python-installer' 'python-maturin')
    
      10optdepends=('libpdfium: PDF page rendering for OCR'
    
      11            'onnxruntime>=1.27.0: CPU OCR inference')
    
      12# The ring dependency cannot link with GCC LTO.
    
      13options=('!debug' '!lto')
    
      14source=("pdf-inspector-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
    
      15sha256sums=('c90af30cfdb8fa0220b5b66bff4d2422847c33634e80bd046a9076bf409200b1')
    
      16
    
      17prepare() {
    
      18  cd "pdf-inspector-${pkgver}"
    
      19  # Load installed CMaps instead of files in the build directory.
    
      20  sed -i 's|Path::new(env!("CARGO_MANIFEST_DIR"))|Path::new("/usr/share/python-pdf-inspector")|; /\.join("external")/d' src/tounicode.rs
    
      21  cargo fetch
    
      22}
    
      23
    
      24build() {
    
      25  cd "pdf-inspector-${pkgver}"
    
      26  CARGO_NET_OFFLINE=true python -m build --wheel --no-isolation \
    
      27    --config-setting="build-args=--locked --compatibility linux"
    
      28}
    
      29
    
      30package() {
    
      31  cd "pdf-inspector-${pkgver}"
    
      32  python -m installer --destdir="${pkgdir}" --prefix=/usr dist/*.whl
    
      33  install -Dm644 external/bcmaps/*.bcmap -t "${pkgdir}/usr/share/${pkgname}/bcmaps/"
    
      34  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      35  install -Dm644 external/bcmaps/LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-bcmaps"
    
      36  install -Dm644 docs/ocr-runtime.md "${pkgdir}/usr/share/doc/${pkgname}/ocr-runtime.md"
    
      37}
    
      38

Changes since previous scan

--- PKGBUILD @ 2026-09-06 00:17
+++ PKGBUILD @ 2026-09-08 05:16
@@ -1,5 +1,5 @@
 pkgname=python-pdf-inspector
-pkgver=1.15.0
+pkgver=1.18.0
 pkgrel=1
 pkgdesc="Python bindings for PDF classification and Markdown extraction with OCR"
 arch=('x86_64' 'aarch64')
@@ -12,7 +12,7 @@
 # The ring dependency cannot link with GCC LTO.
 options=('!debug' '!lto')
 source=("pdf-inspector-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
-sha256sums=('156fbfed4765a4a9e3974f8b402a4fd04420301d1d960c0ca2963a1b2ee8a29f')
+sha256sums=('c90af30cfdb8fa0220b5b66bff4d2422847c33634e80bd046a9076bf409200b1')
 
 prepare() {
   cd "pdf-inspector-${pkgver}"

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-08 05:16:12	Low	1
2026-09-06 00:17:06	Clean	2
2026-09-06 00:01:42	Low	1