rimor

LOW

maintainer alchemy 0 votes scanned 2026-10-06 08:02:16.298752

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Filippo Veneri <filippo.veneri@gmail.com>
    
      2#
    
      3# Template: the release workflow sets pkgver, pkgrel and the checksum from
    
      4# the tag, then publishes it to the AUR.
    
      5pkgname=rimor
    
      6pkgver=0.3.0
    
      7pkgrel=1
    
      8pkgdesc='Terminal workbench for PostgreSQL, SQL Server and SQLite'
    
      9arch=('x86_64' 'aarch64')
    
      10url='https://rimor.dev'
    
      11license=('MIT')
    
      12depends=('glibc') # the PIE build uses the system's dynamic loader
    
      13makedepends=('go')
    
      14source=("${pkgname}-${pkgver}.tar.gz::https://github.com/alchemy/rimor/archive/refs/tags/v${pkgver}.tar.gz")
    
      15sha256sums=('511343b87641bd274f4d32b91f5e6c1adaca2cce0088d83fa660ce5a96c2d5fa')
    
      16
    
      17prepare() {
    
      18  cd "${pkgname}-${pkgver}"
    
      19  export GOPATH="${srcdir}/gopath"
    
      20  go mod download -modcacherw
    
      21}
    
      22
    
      23build() {
    
      24  cd "${pkgname}-${pkgver}"
    
      25  export GOPATH="${srcdir}/gopath"
    
      26  # Pure Go, SQLite driver included: no cgo, so no C flags to pass on.
    
      27  export CGO_ENABLED=0
    
      28  # No VCS stamping: makepkg may unpack the sources inside another git
    
      29  # repository (an AUR clone, a CI checkout), whose state is not rimor's;
    
      30  # the version comes from -ldflags instead.
    
      31  export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw -buildvcs=false"
    
      32  go build -ldflags "-X main.version=v${pkgver}" -o rimor ./cmd/rimor
    
      33}
    
      34
    
      35check() {
    
      36  cd "${pkgname}-${pkgver}"
    
      37  export GOPATH="${srcdir}/gopath"
    
      38  export GOFLAGS="-mod=readonly -modcacherw -buildvcs=false"
    
      39  # Database server tests skip without their RIMOR_TEST_* settings.
    
      40  go test ./...
    
      41}
    
      42
    
      43package() {
    
      44  cd "${pkgname}-${pkgver}"
    
      45  install -Dm755 rimor "${pkgdir}/usr/bin/rimor"
    
      46  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      47  install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
    
      48}
    
      49

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-06 08:02:16	Low	1
2026-10-06 00:13:36	Clean	2
2026-10-05 23:40:58	Low	1