python-timestral-git

LOW

maintainer rnbguy 0 votes scanned 2026-10-22 00:13:10.488046

View on AUR

Why flagged

The package builds from the official project Git repository, uses SKIP for checksums due to frequent changes, and installs only the project's own code; the low severity is due to lack of verifiable source integrity, not malicious intent.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package builds from the official project Git repository, uses SKIP for checksums due to frequent changes, and installs only the project's own code; the low severity is due to lack of verifiable source integrity, not malicious intent.

PKGBUILD

      1# Maintainer: rnbguy
    
      2
    
      3pkgname=python-timestral-git
    
      4pkgver=r1.a534bdb
    
      5pkgrel=1
    
      6pkgdesc='Standalone inference for Mistral AI Timestral time-series forecasting models'
    
      7arch=('any')
    
      8url='https://github.com/mistralai/timestral'
    
      9license=('Apache-2.0')
    
      10depends=(
    
      11  'python'
    
      12  'python-huggingface-hub>=0.23'
    
      13  'python-numpy>=1.24'
    
      14  'python-pytorch>=2.4'
    
      15  'python-safetensors>=0.4'
    
      16)
    
      17makedepends=(
    
      18  'git'
    
      19  'python-build'
    
      20  'python-installer'
    
      21  'python-setuptools>=77'
    
      22  'python-wheel'
    
      23)
    
      24checkdepends=('python-pytest')
    
      25provides=('python-timestral')
    
      26conflicts=('python-timestral')
    
      27source=('timestral::git+https://github.com/mistralai/timestral.git#branch=main')
    
      28sha256sums=('SKIP')
    
      29
    
      30# Upstream has no tags; use the commit count and hash for the version.
    
      31pkgver() {
    
      32  cd timestral
    
      33  printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
    
      34}
    
      35
    
      36build() {
    
      37  cd timestral
    
      38  python -m build --wheel --no-isolation
    
      39}
    
      40
    
      41check() {
    
      42  cd timestral
    
      43  python -m venv --system-site-packages test-env
    
      44  test-env/bin/python -m installer dist/*.whl
    
      45  test-env/bin/python -m pytest tests
    
      46}
    
      47
    
      48package() {
    
      49  cd timestral
    
      50  python -m installer --destdir="$pkgdir" dist/*.whl
    
      51  install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
    
      52}
    
      53

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-22 00:13:10	Low	2
2026-10-21 09:31:11	Low	2