rake-unstable

LOW

maintainer jozias 0 votes scanned 2026-09-17 00:27:14.276658

View on AUR

Why flagged

The source is a tarball from the maintainer's personal domain, but it contains the project's own source code which is then compiled normally; the realistic worst case of a swapped source is limited to code execution during build, which is typical for AUR packages building from source, and the checksum is provided.

Triggered rules

Low AI review downgraded a static finding llm_review

The static rules flagged this MEDIUM, but an AI model (qwen/qwen3-235b-a22b-2507) reviewed the full PKGBUILD and judged it LOW (confidence 95%): The source is a tarball from the maintainer's personal domain, but it contains the project's own source code which is then compiled normally; the realistic worst case of a swapped source is limited to code execution during build, which is typical for AUR packages building from source, and the checksum is provided.

1 higher static finding superseded - not the current verdict (shown for transparency)

Medium source=() URL on a non-standard host source_untrusted_domain

One or more source=() URLs point to a host outside the trusted allowlist (github.com, gitlab.com, codeberg.org, pypi.org, …).

PKGBUILD:13 source=("$pkgname-$pkgver.tar.gz::https://git.jasonozias.com/dl/cargo-rake/v${pkgver}/cargo-rake-$pkgver-src.tar.gz")

PKGBUILD

1 offending line(s) highlighted

      1# Maintainer: Jason Ozias <jason.g.ozias@gmail.com>
    
      2
    
      3pkgname=rake-unstable
    
      4pkgver=0.7.4
    
      5pkgrel=1
    
      6pkgdesc="Configuration-driven build tool that runs Rakefile.toml targets (nightly unstable build)"
    
      7arch=('x86_64')
    
      8url="https://github.com/rustyhorde/cargo-rake"
    
      9license=('MIT' 'Apache-2.0')
    
      10provides=('rake')
    
      11conflicts=('rake')
    
      12makedepends=('cargo')
    
      13source=("$pkgname-$pkgver.tar.gz::https://git.jasonozias.com/dl/cargo-rake/v${pkgver}/cargo-rake-$pkgver-src.tar.gz")
    
      14# Checksum is filled in by the release workflow before publishing to the AUR.
    
      15sha256sums=('1144862f8aaac73f1a5375e3568c3dd2a5d8debb9ab27f910458615fbb868e01')
    
      16
    
      17prepare() {
    
      18    cd "cargo-rake-$pkgver"
    
      19    # The `unstable` feature is a functional no-op (it only toggles nightly-only
    
      20    # lint gates), so the unstable variant builds on the stable toolchain just
    
      21    # like `rake`.
    
      22    export RUSTUP_TOOLCHAIN=stable
    
      23    cargo fetch --locked --target x86_64-unknown-linux-gnu
    
      24}
    
      25
    
      26build() {
    
      27    cd "cargo-rake-$pkgver"
    
      28    export RUSTUP_TOOLCHAIN=stable
    
      29    export CARGO_TARGET_DIR=target
    
      30    export VERGEN_IDEMPOTENT=1
    
      31    cargo build --release --locked --bin rake --features unstable
    
      32    cargo run --release --locked -p xtask -- dist rake
    
      33}
    
      34
    
      35package() {
    
      36    cd "cargo-rake-$pkgver"
    
      37
    
      38    install -Dm755 "target/release/rake" "$pkgdir/usr/bin/rake"
    
      39
    
      40    # Man page
    
      41    install -Dm644 "dist/rake/rake.1" "$pkgdir/usr/share/man/man1/rake.1"
    
      42
    
      43    # Shell completions
    
      44    install -Dm644 "dist/rake/rake.bash" \
    
      45        "$pkgdir/usr/share/bash-completion/completions/rake"
    
      46    install -Dm644 "dist/rake/_rake" \
    
      47        "$pkgdir/usr/share/zsh/site-functions/_rake"
    
      48    install -Dm644 "dist/rake/rake.fish" \
    
      49        "$pkgdir/usr/share/fish/vendor_completions.d/rake.fish"
    
      50
    
      51    # Example Rakefile and documentation
    
      52    install -Dm644 "dist/rake/Rakefile.toml.example" \
    
      53        "$pkgdir/usr/share/doc/$pkgname/examples/Rakefile.toml.example"
    
      54    install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
    
      55
    
      56    # Licenses
    
      57    install -Dm644 LICENSE-MIT    "$pkgdir/usr/share/licenses/$pkgname/LICENSE-MIT"
    
      58    install -Dm644 LICENSE-APACHE "$pkgdir/usr/share/licenses/$pkgname/LICENSE-APACHE"
    
      59}
    
      60

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-17 00:27:14	Low	2
2026-09-16 00:03:17	Low	2
2026-09-15 00:25:31	Low	2
2026-09-14 00:27:57	Low	2
2026-09-13 00:19:54	Low	2
2026-09-12 00:25:17	Low	2
2026-09-11 00:19:22	Low	2
2026-09-10 00:22:44	Low	2
2026-09-09 00:04:09	Low	2
2026-09-08 00:18:08	Low	2
2026-09-07 00:30:15	Low	2
2026-09-06 00:17:06	Low	2
2026-09-05 00:16:27	Low	2
2026-09-04 00:03:13	Low	2
2026-09-03 00:15:47	Low	2
2026-09-02 00:02:31	Low	2
2026-09-01 00:11:19	Low	2
2026-08-31 00:19:57	Low	2
2026-08-30 00:04:14	Low	2
2026-08-29 00:29:17	Low	2