ros2-jazzy-self_test

LOW
maintainer AutoUpdateBot 0 votes base ros2-jazzy-diagnostics scanned 2026-09-05 05:59:21.758090
View on AUR
Why flagged
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
Triggered rules

Low Few votes, recently uploaded zero_votes_recent
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
PKGBUILD

      1# Maintainer: AutoUpdateBot <auto-update-bot@arch4edu.org>
    
      2
    
      3pkgbase=ros2-jazzy-diagnostics
    
      4pkgname=(
    
      5    'ros2-jazzy-diagnostic_updater'
    
      6    'ros2-jazzy-diagnostic_aggregator'
    
      7    'ros2-jazzy-diagnostic_common_diagnostics'
    
      8    'ros2-jazzy-diagnostic_remote_logging'
    
      9    'ros2-jazzy-self_test'
    
      10    'ros2-jazzy-diagnostics'
    
      11)
    
      12pkgver=4.2.7
    
      13pkgrel=1
    
      14pkgdesc="Diagnostics packages for ROS 2 Jazzy"
    
      15url="https://github.com/ros/diagnostics"
    
      16arch=('x86_64')
    
      17license=('BSD-3-Clause')
    
      18depends=('ros2-jazzy')
    
      19makedepends=('cmake')
    
      20source=("$pkgbase-$pkgver.tar.gz::https://github.com/ros/diagnostics/archive/refs/tags/${pkgver}.tar.gz")
    
      21sha256sums=('d8ae00740db5eb3a23a7fa5f3cfa7e3c0d1082edcad5209ab84900d0368908fd')
    
      22
    
      23_srcname="diagnostics-$pkgver"
    
      24
    
      25_build_cmake() {
    
      26    local _sub="$1"
    
      27    shift
    
      28
    
      29    source /opt/ros/jazzy/setup.bash
    
      30
    
      31    local _prefix='' _dep
    
      32    for _dep in "$@"; do
    
      33        _prefix+="$srcdir/_staging/$_dep/opt/ros/jazzy:"
    
      34    done
    
      35
    
      36    CMAKE_PREFIX_PATH="${_prefix}${CMAKE_PREFIX_PATH}" \
    
      37        cmake -B "$srcdir/build-$_sub" -S "$srcdir/$_srcname/$_sub" \
    
      38            -DCMAKE_BUILD_TYPE='None' \
    
      39            -DCMAKE_INSTALL_PREFIX='/opt/ros/jazzy' \
    
      40            -DBUILD_TESTING=OFF \
    
      41            -Wno-dev
    
      42    cmake --build "$srcdir/build-$_sub"
    
      43    DESTDIR="$srcdir/_staging/$_sub" cmake --install "$srcdir/build-$_sub"
    
      44}
    
      45
    
      46build() {
    
      47    rm -rf "$srcdir/_staging"
    
      48
    
      49    # Compiled nodes embed __FILE__ build paths.
    
      50    export CFLAGS+=" -ffile-prefix-map=$srcdir=/usr/src/debug/$pkgbase"
    
      51    export CXXFLAGS+=" -ffile-prefix-map=$srcdir=/usr/src/debug/$pkgbase"
    
      52
    
      53    _build_cmake diagnostic_updater
    
      54    _build_cmake diagnostic_aggregator
    
      55    _build_cmake diagnostic_common_diagnostics diagnostic_updater
    
      56    _build_cmake diagnostic_remote_logging
    
      57    _build_cmake self_test diagnostic_updater
    
      58    _build_cmake diagnostics
    
      59}
    
      60
    
      61package_ros2-jazzy-diagnostic_updater() {
    
      62    pkgdesc="Tools for easily updating ROS 2 diagnostics"
    
      63    depends=('ros2-jazzy')
    
      64
    
      65    cp -a "$srcdir/_staging/diagnostic_updater/." "$pkgdir/"
    
      66    install -Dm644 "$srcdir/$_srcname/LICENSE" \
    
      67        "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      68}
    
      69
    
      70package_ros2-jazzy-diagnostic_aggregator() {
    
      71    pkgdesc="Aggregates and categorizes ROS 2 diagnostic messages"
    
      72    depends=('ros2-jazzy')
    
      73
    
      74    cp -a "$srcdir/_staging/diagnostic_aggregator/." "$pkgdir/"
    
      75    install -Dm644 "$srcdir/$_srcname/LICENSE" \
    
      76        "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      77}
    
      78
    
      79package_ros2-jazzy-diagnostic_common_diagnostics() {
    
      80    pkgdesc="Predefined diagnostic nodes for monitoring Linux and ROS 2 systems"
    
      81    arch=('any')
    
      82    depends=('ros2-jazzy' 'ros2-jazzy-diagnostic_updater' 'lm_sensors' 'python-psutil' 'python-ntplib')
    
      83
    
      84    cp -a "$srcdir/_staging/diagnostic_common_diagnostics/." "$pkgdir/"
    
      85    install -Dm644 "$srcdir/$_srcname/LICENSE" \
    
      86        "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      87}
    
      88
    
      89package_ros2-jazzy-diagnostic_remote_logging() {
    
      90    pkgdesc="Remote logging for ROS 2 diagnostics (InfluxDB)"
    
      91    depends=('ros2-jazzy' 'curl')
    
      92
    
      93    cp -a "$srcdir/_staging/diagnostic_remote_logging/." "$pkgdir/"
    
      94    install -Dm644 "$srcdir/$_srcname/LICENSE" \
    
      95        "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      96}
    
      97
    
      98package_ros2-jazzy-self_test() {
    
      99    pkgdesc="Self-test tools for ROS 2 diagnostics"
    
      100    depends=('ros2-jazzy' 'ros2-jazzy-diagnostic_updater')
    
      101
    
      102    cp -a "$srcdir/_staging/self_test/." "$pkgdir/"
    
      103    install -Dm644 "$srcdir/$_srcname/LICENSE" \
    
      104        "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      105}
    
      106
    
      107package_ros2-jazzy-diagnostics() {
    
      108    pkgdesc="Metapackage for the ROS 2 diagnostics suite"
    
      109    arch=('any')
    
      110    depends=(
    
      111        'ros2-jazzy-diagnostic_updater'
    
      112        'ros2-jazzy-diagnostic_aggregator'
    
      113        'ros2-jazzy-diagnostic_common_diagnostics'
    
      114        'ros2-jazzy-diagnostic_remote_logging'
    
      115        'ros2-jazzy-self_test'
    
      116    )
    
      117
    
      118    cp -a "$srcdir/_staging/diagnostics/." "$pkgdir/"
    
      119    install -Dm644 "$srcdir/$_srcname/LICENSE" \
    
      120        "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      121}
    
      122
Scan history

Scanned at (UTC)	Severity	Rules
2026-09-05 05:59:21	Low	1