qqtui

LOW

maintainer w568w 0 votes scanned 2026-10-17 17:19:05.078207

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: w568w <w568w at outlook dot com>
    
      2
    
      3pkgname=qqtui
    
      4pkgver=0.1.1
    
      5pkgrel=1
    
      6pkgdesc='Terminal frontend using the native Linux QQ service'
    
      7arch=('x86_64')
    
      8url='https://github.com/w568w/qqtui'
    
      9license=('MPL-2.0')
    
      10depends=('glibc' 'gcc-libs' 'sqlite>=3.51.2' 'systemd' 'dbus' 'xorg-server-xvfb'
    
      11         'xorg-xauth' 'xorg-xkbcomp' 'tigervnc' 'novnc'
    
      12         'linuxqq=5:3.2.34_53644')
    
      13makedepends=('cargo')
    
      14checkdepends=('nodejs' 'python')
    
      15optdepends=('kitty: inline images and animations'
    
      16            'noto-fonts-cjk: Chinese text in the terminal and QQ login page'
    
      17            'firefox: browser for first login (other graphical browsers also work)'
    
      18            'wl-clipboard: Wayland clipboard'
    
      19            'xclip: X11 clipboard'
    
      20            'xdg-utils: open files and links in external applications')
    
      21source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      22sha256sums=('adf256c36ee77a9a3f3ed0d595e013614ed46898b2565708b9475f8fb87ce3ca')
    
      23
    
      24prepare() {
    
      25  cd "qqtui-$pkgver"
    
      26  export RUSTUP_TOOLCHAIN=stable
    
      27  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
    
      28}
    
      29
    
      30build() {
    
      31  cd "qqtui-$pkgver"
    
      32  export RUSTUP_TOOLCHAIN=stable
    
      33  cargo build --release --frozen
    
      34}
    
      35
    
      36check() {
    
      37  cd "qqtui-$pkgver"
    
      38  export RUSTUP_TOOLCHAIN=stable
    
      39  cargo test --release --frozen
    
      40  node --test tests/native.test.cjs tests/journal.test.cjs
    
      41  python tests/loader.test.py
    
      42}
    
      43
    
      44package() {
    
      45  cd "qqtui-$pkgver"
    
      46  install -Dm755 target/release/qqtui "$pkgdir/usr/bin/qqtui"
    
      47  install -Dm644 packaging/systemd/qqtui-host.service \
    
      48    "$pkgdir/usr/lib/systemd/user/qqtui-host.service"
    
      49  install -Dm644 packaging/systemd/qqtui-host@.service \
    
      50    "$pkgdir/usr/lib/systemd/user/qqtui-host@.service"
    
      51  local doc
    
      52  for doc in README.md CONTRIBUTING.md docs/*.md bridge/compatibility.json; do
    
      53    install -Dm644 "$doc" "$pkgdir/usr/share/doc/qqtui/$doc"
    
      54  done
    
      55  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/qqtui/LICENSE"
    
      56  ln -s ../../licenses/qqtui/LICENSE "$pkgdir/usr/share/doc/qqtui/LICENSE"
    
      57}
    
      58

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-17 17:19:05	Low	1