qqtui-bin

LOW

maintainer w568w 0 votes scanned 2026-10-18 09:21:55.083363

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: w568w <w568w at outlook dot com>
    
      2
    
      3pkgname=qqtui-bin
    
      4pkgver=0.1.2
    
      5pkgrel=1
    
      6pkgdesc='Terminal frontend using the native Linux QQ service'
    
      7arch=('x86_64')
    
      8url='https://github.com/w568w/qqtui'
    
      9license=('MPL-2.0')
    
      10depends=('glibc' 'libgcc' 'sqlite>=3.51.2' 'systemd' 'dbus' 'xorg-server-xvfb'
    
      11         'xorg-xauth' 'xorg-xkbcomp' 'tigervnc' 'novnc'
    
      12         'linuxqq=5:3.2.34_53644')
    
      13optdepends=('kitty: inline images and animations'
    
      14            'noto-fonts-cjk: Chinese text in the terminal and QQ login page'
    
      15            'firefox: browser for first login (other graphical browsers also work)'
    
      16            'wl-clipboard: Wayland clipboard'
    
      17            'xclip: X11 clipboard'
    
      18            'xdg-utils: open files and links in external applications')
    
      19provides=("qqtui=$pkgver")
    
      20conflicts=('qqtui')
    
      21options=('!strip')
    
      22source=("$url/releases/download/v$pkgver/qqtui-$pkgver-linux-$CARCH.tar.gz")
    
      23sha256sums=('2037762de18abbf843a93446235a8513b630c1729671b0c779c71b43bf88392b')
    
      24
    
      25package() {
    
      26  cd "qqtui-$pkgver-linux-$CARCH"
    
      27  install -Dm755 qqtui "$pkgdir/usr/bin/qqtui"
    
      28  install -Dm644 packaging/systemd/qqtui-host.service \
    
      29    "$pkgdir/usr/lib/systemd/user/qqtui-host.service"
    
      30  install -Dm644 packaging/systemd/qqtui-host@.service \
    
      31    "$pkgdir/usr/lib/systemd/user/qqtui-host@.service"
    
      32  local doc
    
      33  for doc in README.md CONTRIBUTING.md docs/*.md bridge/compatibility.json; do
    
      34    install -Dm644 "$doc" "$pkgdir/usr/share/doc/qqtui/$doc"
    
      35  done
    
      36  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/qqtui/LICENSE"
    
      37  ln -s ../../licenses/qqtui/LICENSE "$pkgdir/usr/share/doc/qqtui/LICENSE"
    
      38}
    
      39

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-18 09:21:55	Low	1