rust-discord-overlay

LOW

maintainer Deddroid 0 votes scanned 2026-10-20 09:27:54.737837

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: deddroid <deddo9412@gmail.com>
    
      2pkgname=rust-discord-overlay
    
      3pkgver=0.2.0
    
      4pkgrel=1
    
      5pkgdesc="Lightweight Discord voice/text overlay for Linux (Wayland, GTK4 layer-shell), written in Rust"
    
      6arch=('x86_64')
    
      7url="https://github.com/deddroid/rust-discord-overlay"
    
      8license=('GPL-3.0-or-later')
    
      9depends=(
    
      10    'cairo'
    
      11    'dbus'
    
      12    'gcc-libs'
    
      13    'glib2'
    
      14    'glibc'
    
      15    'gtk4'
    
      16    'gtk4-layer-shell'
    
      17    'libadwaita'
    
      18    'openssl'
    
      19    'pango'
    
      20)
    
      21makedepends=('cargo' 'librsvg')
    
      22optdepends=('libpulse: sync system mic/speaker mute with Discord (pactl)')
    
      23source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      24sha256sums=('5aac1835cc98cacd316b38aa916bb9b649f26d9ec53254347df4f31975f8b0c5')
    
      25
    
      26prepare() {
    
      27    cd "$pkgname-$pkgver"
    
      28    export RUSTUP_TOOLCHAIN=stable
    
      29    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      30}
    
      31
    
      32build() {
    
      33    cd "$pkgname-$pkgver"
    
      34    export RUSTUP_TOOLCHAIN=stable
    
      35    export CARGO_TARGET_DIR=target
    
      36    cargo build --frozen --release
    
      37}
    
      38
    
      39package() {
    
      40    cd "$pkgname-$pkgver"
    
      41
    
      42    install -Dm755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
    
      43
    
      44    install -Dm644 assets/icon.svg \
    
      45        "$pkgdir/usr/share/icons/hicolor/scalable/apps/$pkgname.svg"
    
      46    for size in 16 32 48 64 128 256; do
    
      47        install -dm755 "$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps"
    
      48        rsvg-convert -w "$size" -h "$size" assets/icon.svg \
    
      49            -o "$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps/$pkgname.png"
    
      50    done
    
      51
    
      52    install -Dm644 "assets/$pkgname.desktop" \
    
      53        "$pkgdir/usr/share/applications/$pkgname.desktop"
    
      54    install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
    
      55}
    
      56

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-20 09:27:54	Low	1