rune-ide

LOW
maintainer leynebe 0 votes scanned 2026-10-07 16:05:57.670383
View on AUR
Why flagged
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
Triggered rules

Low Few votes, recently uploaded zero_votes_recent
Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.
PKGBUILD

      1# Maintainer: Ben Leynen <leynenben@gmail.com>
    
      2
    
      3pkgname=rune-ide
    
      4_pkgname=rune
    
      5_binaryname=rune
    
      6pkgdesc="Fast, GPU-rendered, keyboard-driven IDE for power users"
    
      7pkgver=1.2.1
    
      8pkgrel=1
    
      9arch=('x86_64' 'aarch64')
    
      10url="https://github.com/unstablebuild/rune"
    
      11license=('GPL-3.0-or-later')
    
      12# makepkg's default LTO CFLAGS can break cgo builds, and Go emits no DWARF
    
      13# that makepkg's debug split can use (empty /usr/src/debug)
    
      14options=('!lto' '!debug')
    
      15# the GUI dlopens its graphics and X11 libraries only when a window opens,
    
      16# so they're optional and --tui/--headless work without a graphical stack
    
      17depends=('glibc' 'hicolor-icon-theme')
    
      18makedepends=(
    
      19    'go'
    
      20    'git'
    
      21    'alsa-lib'
    
      22    'wayland'
    
      23    'libxkbcommon'
    
      24    'libx11'
    
      25    'libxcursor'
    
      26    'libxext'
    
      27    'libxi'
    
      28    'libxinerama'
    
      29    'libxrandr'
    
      30    'libxrender'
    
      31    'libxxf86vm'
    
      32    'libglvnd'
    
      33)
    
      34optdepends=(
    
      35    'zsh: bundled shell profile bootstrap'
    
      36    'libglvnd: OpenGL and EGL GUI support'
    
      37    'libx11: X11 GUI support'
    
      38    'libxcursor: X11 cursor support'
    
      39    'libxext: X11 extension support'
    
      40    'libxi: XInput GUI support'
    
      41    'libxinerama: Xinerama multi-monitor GUI support'
    
      42    'libxrandr: RandR display configuration support'
    
      43    'libxrender: XRender GUI support'
    
      44    'libxxf86vm: XF86VidMode GUI support'
    
      45)
    
      46conflicts=("${pkgname}-bin")
    
      47
    
      48source=("${pkgname}-src::git+${url}.git#tag=v${pkgver}")
    
      49sha256sums=('21c1429df444c9320c29291b32c4add3cc66aff62730ef3954628a710a1b5c96')
    
      50
    
      51prepare() {
    
      52    cd "${srcdir}/${pkgname}-src"
    
      53    export GOPATH="${srcdir}/gopath"
    
      54    go mod download -modcacherw
    
      55}
    
      56
    
      57build() {
    
      58    cd "${srcdir}/${pkgname}-src"
    
      59    export GOPATH="${srcdir}/gopath"
    
      60    export CGO_ENABLED=1
    
      61    export CGO_CPPFLAGS="${CPPFLAGS}"
    
      62    export CGO_CFLAGS="${CFLAGS}"
    
      63    export CGO_CXXFLAGS="${CXXFLAGS}"
    
      64    export CGO_LDFLAGS="${LDFLAGS}"
    
      65    export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
    
      66
    
      67    local _builddate _commit
    
      68    _builddate="$(go run ./cmd/buildstamp)"
    
      69    _commit="$(git rev-parse --short HEAD)"
    
      70
    
      71    # mirrors upstream's dist/arch/PKGBUILD (RUNE_ENV=prod in cmd/rune/Makefile)
    
      72    go build \
    
      73        -tags ebitensinglethread \
    
      74        -ldflags "-linkmode=external \
    
      75            -X unstable.build/rune/internal/debug.Tag=v${pkgver} \
    
      76            -X unstable.build/rune/internal/debug.Commit=${_commit} \
    
      77            -X unstable.build/rune/internal/debug.BuildDate=${_builddate} \
    
      78            -X unstable.build/rune/internal/debug.Package=rune \
    
      79            -X unstable.build/rune/internal/debug.OSPackaged=true" \
    
      80        -o "${_binaryname}" ./cmd/rune
    
      81}
    
      82
    
      83package() {
    
      84    cd "${srcdir}/${pkgname}-src"
    
      85
    
      86    # the binary only picks up share/zdot when it lives at .../rune.app/bin/,
    
      87    # so the upstream bundle layout is kept intact
    
      88    local _appdir="/usr/lib/${pkgname}/${_pkgname}.app"
    
      89    install -D -m0755 "${_binaryname}" "${pkgdir}${_appdir}/bin/${_binaryname}"
    
      90    for f in .zlogin .zprofile .zshenv .zshrc; do
    
      91        install -D -m0644 "extra/osx/Rune.app/Contents/Resources/zdot/$f" "${pkgdir}${_appdir}/share/zdot/$f"
    
      92    done
    
      93
    
      94    install -d "${pkgdir}/usr/bin"
    
      95    ln -s "${_appdir}/bin/${_binaryname}" "${pkgdir}/usr/bin/${_binaryname}"
    
      96
    
      97    # renamed from upstream's rune.desktop: the unrelated AUR package
    
      98    # "rune" (a Loki Entertainment game) already owns that filename
    
      99    install -D -m0644 "deploy/rune-linux/${_pkgname}.desktop" "${pkgdir}/usr/share/applications/rune-ide.desktop"
    
      100    install -D -m0644 "extra/icon.iconset/icon_512x512.png" "${pkgdir}/usr/share/icons/hicolor/512x512/apps/${_pkgname}.png"
    
      101    install -D -m0644 "extra/icon.iconset/icon_512x512@2x.png" "${pkgdir}/usr/share/icons/hicolor/1024x1024/apps/${_pkgname}.png"
    
      102
    
      103    install -D -m0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      104}
    
      105
Scan history

Scanned at (UTC)	Severity	Rules
2026-10-07 16:05:57	Low	1